#include "..\script_component.hpp"

if (!isServer) exitWith {};

// array of all respawn modules in the mission representing "bases"
GVARMAIN(baseObjects) = allMissionObjects "ModuleRespawnPosition_F";
publicVariable QGVARMAIN(baseObjects);

// Initializes the Dynamic Groups framework and groups
["Initialize", [true]] call BIS_fnc_dynamicGroups;

if (isDedicated) then {
	["milsim_logText", {
		params [["_strArray", [""], [[]]]];
		{
			diag_log text _x;
		} forEach _strArray;
	}] call CBA_fnc_addEventHandler;
};


// initialize other modules
call EFUNC(common,logMissionInfo);
call EFUNC(fbcb2_assets,initServer);
call EFUNC(reinsert,initServer);

// declare init complete to other modules
missionNamespace setVariable [QGVARMAIN(complete), true, true];

[
	LEVEL_INFO,
	QUOTE(COMPONENT),
	format["%1: version %2", QGVARMAIN(complete), QUOTE(VERSION_STR)],
	[["version", QUOTE(VERSION_STR)]]
] call EFUNC(common,log);

[
	LEVEL_DEBUG,
	QUOTE(COMPONENT),
	"postInit complete",
	[]
] call EFUNC(common,log);