17th-Ranger-Battalion-ORG/MissionTemplate
6
0
Fork 0
Code Issues 1 Pull Requests Actions Projects 1 Releases 16 Wiki Activity

change root level folder name to framework, update resupply+vehicleflags

Browse Source 
tested locally
This commit is contained in:
IndigoFox
2024-02-04 21:23:12 -08:00
parent c45f778188
commit 4cfa159ee9
88 changed files with 193 additions and 359 deletions
Download Patch File Download Diff File Expand all files Collapse all files

56
framework/reinsert/server/fn_addToQueue.sqf Normal file
View File

@@ -0,0 +1,56 @@
params [
["_player", objNull, [objNull]],
["_base", objNull, [objNull]],
["_timeFiled", diag_tickTime, [25]]
];
if (!isServer) exitWith {
[
"respawn_reinsertion",
"ATTEMPTED RUN ON CLIENT",
[
["player", _player],
["base", _base]
]
] call milsim_util_fnc_log;
};
if (
isNull _player ||
isNull _base
) exitWith {
[
"respawn_reinsertion",
"NULL PARAMETERS",
[
["player", _player],
["base", _base]
]
] call milsim_util_fnc_log;
};
private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
// nearest base here is the same as the base sent
private _nearestBase = _base;
milsim_reinsert_reinsertionQueue pushBackUnique [
_player, _base, _timeFiled
];
// broadcast new list to all machines
publicVariable "milsim_reinsert_reinsertionQueue";
// log to rpt
private _logParams = [
["filedAtBase", [_base] call milsim_util_fnc_getNameOfBase],
["filedAtBaseDistance", _player distance _base],
["closestBase", [_nearestBase] call milsim_util_fnc_getNameOfBase],
["closestBaseDistance", _player distance _nearestBase],
["maxDistanceSetting", _maxRangeToReady],
["inQueueDuration", diag_tickTime - _timeFiled]
];
_logParams = [_player, _logParams] call milsim_util_fnc_addPlayerInfoToArray;
[
"respawn_reinsertion",
"PLAYER FILED REQUEST",
_logParams
] call milsim_util_fnc_log;

70
framework/reinsert/server/fn_globalShowQueue.sqf Normal file
View File

