#include "..\script_component.hpp"

params [
	["_types", [], [[]]], // classnames to assign these action to
	["_useInheritance", false, [false]]
];

{ // forEach _types
	private _classToAddActionsTo = _x;

	private _checkReinsertQueueAction = [
		QGVAR(checkReinsertQueue),
		"[PILOT] Check Re-insert Queue",
		"\A3\ui_f\data\igui\cfg\simpleTasks\types\land_ca.paa",
		{
			params ["_target", "_player", "_params"];
			// request notification from the server
			call FUNC(requestShowQueue);
			// reset last check time
			localNamespace setVariable [QGVAR(lastReinsertQueueCheck), diag_tickTime];
		},
		{
			GVAR(setting_enabled);
		} // condition
	] call ace_interact_menu_fnc_createAction;
	[_classToAddActionsTo, 1, ["ACE_SelfActions"], _checkReinsertQueueAction, _useInheritance] call ace_interact_menu_fnc_addActionToClass;

} forEach _types;