#include "..\script_component.hpp"

private _rootAction = [
	QGVAR(action_deploy),
	"Deploy EMP Device",
	"",
	{
		params ["_target", "_player", "_params"];
		true;
	},
	{true},
	{
		params ["_target", "_player", "_params"];
		private _childActions = [];
		{
			private _radius = _x;
			private _action = [
				format["%1_%2", QGVAR(action_deploy), _radius],
				format["Deploy EMP Device (%1m)", _radius],
				"",
				{
					params ["_target", "_player", "_params"];
					_params params ["_radius"];
					[GVAR(empDevice1), _radius] call FUNC(deploy);
				},
				{!isNull (missionNamespace getVariable [QGVAR(empDevice1), objNull]);},
				nil,
				[_radius]
			] call ace_interact_menu_fnc_createAction;
			[
				LEVEL_TRACE,
				QUOTE(COMPONENT),
				format["parsed child action: %1", _action]
			] call EFUNC(common,log);
			_childActions pushBack _action;
			false
		} count [100,500,3000];
		[
			LEVEL_TRACE,
			QUOTE(COMPONENT),
			format["parsed child actions: %1", _childActions]
		] call EFUNC(common,log);

		_childActions;
	}
] call ace_interact_menu_fnc_createAction;
["CAManBase", 1, ["ACE_SelfActions"], _rootAction, true] call ace_interact_menu_fnc_addActionToClass;