[
	"17th Battalion",
	"Create Resupply Box", 
	{
		params [["_pos", [0,0,0], [[]], 3], ["_target", objNull, [objNull]]];
		
		[
			"Resupply Box Options",
			[
				[ "COMBO", "Box Type", [[1,2,3], [["Ammo"],["Weapons"],["Medical"]],0] ]
			],
			{
				
				params ["_dialog", "_args"];
				
				_dialog params ["_type"];
				_args params ["_pos", "_target"];
						
				switch (_type) do {
					case 1: {
						[_target, _pos] call milsim_fnc_createAmmoBox;
					};
					case 2: {
						[_target, _pos] call milsim_fnc_createWeaponsBox;
					};
					case 3: {
						[_target, _pos] call milsim_fnc_createMedicalBox;
					};
				};
			},
			{},
			[_pos, _target]
		] call zen_dialog_fnc_create;

	}
] call zen_custom_modules_fnc_register;


[
	"17th Battalion",
	"Grounds Cleanup2", 
	{
		params [["_pos", [0,0,0], [[]], 3], ["_target", objNull, [objNull]]];
		
		_pos = [_pos#0, _pos#1, 0];
		
		[
			"Cleanup Area",
			[
				[ "SLIDER:RADIUS", "Radius (meters)", [50, 500, 100, 0, _pos, [0.8, 0.2, 0.2, 1.0]], true ]
			],
			{
				
				params ["_dialog", "_args"];
				
				_dialog params ["_radius"];
				_args params ["_pos", "_target"];
						
				_objects = _pos nearObjects ["GroundWeaponHolder", _radius];
				{
					deleteVehicle _x;
				} forEach _objects

			},
			{},
			[_pos, _target]
		] call zen_dialog_fnc_create;

	}
] call zen_custom_modules_fnc_register;