major updates to fbcb2 diary stuff

functions/fbcb2/radioFrequencies/fn_formatRadioElementForDiary.sqf

@@ -0,0 +1,62 @@
+// called from milsim_fnc_processFBCB2RadioFrequencies
+params ["_cfg", ["_indentCount", 1, [5]]];
+
+private _leadingSpace = [
+	format["<font size='%1' face='%2'>| ", _ELEMENT_NAME_SIZE, _ELEMENT_NAME_FONT]
+];
+for "_i" from 1 to _indentCount do {
+	_leadingSpace pushBack "-";
+};
+_leadingSpace pushBack " | </font>";
+
+// make header line
+private _lines = [
+	format[
+		"<font color='%1'>%2%3</font>",
+		getText(_cfg >> "textColor"),
+		_leadingSpace joinString "",
+		getText (_cfg >> "callsign")
+	]
+];
+
+// make frequency lines
+private _freqLeadingSpace = [
+	format["<font size='%1' face='%2'>| ", _ELEMENT_NAME_SIZE, _ELEMENT_NAME_FONT]
+];
+for "_i" from 1 to _FREQ_INDENT_CONSTANT do {
+	_freqLeadingSpace pushBack " ";
+};
+_freqLeadingSpace pushBack "</font>";
+_freqLeadingSpace = _freqLeadingSpace joinString "";
+
+{
+	_x params ["_role", "_sr", "_lr"];
+
+
+	private ["_srStr", "_lrStr"];
+	if (count _sr > 0) then {
+		_srStr = format["%1", _sr joinString " / "];
+	} else {
+		_srStr = "----";
+	};
+	if (count _lr > 0) then {
+		_lrStr = format["%1", _lr joinString " / "];
+	} else {
+		_lrStr = "----";
+	};
+
+
+	_lines pushBack format[
+		"%1<font size='%2' face='%3' color='%4'>- %5%6%7</font>",
+		_freqLeadingSpace,
+		_ELEMENT_FREQ_SIZE,
+		_ELEMENT_FREQ_FONT,
+		_FREQ_TEXT_COLOR,
+		[_role, "right", " ", _FREQ_PAD_LENGTH] call milsim_fnc_padString,
+		[_srStr, "right", " ", _FREQ_PAD_LENGTH] call milsim_fnc_padString,
+		_lrStr
+	];
+} forEach (getArray (_cfg >> "frequencies"));
+// diag_log text (_lines joinString endl);
+
+_lines;

functions/fbcb2/radioFrequencies/fn_generateElementFrequencyRecordText.sqf

@@ -0,0 +1,60 @@
+// called from milsim_fnc_processFBCB2RadioFrequencies
+params [
+	["_elementCfg", configNull, [configNull]],
+	["_shouldProcessChildCfgs", true]
+];
+
+if (isNull _elementCfg) exitWith {
+	["_elementCfg parameter is NULL"] call BIS_fnc_error;
+};
+
+private _battalionElement = _elementCfg;
+
+private _recordTitle = format[
+	"%1 (%2)",
+	getText(_battalionElement >> "callsign"),
+	getText(_battalionElement >> "shortDescription")
+];
+// systemChat _recordTitle;
+
+private _headers = [
+	format[
+		"<font size='%1' color='%2' face='%3'>%4</font><br/><br/>",
+		milsim_fbcb2_recordTitleSize,
+		milsim_fbcb2_recordTitleColor,
+		milsim_fbcb2_recordTitleFont,
+		_recordTitle
+	],
+	format[
+		"%1<font size='%2' face='%3' color='%4'>- %5%6%7</font><br/><br/>",
+		_freqLeadingSpace,
+		_ELEMENT_FREQ_SIZE,
+		_ELEMENT_FREQ_FONT,
+		_FREQ_TEXT_COLOR,
+		["ROLE", "right", " ", _FREQ_PAD_LENGTH] call milsim_fnc_padString,
+		["SR", "right", " ", _FREQ_PAD_LENGTH] call milsim_fnc_padString,
+		"LR"
+	]
+];
+
+private _allText = [];
+
+// get all child elements recursively and format them
+if (_shouldProcessChildCfgs) then {
+	[_battalionElement, {
+		params ["_cfg", "_recurseCounter"];
+		// add config
+		private _lines = [_cfg, _recurseCounter+1] call milsim_fnc_formatRadioElementForDiary;
+		// private _lines = [_cfg, _indentCount] call t;
+		_allText pushBack (_lines joinString "<br/>");
+	}] call milsim_fnc_recurseSubclasses;
+} else {
+	private _lines = [_battalionElement, 1] call milsim_fnc_formatRadioElementForDiary;
+	// private _lines = [_cfg, _indentCount] call t;
+	_allText pushBack (_lines joinString "<br/>");
+};
+
+
+_allText = format["%1<font face='EtelkaMonospaceProBold'>%2</font>", _headers joinString "<br/>", _allText joinString "<br/>"];
+
+[_recordTitle, _allText];