Merge pull request 'Draw 3D icons representing triage status of unconscious units (visible to medics only)' (#4) from feature/triagestatus-draw3d into main

Reviewed-on: https://17th-gs.iceberg-gaming.com:5443/hizumi/MissionTemplate/pulls/4

CHANGELOG.md

@@ -4,6 +4,14 @@ All notable changes to this project will be documented in this file.
 
 The format is based on [Keep a Changelog](https://keepachangelog.com/en/1.0.0/), and this project badly attempts [Semantic Versioning](https://semver.org/spec/v2.0.0.html).
 
+## [3.1.2] - 2024-01-04
+
+### Added
+- Add forgotten code file file for medical overlay
+
+### Changed
+- Merge update-flag-exclusions branch to fix issues with vehicles not applying flag
+
 ## [3.1.1] - 2024-01-04
 
 ### Changed

functions/CfgFunctions.hpp

@@ -32,6 +32,7 @@ class milsim
 		class bindEventHandlers { postInit = 1; };
 		class bindVehicleActions { postInit = 1; };
 		class addClientStatsPFH {};
+		class addMedicalOverlayPFH { postInit = 1; };
 		class calculateClientStats {};
 		class initVehicleFlags { postInit = 1; };
 		class bindEmptyGroupGarbageCleanup { postInit = 1; };

functions/client/fn_addClientStatsPFH.sqf

@@ -8,7 +8,7 @@ _cpsPFH = [
 	},
 	"milsim_client_cps_interval" call CBA_settings_fnc_get,
 	[],
-	{ diag_log text format ["[MILSIM] (client) PFH loaded with interval %1 seconds", "milsim_client_cps_interval" call CBA_settings_fnc_get ], },
+	{ diag_log text format ["[MILSIM] (client) PFH loaded with interval %1 seconds", "milsim_client_cps_interval" call CBA_settings_fnc_get ] },
 	{ diag_log text format ["[MILSIM] (client) PFH unloaded"] },
 	{ "milsim_client_cps_enable" call CBA_settings_fnc_get },
 	{ false },

functions/client/fn_addMedicalOverlayPFH.sqf

@@ -0,0 +1,93 @@
+/*
+
+milsim_fnc_addMedicalOverlayPFH
+
+Author: IndigoFox
+
+Description:
+    Affects players with medical permissions. Will see a 3D colored dot over nearby (5-10m)
+	unconscious players who are not in a vehicle
+	which indicates their current ACE Triage Card status.
+	Designed to increase efficiency of CCPs.
+
+*/
+
+// Force setting if CBA doesn't work?
+if (isNil "milsim_client_medState3D_enabled") then {
+	milsim_client_medState3D_enabled = true;
+};
+if (isNil "milsim_client_medState3D_drawRange") then {
+	milsim_client_medState3D_drawRange = 10;
+};
+
+// List of units to draw icons for
+milsim_client_medState3D_drawTargets = []; 
+
+// ACE Triage colors, for consistency across UIs and functions
+// #define TRIAGE_COLOR_NONE      0.5, 0.5, 0.5, 0.1
+// #define TRIAGE_COLOR_MINIMAL   0, 0.5, 0, 0.9
+// #define TRIAGE_COLOR_DELAYED   1, 0.84, 0, 0.9
+// #define TRIAGE_COLOR_IMMEDIATE 1, 0, 0, 0.9
+// #define TRIAGE_COLOR_DECEASED  0, 0, 0, 0.9
+
+// ACE Triage colors, for consistency across UIs and functions
+milsim_client_medState3D_colors = [
+	[0, 0.5, 0, 0.9], // TRIAGE_COLOR_MINIMAL
+	[1, 0.84, 0, 0.9], // TRIAGE_COLOR_DELAYED
+	[1, 0, 0, 0.9], // TRIAGE_COLOR_IMMEDIATE
+	[0, 0, 0, 0.9], // TRIAGE_COLOR_DECEASED
+	[0.5, 0.5, 0.5, 0] // TRIAGE_COLOR_NONE
+];
+
+// Per-frame handler to draw icons
+// cleanup
+[milsim_client_medState3D_drawTargetsPfh] call CBA_fnc_removePerFrameHandler;
+// add pfh
+milsim_client_medState3D_pfh =	[{
+	// if disabled, skip processing
+	if (!milsim_client_medState3D_enabled) exitWith {false};
+	// if no targets, skip processing
+	if (count milsim_client_medState3D_drawTargets == 0) exitWith {false};
+	if !([player] call ace_medical_treatment_fnc_isMedic) exitWith {false};
+	{
+		// distance within 10 meters
+		if (player distance _x > milsim_client_medState3D_drawRange) then {continue};
+		// check unit not null, not conscious, and not in a vehicle
+		if (
+			!(_x getVariable ["ACE_isUnconscious", false]) ||
+			!isNull (objectParent _x)
+		) then {continue};
+
+		// color based on triage level
+		private _color = milsim_client_medState3D_colors select (
+			(_x getVariable ["ace_medical_triageLevel", -1]) -1
+		);
+		// draw position, slightly above the prone unit
+		private _drawPos = (visiblePosition _x) vectorAdd [0, 0, 0.5];
+		// draw icon
+		drawIcon3D [
+			"\A3\ui_f\data\map\markers\military\dot_CA.paa", // icon texture
+			_color, // color
+			_drawPos, // position AGL
+			1, // width
+			1, // height
+			0 // angle
+			// further params optional, omitted
+		];
+	} forEach milsim_client_medState3D_drawTargets;
+}, 0, []] call CBA_fnc_addPerFrameHandler;
+
+// subroutine to gather nearest 50 units every 5 seconds and store in milsim_client_medState3D_drawTargets
+// cleanup
+[milsim_client_medState3D_drawTargetsPfh] call CBA_fnc_removePerFrameHandler;
+// add pfh
+milsim_client_medState3D_drawTargetsPfh = [{
+	milsim_client_medState3D_drawTargets = (
+		(allUnits + allDeadMen) select {
+			_x isKindOf "CAManBase" && 
+			player distance _x < 50 &&
+			!isNull _x &&
+			player isNotEqualTo _x
+		}
+	);
+}, 5, false] call CBA_fnc_addPerFrameHandler;

functions/client/fn_initVehicleFlags.sqf

@@ -85,6 +85,16 @@ private _appliedParentClasses = [
 	"Helicopter"
 ];
 
+private _modelsWithoutFlagProxies = [
+	"TF373_SOAR_MH47G_Base", // MH-47G Chinook
+	"RHS_MELB_base", // MELB AH-6M/MH-6M/H-6M Little Bird
+	"USAF_C17", // C17 Globemaster III
+	"USAF_C130J", // C130J Super Hercules
+	"USAF_AC130U", // AC130 Spooky II
+	"ej_UH60M_base", // UH-60M Black Hawk + DAP variants
+	"rhsusf_fmtv_base" // M1083A1P2 variants + SOV SOCOM variants
+];
+
 {
 	private _parentClass = _x;
 	[_parentClass, "InitPost", {
@@ -94,7 +104,22 @@ private _appliedParentClasses = [
 			"Set Vehicle Flag", // displayed title
 			"\A3\ui_f\data\map\markers\flags\nato_ca.paa", // flag icon
 			{true}, // statement
-			{true}, // condition
+			{
+				params ["_target", "_player", "_params"];
+				private _modelsWithoutFlagProxies = _params select 1;
+				
+				// check if hierarchy includes any of the models without flag proxies
+				private _excluded = false;
+				{
+					if (_excluded) exitWith {false};
+					_excluded = _target isKindOf _x;
+				} forEach _modelsWithoutFlagProxies;
+				if (_excluded) exitWith {false};
+				
+
+				// check if vehicle is alive
+				alive _target;
+			}, // condition
 			{
 				params ["_target", "_player", "_params"];
 				private _flagActionID = _params#0;
@@ -155,7 +180,7 @@ private _appliedParentClasses = [
 
 				_actions;
 			}, // child code
-			[_flagActionID], // params
+			[_flagActionID, _modelsWithoutFlagProxies], // params
 			nil, // position
 			4, // distance
 			[false, false, false, false, false], // other params
@@ -180,7 +205,10 @@ private _appliedParentClasses = [
 				params ["_target", "_player", "_params"];
 				_target forceFlagTexture "";
 			}, // statement
-			{true}, // condition
+			{
+				params ["_target", "_player", "_params"];
+				alive _target && getForcedFlagTexture _target != "";
+			}, // condition
 			nil // child code
 		] call ace_interact_menu_fnc_createAction;
 

functions/server/fn_logPlayerInventory.sqf

@@ -3,7 +3,7 @@ params [
 	["_player", objNull, [objNull]]
 ];
 
-if (!isPlayer _player) exitWith { diag_log("exitWith inventotry")};
+if (!isPlayer _player) exitWith { diag_log("exitWith logPlayerInventory")};
 
 _items = [];
 _items append uniformItems _player;
@@ -13,6 +13,9 @@ _items pushback hmd _player;
 _items pushback binocular _player;
 _items append primaryWeaponItems _player;
 
+_noncompliant = [];
+_unlisted = [];
+
 {
 	_item = _x;
 	_modes = getArray(configfile >> "CfgWeapons" >> _item >> "visionMode");
@@ -26,15 +29,28 @@ _items append primaryWeaponItems _player;
 	_restrictedItemList = ["A3_GPNVG18b_REC_TI","A3_GPNVG18_REC_TI","A3_GPNVG18b_TI","A3_GPNVG18_TI","A3_GPNVG18b_REC_BLK_TI","A3_GPNVG18_REC_BLK_TI","A3_GPNVG18b_BLK_TI","A3_GPNVG18_BLK_TI","NVGogglesB_gry_F","NVGogglesB_grn_F","NVGogglesB_blk_F","optic_Nightstalker","rhsusf_acc_anpas13gv1","Tier1_ANPVS10_Tan","rhsusf_acc_anpvs27","optic_tws_mg","optic_tws"];
 
 	if ( _x in _restrictedItemList ) then {
-		diag_log text format["[MILSIM] (logPlayerInventory): %1 has a restricted inventory item: %2", name _player, getText( configfile >> "CfgWeapons" >> _item >> "displayName" )];
-	} else if ((count _modes) isNotEqualTo 0) then {
+		_noncompliant pushBackUnique _item;
+	};
+	
+	if ((count _modes) isNotEqualTo 0) then {
 		_modes = _modes apply { toLower _x };
 		if ( "ti" in _modes ) then {	
-			diag_log text format["[MILSIM] (logPlayerInventory): %1 has an unlisted thermal item: %2", name _player, getText( configfile >> "CfgWeapons" >> _item >> "displayName" )];
+			_unlisted pushBackUnique _item;
 		};
-	} else {
-		diag_log text format["[MILSIM] (logPlayerInventory): %1 inventory in compliance", name _player];
-	}
+	};
+
 } forEach _items;
 
+{
+	diag_log text format["[MILSIM] (logPlayerInventory): %1 has a restricted inventory item: %2", name _player, getText( configfile >> "CfgWeapons" >> _x >> "displayName" )];
+} forEach _noncompliant;
+
+{
+	diag_log text format["[MILSIM] (logPlayerInventory): %1 has an unlisted thermal item: %2", name _player, getText( configfile >> "CfgWeapons" >> _x >> "displayName" )];	
+} forEach _unlisted;
+
+if (((count _noncompliant) isEqualTo 0) && ((count _unlisted) isEqualTo 0)) then {
+	diag_log text format["[MILSIM] (logPlayerInventory): %1 inventory in compliance", name _player];
+};
+
 nil

functions/settings/fn_addCBASettings.sqf

@@ -104,6 +104,26 @@
 	}
 ] call CBA_fnc_addSetting;
 
+//---------------------
+//	Medical Overlay
+//---------------------
+
+[
+	"milsim_client_medState3D_enabled", // variable
+	"CHECKBOX", // type
+	["Enable 3D Triage Card State", "Draws a colored dot over units within 10m indicating current ACE Triage State"], // title
+	["17th Battalion", "Medical"], // category
+	true // default value
+] call CBA_fnc_addSetting;
+
+[
+	"milsim_client_medState3D_drawRange", // variable
+	"LIST", // type
+	["Range To Draw Icons", "Determines range at which dots are visible"], // title
+	["17th Battalion", "Medical"], // category
+	[[2, 4, 6, 8, 10], ["2", "4", "6", "8", "10"], 4] // option values, option labels, default index
+] call CBA_fnc_addSetting;
+
 
 diag_log text "[MILSIM] (settings) Custom CBA settings initialized";