@@ -0,0 +1,70 @@
if (!isServer) exitWith {};
// if at least 1 player in the queue has been waiting longer than the configured timeout, notify all players
private _timeout = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_max_wait", 60*20]; // default 20 minutes
private _timeoutPlayers = milsim_reinsert_reinsertionQueue select {
_x params ["_player", "_base", "_timeFiled"];
alive (_player) &&
(diag_tickTime - (_timeFiled)) > _timeout
};
if (count _timeoutPlayers > 0) then {
// GLOBAL CBA NOTIFY
private _playerLines = [["Players are still waiting for Re-insert!", 1.2, [1, 0.64, 0, 1]]];
private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
// get base objects from queue
private _basesWithPeople = (missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []]) apply {_x#1};
// get unique base objects
private _basesWithPeople = _basesWithPeople arrayIntersect _basesWithPeople;
{
private _thisBase = _x;
// Add line for base name
_playerLines pushBack ([[_thisBase] call milsim_util_fnc_getNameOfBase, 1, [0,1,0,1]]);
// Get players under this base
private _thisBasePlayers = _timeoutPlayers select {_x#1 isEqualTo _thisBase};
// sort _timeoutPlayers by time in queue, descending
_thisBasePlayers = [_thisBasePlayers, [], {
_x params ["_player", "_base", "_timeFiled"];
_timeFiled;
}, "DESCEND"] call BIS_fnc_sortBy;
{ // for each player under this base, add a line
_x params ["_player", "_base", "_timeFiled"];
// get the closest base to the player
private _nearestBase = [_player] call milsim_util_fnc_getNearestBase;
// add player to array of players under bases
_playerLines pushBack ([format [
"%1: %2 [%3]",
groupID (group (_player)),
name (_player),
[diag_tickTime - (_timeFiled), "MM:SS"] call BIS_fnc_secondsToString
], 0.8, [0.8, 0.8, 0.8, 1]]);
// log to rpt
private _logParams = [
["filedAtBase", [_base] call milsim_util_fnc_getNameOfBase],
["filedAtBaseDistance", _player distance _base],
["closestBase", [_nearestBase] call milsim_util_fnc_getNameOfBase],
["closestBaseDistance", _player distance _nearestBase],
["maxDistanceSetting", _maxRangeToReady],
["inQueueDuration", diag_tickTime - _timeFiled]
];
_logParams = [_player, _logParams] call milsim_util_fnc_addPlayerInfoToArray;
[
"respawn_reinsertion",
"PLAYER WAITING OVER TIMEOUT",
_logParams
] call milsim_util_fnc_log;
} forEach _thisBasePlayers;
} forEach _basesWithPeople;
// SEND NOTIFY
_playerLines remoteExec ["CBA_fnc_notify", [0, -2] select isDedicated];
// RESET NOTIFICATION TIMER
milsim_reinsert_reinsertionOverTimeoutLastNotificationTime = diag_tickTime;
};

50
framework/reinsert/server/fn_initServer.sqf Normal file
View File

@@ -0,0 +1,50 @@
// if a player files for reinsert using self-interaction
// they're added to the queue along with their nearest base location and the time they filed
// if a player's time in the queue exceeds the configured timeout, a message will be posted every 5 minutes on a cycle based around
// the player's time in the queue stating how long they have been waiting, their name, and their group's name
if (!isServer) exitWith {};
// array of all respawn modules in the mission, used as 'base' locations for reinsertion
milsim_baseObjects = allMissionObjects "ModuleRespawnPosition_F";
publicVariable "milsim_baseObjects";
// register queue
milsim_reinsert_reinsertionQueue = [];
publicVariable "milsim_reinsert_reinsertionQueue";
// server mission start time
milsim_reinsert_missionStartServerTime = serverTime;
// FILE REQUEST CBA HANDLER
["milsim_reinsert_fileReinsertRequest", {
params ["_player", "_base"];
[_player, _base] call milsim_reinsert_fnc_addToQueue;
}] call CBA_fnc_addEventHandler;
// REMOVE REQUEST CBA HANDLER
["milsim_reinsert_removeReinsertRequest", {
params ["_player"];
[_player] call milsim_reinsert_fnc_removeFromQueue;
}] call CBA_fnc_addEventHandler;
// automated wait threshold timer
milsim_reinsert_reinsertionOverTimeoutLastNotificationTime = 0;
[{ // every 60 seconds
// validate queue
call milsim_reinsert_fnc_validateQueue;
// check if last overTimeout notification was sent more than X minutes ago
if (
diag_tickTime - milsim_reinsert_reinsertionOverTimeoutLastNotificationTime > 60*5
) then {
// show global queue notification with any players that are over timeout
call milsim_reinsert_fnc_globalShowQueue;
};
}, 60] call CBA_fnc_addPerFrameHandler;

57
framework/reinsert/server/fn_removeFromQueue.sqf Normal file
View File

@@ -0,0 +1,57 @@
params [["_player", objNull, [objNull]]];
if (!isServer) exitWith {
[
"respawn_reinsertion",
"ATTEMPTED RUN ON CLIENT",
[
["player", _player]
]
] call milsim_util_fnc_log;
};
if (isNull _player) exitWith {
[
"respawn_reinsertion",
"NULL PARAMETERS",
[
["player", _player]
]
] call milsim_util_fnc_log;
};
// get entries for this player from queue
private _unitArrs = milsim_reinsert_reinsertionQueue select {_x#0 isEqualTo _player};
// if player not in queue, skip
if (count _unitArrs isEqualTo 0) exitWith {};
private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
// remove player from queue
milsim_reinsert_reinsertionQueue = milsim_reinsert_reinsertionQueue - _unitArrs;
// broadcast new list to all machines
publicVariable "milsim_reinsert_reinsertionQueue";
// sort _unitArrs by time in queue, descending, to get longest wait (if for some reason there's a duplicate)
[_unitArrs, [], {
_x#2
}, "DESCEND"] call BIS_fnc_sortBy;
// get first entry (longest wait)
(_unitArrs#0) params ["_player", "_base", "_timeFiled"]; // _unitArr = [unit, base, timeInQueue]
// get the closest base to the player
private _nearestBase = [_player] call milsim_util_fnc_getNearestBase;
// log to rpt
private _logParams = [
["filedAtBase", [_base] call milsim_util_fnc_getNameOfBase],
["filedAtBaseDistance", _player distance _base],
["closestBase", [_nearestBase] call milsim_util_fnc_getNameOfBase],
["closestBaseDistance", _player distance _nearestBase],
["maxDistanceSetting", _maxRangeToReady],
["inQueueDuration", diag_tickTime - _timeFiled]
];
_logParams = [_player, _logParams] call milsim_util_fnc_addPlayerInfoToArray;
[
"respawn_reinsertion",
"PLAYER RESCINDED REQUEST",
_logParams
] call milsim_util_fnc_log;

109
framework/reinsert/server/fn_returnReinsertQueueNotification.sqf Normal file
View File

@@ -0,0 +1,109 @@
/*
Function: milsim_reinsert_fnc_showReinsertQueueNotification
Description:
Designed to be remoteExecuted on the server. Will show a CBA notification on the remoteExecutedOwner's screen with the current reinsertion queue and log this occurrence in the server RPT.
Author: IndigoFox
*/
if (not isRemoteExecuted) exitWith {
diag_log text format ["[milsim] (respawn_reinsertion) SHOW QUEUE NOT REMOTE EXECUTED"];
};
if (not isServer) exitWith {
diag_log text format ["[milsim] (respawn_reinsertion) SHOW QUEUE NOT RUN ON SERVER"];
};
private _users = allUsers apply {getUserInfo _x} select {count _x > 0};
private _userIndex = _users findIf {_x#1 isEqualTo remoteExecutedOwner};
if (_userIndex isEqualTo -1) exitWith {
diag_log text format ["[milsim] (respawn_reinsertion) SHOW QUEUE USER NOT FOUND"];
};
private _userObject = _users select _userIndex select 10;
if (isNull _userObject) exitWith {
diag_log text format ["[milsim] (respawn_reinsertion) SHOW QUEUE USER OBJECT NOT FOUND"];
};
// log to rpt
private _logParams = [_userObject, []] call milsim_util_fnc_addPlayerInfoToArray;
[
"respawn_reinsertion",
"SHOW QUEUE REQUESTED",
_logParams
] call milsim_util_fnc_log;
private _queue = missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []];
// get base objects from queue
private _basesWithPeople = (missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []]) apply {_x#1};
// get unique base objects
private _basesWithPeople = _basesWithPeople arrayIntersect _basesWithPeople;
// text array to use in notification
private _par = [["Players Awaiting Reinsert", 1.2, [1,0.64,0,1]]];
if (count _basesWithPeople isEqualTo 0) then {
_par pushBack ["[QUEUE EMPTY]", 1, [1,1,1,1]];
};
// forEach _basesWithPeople
{
private _thisBase = _x;
private _baseName = [_thisBase] call milsim_util_fnc_getNameOfBase;
// generate player lines for this base
private _playerLines = _queue select {
_x#1 isEqualTo _thisBase
} apply {
_x params ["_player", "_base", "_timeFiled"];
[
format [
"%1: %2 [%3]",
groupId (group _player),
name _player,
[diag_tickTime - _timeFiled, "MM:SS"] call BIS_fnc_secondsToString
],
0.8,
[1,1,1,1]
];
};
// determine suffix for player count based on count
private _playerCountText = "";
switch (count _playerLines) do {
case 0: {
_playerCountText = "No players";
};
case 1: {
_playerCountText = "1 player";
};
default {
_playerCountText = format ["%1 players", count _playerLines];
};
};
// add base name and player count to notification lines
_par pushBack [
format ["Location: %1 (%2)",
_baseName,
_playerCountText
],
1,
[0,1,0,1]
];
// sort by text (first piece of text is group name)
_playerLines = [
_playerLines,
[],
{_x#0}
] call BIS_fnc_sortBy;
// add to notification lines
{
_par pushBack _x;
} forEach _playerLines;
} forEach _basesWithPeople;
_par remoteExec ["CBA_fnc_notify", remoteExecutedOwner];
true;

57
framework/reinsert/server/fn_validateQueue.sqf Normal file
View File

@@ -0,0 +1,57 @@
// revalidate any players in the queue
// compare their distance to the nearest base, and remove them if they're too far away (or dead)
private _stillValid = [];
private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
{
_x params ["_player", "_base", "_timeFiled"]; // _unitArr = [unit, baseName, timeInQueue]
private _distanceToOriginalBase = _player distance _base;
// get the closest base to the player
private _nearestBase = [_player] call milsim_util_fnc_getNearestBase;
private _isCloseEnoughToAnyBase = (_player distance _nearestBase) < _maxRangeToReady;
if (not _isCloseEnoughToAnyBase || not (alive _player)) then {
// don't include player in updated queue
// log to rpt
private _logParams = [
["filedAtBase", [_base] call milsim_util_fnc_getNameOfBase],
["filedAtBaseDistance", _player distance _base],
["closestBase", [_nearestBase] call milsim_util_fnc_getNameOfBase],
["closestBaseDistance", _player distance _nearestBase],
["maxDistanceSetting", _maxRangeToReady],
["inQueueDuration", diag_tickTime - _timeFiled]
];
_logParams = [_player, _logParams] call milsim_util_fnc_addPlayerInfoToArray;
[
"respawn_reinsertion",
"PLAYER DEQUEUED AUTOMATICALLY",
_logParams
] call milsim_util_fnc_log;
// continue loop
continue
};
// include player in updated queue, and update their location to nearest base
_stillValid pushBackUnique [_player, _nearestBase, _timeFiled];
// if player's base has changed, log to rpt
if (_base != _nearestBase) then {
private _logParams = [
["filedAtBase", [_base] call milsim_util_fnc_getNameOfBase],
["filedAtBaseDistance", _player distance _base],
["closestBase", [_nearestBase] call milsim_util_fnc_getNameOfBase],
["closestBaseDistance", _player distance _nearestBase],
["maxDistanceSetting", _maxRangeToReady],
["inQueueDuration", diag_tickTime - _timeFiled]
];
_logParams = [_player, _logParams] call milsim_util_fnc_addPlayerInfoToArray;
[
"respawn_reinsertion",
"PLAYER BASE WAS UPDATED",
_logParams
] call milsim_util_fnc_log;
};
} forEach milsim_reinsert_reinsertionQueue;
// broadcast new list to all machines
milsim_reinsert_reinsertionQueue = _stillValid;
publicVariable "milsim_reinsert_reinsertionQueue";