many changes. includes rework of baselocation-asset storage format

framework/fbcb2_main/functions/fn_init.sqf

@@ -0,0 +1,39 @@
+#include "../script_component.hpp"
+
+if ( !hasInterface ) exitWith {};
+
+waitUntil { !isNil QGVARMAIN(complete) };
+
+GVAR(recordTitleColor) = "#ff6666";
+GVAR(recordTitleFont) = "PuristaMedium";
+GVAR(recordTitleSize) = 20;
+
+GVAR(recordTextHeaderSize) = 16;
+GVAR(recordTextBodySize) = 14;
+
+GVAR(subjectStatusID) = "FBCB2_Status";
+GVAR(subjectIntelID) = "FBCB2_Intel";
+GVAR(subjectMessagesID) = "FBCB2_Messages";
+GVAR(subjectFrequenciesID) = "FBCB2_Frequencies";
+GVAR(subjectAssetsFixedWingID) = "FBCB2_Assets_FixedWing";
+GVAR(subjectAssetsRotaryID) = "FBCB2_Assets_Rotary";
+GVAR(subjectAssetsGroundID) = "FBCB2_Assets_Ground";
+
+player createDiarySubject[GVAR(subjectStatusID), "FBCB2 Status"];
+player createDiarySubject[GVAR(subjectMessagesID), "FBCB2 Messages"];
+player createDiarySubject[GVAR(subjectIntelID), "FBCB2 Intel"];
+player createDiarySubject[GVAR(subjectFrequenciesID), "FBCB2 Frequencies"];
+player createDiarySubject[GVAR(subjectAssetsFixedWingID), "FBCB2 Planes"];
+player createDiarySubject[GVAR(subjectAssetsRotaryID), "FBCB2 Helicopters"];
+player createDiarySubject[GVAR(subjectAssetsGroundID), "FBCB2 Ground"];
+
+// store records in format:
+// [subject, [
+//		[title, diaryRecord]
+// ]]
+GVAR(diaryRecords) = createHashMap;
+
+// run main inits - assets handled in that component
+[] call FUNC(processFBCB2RadioFrequencies);
+[] call FUNC(processFBCB2SmokeColors);
+[] call FUNC(processFBCB2Environment);

framework/fbcb2_main/functions/fn_processFBCB2Environment.sqf

@@ -0,0 +1,47 @@
+#include "..\script_component.hpp"
+
+private _recordTitle = "MDS - INTEL - ENVIRONMENT";
+
+private _text = [
+	format[
+		"<font size='%1' color='%2' face='%3'>%4</font><br/><br/>",
+		GVAR(recordTitleSize),
+		GVAR(recordTitleColor),
+		GVAR(recordTitleFont),
+		_recordTitle
+	]
+];
+
+private _sunriseColor = "#4A86E8";
+private _sunsetColor = "#6AA84F";
+private _whiteColor = "#FFFFFF";
+
+private _sunTimes = date call BIS_fnc_sunriseSunsetTime;
+
+_text pushBack format[
+	"<font size='%1' color='%2'>Local Sunrise</font><br/>
+	<font size='%3' color='%4'>%5</font><br/><br/>",
+	GVAR(recordTextHeaderSize),
+	_sunriseColor,
+	GVAR(recordTextBodySize),
+	_whiteColor,
+	([_sunTimes select 0, "HH:MM"] call BIS_fnc_timeToString)
+];
+
+_text pushBack format[
+	"<font size='%1' color='%2'>Local Sunset</font><br/>
+	<font size='%3' color='%4'>%5</font><br/><br/>",
+	GVAR(recordTextHeaderSize),
+	_sunsetColor,
+	GVAR(recordTextBodySize),
+	_whiteColor,
+	([_sunTimes select 1, "HH:MM"] call BIS_fnc_timeToString)
+];
+
+_text = _text joinString "";
+
+[
+	GVAR(subjectIntelID),
+	_recordTitle,
+	_text
+] call FUNC(createOrUpdateDiaryRecord);

framework/fbcb2_main/functions/fn_processFBCB2RadioFrequencies.sqf

