17th-Ranger-Battalion-ORG/MissionTemplate
6
0
Fork 0
Code Issues 1 Pull Requests Actions Projects 1 Releases 16 Wiki Activity

adds events, queue, auto-notifications, manual checks for pilots

Browse Source
This commit is contained in:
IndigoFox
2024-01-26 00:26:06 -08:00
parent e9fc5cfe21
commit 754d7356e1
4 changed files with 208 additions and 1 deletions
Download Patch File Download Diff File Expand all files Collapse all files

8
functions/CfgFunctions.hpp
View File

@@ -65,3 +65,11 @@ class milsim
class stringToMapMarker {}; //needs refactor
};
};
class milsim_respawn {
class functions {
file = "functions\respawn";
class init { postInit = 1; };
class showReinsertQueueNotification {};
};
};

2
functions/fbcb2/fn_messageFBCB2AssetStatus.sqf
View File

@@ -11,7 +11,7 @@ _text = composeText [_text, parseText "<t align='left' size='2'>Asset</t><t alig
_assigned = _x select 2;
_available = 0; //count (getMarkerPos "respawn_west" nearEntities [ _asset, 2000] );
_homes = allMissionObjects "ModuleRespawnPosition_F";
_homes = allMissionObjects "ModuleRespawnPosition_F";
{
_home = _x;

182
functions/respawn/fn_init.sqf Normal file
View File

@@ -0,0 +1,182 @@
// execute for all
milsim_respawn_setting_maxRangeToReady = 400; // distance in meters from a base at which players can ready up for pickup. players removed from the queue if they move further away than this distance
milsim_respawn_bases = allMissionObjects "ModuleRespawnPosition_F"; // array of all respawn modules in the mission
// player self-interacts will be applied in initPlayerLocal via milsim_respawn_fnc_readyForPickup
// on the server, initialize the queue and register the CBA event handler by which players can ready up
if (isServer) then {
// register queue
milsim_respawn_reinsertionQueue = [];
publicVariable "milsim_respawn_reinsertionQueue";
// register event handlers
["milsim_respawn_fileReinsertRequest", {
params ["_unit", "_closestBaseName"];
milsim_respawn_reinsertionQueue pushBackUnique [_unit, _closestBaseName];
diag_log text format ["[milsim_respawn] [reinsertion] ADDED name=%1 playerUID=%2 closestBase=%3", name _unit, getPlayerUID _unit, _closestBaseName];
publicVariable "milsim_respawn_reinsertionQueue";
}] call CBA_fnc_addEventHandler;
["milsim_respawn_removeReinsertRequest", {
params ["_unit"];
if (milsim_respawn_reinsertionQueue find {_x#0 isEqualTo _unit} == -1) exitWith {};
milsim_respawn_reinsertionQueue = milsim_respawn_reinsertionQueue select {_x#0 isNotEqualTo _unit};
diag_log text format ["[milsim_respawn] [reinsertion] REMOVED BY REQUEST name=%1 playerUID=%2", name _unit, getPlayerUID _unit];
publicVariable "milsim_respawn_reinsertionQueue";
}] call CBA_fnc_addEventHandler;
// every 60 seconds, revalidate any players in the queue
// compare their distance to the nearest base, and remove them if they're too far away (or dead)
[{
private _stillValid = [];
{
private _queueData = _x;
private _player = _queueData#0;
private _nearBase = false;
private _nearestDistance = 99999;
{
private _baseLocation = _x;
private _distanceFromBase = _player distance _baseLocation;
if (_distanceFromBase < _nearestDistance) then {
_nearestDistance = _distanceFromBase;
};
if (_distanceFromBase < milsim_respawn_setting_maxRangeToReady) then {
_nearBase = true;
};
} forEach milsim_respawn_bases;
if (_nearBase && alive _player) then {
_stillValid pushBackUnique _queueData;
} else {
diag_log text format ["[milsim_respawn] [reinsertion] REMOVED AUTOMATICALLY name=%1 playerUID=%2 nearestBase=%3m", name _player, getPlayerUID _player, _nearestDistance];
};
} forEach milsim_respawn_reinsertionQueue;
milsim_respawn_reinsertionQueue = _stillValid;
publicVariable "milsim_respawn_reinsertionQueue";
}, 60] call CBA_fnc_addPerFrameHandler;
};
// if a player, register the ACE self-interaction to ready up
if (hasInterface) then {
// ACE SELF-INTERACTIONS FOR FILING AND RESCINDING REINSERT REQUESTS NEAR BASE - ALL PLAYERS
localNamespace setVariable ["milsim_respawn_fileForReinsertClassesAdded", []];
private _addReinsertRequestSelfActions = {
params ["_type"]; // string of the object's classname
if (!(_type isKindOf "CAManBase")) exitWith {};
if (
(localNamespace getVariable ["milsim_respawn_fileForReinsertClassesAdded", []])
find _type != -1
) exitWith {};
private _fileForReinsertAction = [
"milsim_respawn_fileReinsertRequest",
"File Re-insert Request",
"\A3\ui_f\data\igui\cfg\simpleTasks\types\takeoff_ca.paa",
{
params ["_target", "_player", "_params"];
private _closestBase = [milsim_respawn_bases, _player] call BIS_fnc_nearestPosition;
["milsim_respawn_fileReinsertRequest", [_player, _closestBase getVariable ["name", "unknown"]]] call CBA_fnc_serverEvent;
format["Re-insert Request Filed at Location %1", _closestBase getVariable ["name", "unknown"]] call CBA_fnc_notify;
},
{
params ["_target", "_player", "_params"];
private _closestBase = [milsim_respawn_bases, _player] call BIS_fnc_nearestPosition;
(_player distance _closestBase < milsim_respawn_setting_maxRangeToReady) &&
not (_player in ((missionNamespace getVariable ["milsim_respawn_reinsertionQueue", []]) apply {_x#0}))
}
] call ace_interact_menu_fnc_createAction;
[_type, 1, ["ACE_SelfActions"], _fileForReinsertAction, true] call ace_interact_menu_fnc_addActionToClass;
private _removeFileForReinsertAction = [
"milsim_respawn_removeReinsertRequest",
"Remove Re-insert Request",
"\A3\ui_f\data\igui\cfg\simpleTasks\types\land_ca.paa",
{
params ["_target", "_player", "_params"];
["milsim_respawn_removeReinsertRequest", [_player]] call CBA_fnc_serverEvent;
"Re-insert Request has been rescinded." call CBA_fnc_notify;
},
{
params ["_target", "_player", "_params"];
(_player in ((missionNamespace getVariable ["milsim_respawn_reinsertionQueue", []]) apply {_x#0}))
}
] call ace_interact_menu_fnc_createAction;
[_type, 1, ["ACE_SelfActions"], _removeFileForReinsertAction, true] call ace_interact_menu_fnc_addActionToClass;
private _classesActionsAddedTo = (localNamespace getVariable ["milsim_respawn_fileForReinsertClassesAdded", []]);
_classesActionsAddedTo pushBackUnique _type;
localNamespace setVariable ["milsim_respawn_fileForReinsertClassesAdded", _classesActionsAddedTo];
};
[typeOf player] call _addReinsertRequestSelfActions;
["ace_interact_menu_newControllableObject", {
_thisArgs params ["_fnc"];
_this call _fnc;
}, [_addReinsertRequestSelfActions]] call CBA_fnc_addEventHandlerArgs;
/////////////////////////////////////////////////////
// PILOTS ONLY
// ACE SELF-INTERACTIONS FOR CHECKING REINSERT QUEUE - ONLY FOR PILOTS
localNamespace setVariable ["milsim_respawn_checkReinsertQueueClassesAdded", []];
localNamespace setVariable ["milsim_respawn_lastReinsertQueueCheck", diag_tickTime];
private _addCheckReinsertQueueSelfAction = {
params ["_type"]; // string of the object's classname
if (!(_type isKindOf "CAManBase")) exitWith {};
if (!(_type in ["B_Helipilot_F", "B_helicrew_F"])) exitWith {};
if (
(localNamespace getVariable ["milsim_respawn_checkReinsertQueueClassesAdded", []])
find _type != -1
) exitWith {};
private _checkReinsertQueueAction = [
"milsim_respawn_checkReinsertQueue",
"[PILOT] Check Re-insert Queue",
"\A3\ui_f\data\igui\cfg\simpleTasks\types\land_ca.paa",
{
params ["_target", "_player", "_params"];
// reset last check time
localNamespace setVariable ["milsim_respawn_lastReinsertQueueCheck", diag_tickTime];
call milsim_respawn_fnc_showReinsertQueueNotification;
},
{true} // always allow
] call ace_interact_menu_fnc_createAction;
[_type, 1, ["ACE_SelfActions"], _checkReinsertQueueAction, true] call ace_interact_menu_fnc_addActionToClass;
private _classesActionsAddedTo = (localNamespace getVariable ["milsim_respawn_checkReinsertQueueClassesAdded", []]);
_classesActionsAddedTo pushBackUnique _type;
localNamespace setVariable ["milsim_respawn_checkReinsertQueueClassesAdded", _classesActionsAddedTo];
};
[typeOf player] call _addCheckReinsertQueueSelfAction;
["ace_interact_menu_newControllableObject", {
_thisArgs params ["_fnc"];
_this call _fnc;
}, [_addCheckReinsertQueueSelfAction]] call CBA_fnc_addEventHandlerArgs;
// ADD TIMER FOR PILOTS - IF REINSERT LIST NOT CHECKED FOR 20 MINUTES, SHOW NOTIFICATION AUTOMATICALLY
if ((typeOf player) in ["B_Helipilot_F", "B_helicrew_F"]) then {
[{
private _lastCheck = localNamespace getVariable ["milsim_respawn_lastReinsertQueueCheck", diag_tickTime];
if (diag_tickTime - _lastCheck < (60*20)) exitWith {}; // if last check was less than 20 minutes ago, skip
// if last check was greater than 20 minutes ago, we'll prompt the notification now and reset the timer
localNamespace setVariable ["milsim_respawn_lastReinsertQueueCheck", diag_tickTime];
call milsim_respawn_fnc_showReinsertQueueNotification;
}, 30] call CBA_fnc_addPerFrameHandler;
};
/////////////////////////////////////////////////////
};

17
functions/respawn/fn_showReinsertQueueNotification.sqf Normal file
View File

@@ -0,0 +1,17 @@
private _par = [["Players Awaiting Reinsert", 1.2, [1,0.64,0,1]]];
private _baseNames = (missionNamespace getVariable ["milsim_respawn_reinsertionQueue", []]) apply {_x#1};
{
private _baseName = _x;
_par pushBack [format ["Location: %1", _baseName], 1, [0,1,0,1]];
{
_par pushBack _x;
} forEach ((missionNamespace getVariable ["milsim_respawn_reinsertionQueue", []]) select {
_x#1 isEqualTo _baseName
} apply {
[name (_x#0), 0.7, [1,1,1,1]];
});
} forEach _baseNames;
_par call CBA_fnc_notify;
true;