17th-Ranger-Battalion-ORG/MissionTemplate
6
0
Fork 0
Code Issues 1 Pull Requests Actions Projects 1 Releases 16 Wiki Activity

change root level folder name to framework, update resupply+vehicleflags

Browse Source 
tested locally
This commit is contained in:
IndigoFox
2024-02-04 21:23:12 -08:00
parent c45f778188
commit 4cfa159ee9
88 changed files with 193 additions and 359 deletions
Download Patch File Download Diff File Expand all files Collapse all files

67
framework/reinsert/client/fn_addAceSelfActions.sqf Normal file
View File

@@ -0,0 +1,67 @@
params ["_type"]; // string of the object's classname
if (!(_type isKindOf "CAManBase")) exitWith {};
if (
(localNamespace getVariable ["milsim_reinsert_fileForReinsertClassesAdded", []])
find _type != -1
) exitWith {};
private _fileForReinsertAction = [
"milsim_reinsert_fileReinsertRequest",
"File Re-insert Request",
"\A3\ui_f\data\igui\cfg\simpleTasks\types\takeoff_ca.paa",
{ // statement
params ["_target", "_player", "_params"];
// find nearest base or location
private _base = [_player] call milsim_util_fnc_getNearestBase;
private _baseName = [_base] call milsim_util_fnc_getNameOfBase;
// send event to server
["milsim_reinsert_fileReinsertRequest", [_player, _base]] call CBA_fnc_serverEvent;
// notify player their request was filed
[["Re-insert Request Filed"], [format["Location: %1", _baseName]]] call CBA_fnc_notify;
},
{ // condition
params ["_target", "_player", "_params"];
// find nearest base or location
private _base = [_player] call milsim_util_fnc_getNearestBase;
private _baseDistance = _player distance _base;
private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
private _existingQueue = missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []];
// check if module is enabled, player is near a base, and player is not already in the queue
// (serverTime - milsim_reinsert_missionStartServerTime) > 60*5 && // only allow after 15 minutes
missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_enabled", true] &&
(_baseDistance < _maxRangeToReady) &&
not (_player in (_existingQueue apply {_x#0}))
}
] call ace_interact_menu_fnc_createAction;
[_type, 1, ["ACE_SelfActions"], _fileForReinsertAction, true] call ace_interact_menu_fnc_addActionToClass;
private _removeFileForReinsertAction = [
"milsim_reinsert_removeReinsertRequest",
"Remove Re-insert Request",
"\A3\ui_f\data\igui\cfg\simpleTasks\types\land_ca.paa",
{ // statement
params ["_target", "_player", "_params"];
// send event to server
["milsim_reinsert_removeReinsertRequest", [_player]] call CBA_fnc_serverEvent;
// notify player their request was rescinded
"Re-insert Request Rescinded" call CBA_fnc_notify;
},
{ // condition
params ["_target", "_player", "_params"];
private _existingQueue = missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []];
// check if module is enabled, player is in the queue
// (serverTime - milsim_reinsert_missionStartServerTime) > 60*5 && // only allow after 15 minutes
missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_enabled", true] &&
(_player in (_existingQueue apply {_x#0}))
}
] call ace_interact_menu_fnc_createAction;
[_type, 1, ["ACE_SelfActions"], _removeFileForReinsertAction, true] call ace_interact_menu_fnc_addActionToClass;
private _classesActionsAddedTo = (localNamespace getVariable ["milsim_reinsert_fileForReinsertClassesAdded", []]);
_classesActionsAddedTo pushBackUnique _type;
localNamespace setVariable ["milsim_reinsert_fileForReinsertClassesAdded", _classesActionsAddedTo];

28
framework/reinsert/client/fn_addCheckQueueSelfAction.sqf Normal file
View File

@@ -0,0 +1,28 @@
params ["_type"]; // string of the object's classname
if (!(_type isKindOf "CAManBase")) exitWith {};
if (
(localNamespace getVariable ["milsim_reinsert_checkReinsertQueueClassesAdded", []])
find _type != -1
) exitWith {};
private _checkReinsertQueueAction = [
"milsim_reinsert_checkReinsertQueue",
"[PILOT] Check Re-insert Queue",
"\A3\ui_f\data\igui\cfg\simpleTasks\types\land_ca.paa",
{
params ["_target", "_player", "_params"];
// request notification from the server
call milsim_reinsert_fnc_requestShowQueue;
// reset last check time
localNamespace setVariable ["milsim_reinsert_lastReinsertQueueCheck", diag_tickTime];
},
{
missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_enabled", true]
} // always allow
] call ace_interact_menu_fnc_createAction;
[_type, 1, ["ACE_SelfActions"], _checkReinsertQueueAction, true] call ace_interact_menu_fnc_addActionToClass;
private _classesActionsAddedTo = (localNamespace getVariable ["milsim_reinsert_checkReinsertQueueClassesAdded", []]);
_classesActionsAddedTo pushBackUnique _type;
localNamespace setVariable ["milsim_reinsert_checkReinsertQueueClassesAdded", _classesActionsAddedTo];

53
framework/reinsert/client/fn_initClient.sqf Normal file
View File

@@ -0,0 +1,53 @@
if (!hasInterface) exitWith {};
// ACE SELF-INTERACTIONS FOR FILING AND RESCINDING REINSERT REQUESTS NEAR BASE - ALL PLAYERS
localNamespace setVariable ["milsim_reinsert_fileForReinsertClassesAdded", []];
// add actions to current class
[typeOf player] call milsim_reinsert_fnc_addAceSelfActions;
// add actions to future classes
["ace_interact_menu_newControllableObject", {
_this call milsim_reinsert_fnc_addAceSelfActions;
}] call CBA_fnc_addEventHandler;
/////////////////////////////////////////////////////
// PILOTS ONLY
// ACE SELF-INTERACTIONS FOR CHECKING REINSERT QUEUE - ONLY FOR PILOTS
if ((typeOf player) in ["B_Helipilot_F", "B_helicrew_F"]) then {
localNamespace setVariable ["milsim_reinsert_checkReinsertQueueClassesAdded", []];
localNamespace setVariable ["milsim_reinsert_lastReinsertQueueCheck", diag_tickTime];
// add actions to current class
[typeOf player] call milsim_reinsert_fnc_addCheckQueueSelfAction;
// add actions to future classes
["ace_interact_menu_newControllableObject", {
_this call milsim_reinsert_fnc_addCheckQueueSelfAction;
}] call CBA_fnc_addEventHandler;
};
/////////////////////////////////////////////////////
// ADD TIMER FOR PILOTS - IF REINSERT LIST NOT CHECKED FOR 20 MINUTES, SHOW NOTIFICATION AUTOMATICALLY
if ((typeOf player) in ["B_Helipilot_F", "B_helicrew_F"]) then {
[{
// if module not enabled and pilot forced check not enabled, exit
if (not (
missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_enabled", true] &&
missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_pilotForcedCheckEnabled", true]
)) exitWith {};
// if last check was less than X minutes ago, skip
private _lastCheck = localNamespace getVariable ["milsim_reinsert_lastReinsertQueueCheck", diag_tickTime];
private _requiredCheckInterval = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_pilotForcedCheckInterval", 60*20];
if (
diag_tickTime - _lastCheck <
_requiredCheckInterval
) exitWith {}; // if last check was less than X minutes ago, skip
// last check was greater than X minutes ago
// reset last check time
localNamespace setVariable ["milsim_reinsert_lastReinsertQueueCheck", diag_tickTime];
// request notification from the server
call milsim_reinsert_fnc_requestShowQueue;
}, 30] call CBA_fnc_addPerFrameHandler;
};
/////////////////////////////////////////////////////

3
framework/reinsert/client/fn_requestShowQueue.sqf Normal file
View File

@@ -0,0 +1,3 @@
if (!hasInterface) exitWith {};
[] remoteExec ["milsim_reinsert_fnc_returnReinsertQueueNotification", 2];