@@ -0,0 +1,73 @@
+// updated 2024-02-01 by IndigoFox
+// now reads from the battalion config structure to generate the diary entries
+
+#include "../script_component.hpp"
+
+////////////////////////////////////////
+// Get info from missionConfigFile
+////////////////////////////////////////
+private _battalionInfoCfg = call EFUNC(util,getBattalionCfg);
+if (isNull _battalionInfoCfg) exitWith {
+	[
+		QUOTE(COMPONENT),
+		"Null Battalion Config",
+		[]
+	] call EFUNC(util,log);
+};
+
+private _battalionElementCfgs = [_battalionInfoCfg >> "Command"] call BIS_fnc_returnChildren;
+if (count _battalionElementCfgs == 0) exitWith {
+	[
+		QUOTE(COMPONENT),
+		"ERROR: No battalion elements found. Check that the battalion config is correctly structured. See defines/BattalionInfo.hpp and framework/util/functions/getBattalionCfg.sqf.",
+		[]
+	] call EFUNC(util,log);
+};
+
+////////////////////////////////////////
+// Define formatting constants
+////////////////////////////////////////
+private _ELEMENT_NAME_SIZE = 10;
+private _ELEMENT_NAME_FONT = "EtelkaMonospaceProBold";
+private _ELEMENT_FREQ_SIZE = 9;
+private _ELEMENT_FREQ_FONT = "EtelkaMonospacePro";
+private _FREQ_INDENT_CONSTANT = 6;
+private _FREQ_PAD_LENGTH = 17;
+private _FREQ_TEXT_COLOR = "#CCCCCC";
+// Note: Element colors are defined in the battalion config
+
+////////////////////////////////////////
+// ADD DIARY ENTRIES
+////////////////////////////////////////
+
+// First is all the battalion-level elements beneath command
+// To have the records listed in the order they appear in the battalion config, we need to reverse the array
+// Since each entry is added to the top of the list, this will result in the entries being added in the correct order
+reverse _battalionElementCfgs;
+
+{
+	diag_log text format[
+		"[%1] <%2> Processing battalion element %3",
+		QUOTE(PREFIX),
+		_fnc_scriptName,
+		configName _x
+	];
+	// recursively generate diary text for all child elements of battalion-level elements
+	private _diaryTitleText = [_x, true] call FUNC(generateElementFrequencyRecordText);
+	[
+		GVAR(subjectFrequenciesID),
+		_diaryTitleText#0,
+		_diaryTitleText#1
+	] call FUNC(createOrUpdateDiaryRecord);
+} forEach _battalionElementCfgs;
+
+// add the battalion command to the top of the list
+// don't process child elements
+private _diaryTitleText = [_battalionInfoCfg >> "Command", false] call FUNC(generateElementFrequencyRecordText);
+[
+	GVAR(subjectFrequenciesID),
+	_diaryTitleText#0,
+	_diaryTitleText#1
+] call FUNC(createOrUpdateDiaryRecord);
+
+true;

framework/fbcb2_main/functions/fn_processFBCB2SmokeColors.sqf

@@ -0,0 +1,43 @@
+#include "../script_component.hpp"
+
+private _recordTitle = "MDS - INTEL - SMOKES";
+
+private _text = [
+	// Title
+	format[
+		"<font size='%1' color='%2' face='%3'>%4</font>",
+		GVAR(recordTitleSize),
+		GVAR(recordTitleColor),
+		GVAR(recordTitleFont),
+		_recordTitle
+	]
+];
+
+private _smokeColors = [
+	["#FFFFFF", "WHITE", "Concealment"],
+	["#008800", "GREEN", "Friendly Forces"],
+	["#0000FF", "BLUE", "LZ Markers"],
+	["#FF0000", "RED", "Enemy Location"],
+	["#FFA500", "ORANGE", "Resupply Marker"],
+	["#FFFF00", "YELLOW", "Medical Emergency"],
+	["#800080", "PURPLE", "Broken Arrow - 100m radius"]
+];
+
+{
+	_x params ["_color", "_name", "_description"];
+	_text pushBack format[
+		"<font size='%1'><font color='%2'>%3</font> - %4</font>",
+		GVAR(recordTextHeaderSize),
+		_color,
+		_name,
+		_description
+	];
+} forEach _smokeColors;
+
+_text = _text joinString "<br/><br/>";
+
+[
+	GVAR(subjectIntelID),
+	_recordTitle,
+	_text
+] call FUNC(createOrUpdateDiaryRecord);

framework/fbcb2_main/script_component.hpp

@@ -0,0 +1,3 @@
+#define COMPONENT fbcb2_main
+#define COMPONENT_BEAUTIFIED FBCB2 - Main
+#include "../script_mod.hpp"

framework/fbcb2_main/util/fn_createOrUpdateDiaryRecord.sqf

@@ -0,0 +1,30 @@
+#include "../script_component.hpp"
+
+if (!hasInterface) exitWith {};
+
+params [
+	["_subjectID", GVAR(subjectStatusID), [""]],
+	["_recordTitle", "", [""]],
+	["_recordText", "", [""]],
+	["_recordIcon", "", [""]]
+];
+
+// Check if already created
+private _subjectRecords = GVAR(diaryRecords) getOrDefault [_subjectID, createHashMap, true];
+private _existingRecord = _subjectRecords getOrDefault [_recordTitle, diaryRecordNull, true];
+
+if (!isNull _existingRecord) then {
+	player setDiaryRecordText [[_subjectID, _existingRecord], [_recordTitle, _recordText, _recordIcon]];
+	systemChat format ["Updated diary record: %1", _recordTitle];
+} else {
+	private _new = player createDiaryRecord [
+		_subjectID, 
+		[
+			_recordTitle, 
+			_recordText,
+			_recordIcon
+		]
+	];
+	_subjectRecords set [_recordTitle, _new];
+	GVAR(diaryRecords) set [_subjectID, _subjectRecords];
+};

framework/fbcb2_main/util/fn_formatRadioElementForDiary.sqf

@@ -0,0 +1,75 @@
+// called from milsim_fnc_processFBCB2RadioFrequencies
+#include "../script_component.hpp"
+
+params ["_cfg", ["_indentCount", 1, [5]]];
+
+//////////////////////////////////////////////////////
+// Define leading space/hyphenation for element name
+//////////////////////////////////////////////////////
+private _leadingSpace = [
+	format["<font size='%1' face='%2'>| ", _ELEMENT_NAME_SIZE, _ELEMENT_NAME_FONT]
+];
+for "_i" from 1 to _indentCount do {
+	_leadingSpace pushBack "-";
+};
+_leadingSpace pushBack " | </font>";
+
+/////////////////////////////////////////////////////////
+// Create the header line for the provided config entry
+/////////////////////////////////////////////////////////
+private _lines = [
+	format[
+		"<font color='%1'>%2%3</font>",
+		getText(_cfg >> "textColor"),
+		_leadingSpace joinString "",
+		getText (_cfg >> "callsign")
+	]
+];
+
+////////////////////////////////////////////////////////////
+// Create the frequency lines for the provided config entry
+////////////////////////////////////////////////////////////
+
+// Generate leading space
+private _freqLeadingSpace = [
+	format["<font size='%1' face='%2'>| ", _ELEMENT_NAME_SIZE, _ELEMENT_NAME_FONT]
+];
+for "_i" from 1 to _FREQ_INDENT_CONSTANT do {
+	_freqLeadingSpace pushBack " ";
+};
+_freqLeadingSpace pushBack "</font>";
+_freqLeadingSpace = _freqLeadingSpace joinString "";
+
+// Process config values for frequencies
+{
+	_x params ["_role", "_sr", "_lr"];
+
+
+	private ["_srStr", "_lrStr"];
+	if (count _sr > 0) then {
+		_srStr = format["%1", _sr joinString " / "];
+	} else {
+		_srStr = "----";
+	};
+	if (count _lr > 0) then {
+		_lrStr = format["%1", _lr joinString " / "];
+	} else {
+		_lrStr = "----";
+	};
+
+	// Add formatted line to the array
+	_lines pushBack format[
+		"%1<font size='%2' face='%3' color='%4'>- %5%6%7</font>",
+		_freqLeadingSpace,
+		_ELEMENT_FREQ_SIZE,
+		_ELEMENT_FREQ_FONT,
+		_FREQ_TEXT_COLOR,
+		[_role, "right", " ", _FREQ_PAD_LENGTH] call EFUNC(util,padString),
+		[_srStr, "right", " ", _FREQ_PAD_LENGTH] call EFUNC(util,padString),
+		_lrStr
+	];
+} forEach (getArray (_cfg >> "frequencies"));
+// diag_log text (_lines joinString endl);
+
+// Return the formatted lines in ARRAY format
+_lines;

framework/fbcb2_main/util/fn_generateElementFrequencyRecordText.sqf

@@ -0,0 +1,102 @@
+// called from milsim_fnc_processFBCB2RadioFrequencies ONLY
+// this function is called recursively to process all child elements of a battalion element in missionConfigFile
+
+#include "../script_component.hpp"
+
+params [
+	["_elementCfg", configNull, [configNull]],
+	["_shouldProcessChildCfgs", true]
+];
+
+if (isNull _elementCfg) exitWith {
+	["_elementCfg parameter is NULL"] call BIS_fnc_error;
+};
+
+// change reference variable for clarity
+private _battalionElement = _elementCfg;
+
+// Generate title from callsign and shortDescription
+private _recordTitle = format[
+	"%1 (%2)",
+	getText(_battalionElement >> "callsign"),
+	getText(_battalionElement >> "shortDescription")
+];
+// systemChat _recordTitle;
+
+
+//////////////////////////////////////////////////////////
+// Generate frequency table header line's leading space
+//////////////////////////////////////////////////////////
+private _freqLeadingSpace = [
+	format["<font size='%1' face='%2'>| ", _ELEMENT_NAME_SIZE, _ELEMENT_NAME_FONT]
+];
+for "_i" from 1 to _FREQ_INDENT_CONSTANT do {
+	_freqLeadingSpace pushBack " ";
+};
+_freqLeadingSpace pushBack "</font>";
+_freqLeadingSpace = _freqLeadingSpace joinString "";
+
+//////////////////////////////////////////////////////////
+// Generate header line and frequency table header line
+//////////////////////////////////////////////////////////
+
+private _headers = [
+	format[
+		"<font size='%1' color='%2' face='%3'>%4</font>",
+		GVAR(recordTitleSize),
+		GVAR(recordTitleColor),
+		GVAR(recordTitleFont),
+		_recordTitle
+	],
+	format[
+		"%1<font size='%2' face='%3' color='%4'>- %5%6%7</font>",
+		_freqLeadingSpace,
+		_ELEMENT_FREQ_SIZE,
+		_ELEMENT_FREQ_FONT,
+		_FREQ_TEXT_COLOR,
+		["ROLE", "right", " ", _FREQ_PAD_LENGTH] call EFUNC(util,padString),
+		["SR", "right", " ", _FREQ_PAD_LENGTH] call EFUNC(util,padString),
+		"LR"
+	]
+];
+
+
+//////////////////////////////////////////////////////////
+// Generate the list of element headers and frequencies
+//////////////////////////////////////////////////////////
+private _allText = [];
+
+// get all child elements recursively and format them
+if (_shouldProcessChildCfgs) then {
+	diag_log text format[
+		"[%1] <%2> Processing %3",
+		QUOTE(PREFIX),
+		_fnc_scriptName,
+		configName _battalionElement
+	];
+	[_battalionElement, {
+		params ["_cfg", "_recurseCounter"];
+		// add config
+		private _lines = [_cfg, _recurseCounter+1] call FUNC(formatRadioElementForDiary);
+		// private _lines = [_cfg, _indentCount] call t;
+		_allText pushBack (_lines joinString "<br/>");
+	}] call EFUNC(util,recurseSubclasses);
+} else {
+	diag_log text format[
+		"[%1] <%2> Processing %3",
+		QUOTE(PREFIX),
+		_fnc_scriptName,
+		configName _battalionElement
+	];
+	// or if the param was false, just add the battalion element
+	private _lines = [_battalionElement, 1] call FUNC(formatRadioElementForDiary);
+	// private _lines = [_cfg, _indentCount] call t;
+	_allText pushBack (_lines joinString "<br/>");
+};
+
+// add headers, add all other lines and format them as monospace
+_allText = format[
+	"%1<br/><br/><font face='EtelkaMonospaceProBold'>%2</font>", _headers joinString "<br/>", _allText joinString "<br/><br/>"];
+
+// return the title and all text
+[_recordTitle, _allText];