#include "..\script_component.hpp"

[
	LEVEL_INFO,
	QUOTE(COMPONENT),
	"Initializing empty group deletion PFH",
	[]
] call EFUNC(common,log);

GVAR(emptyGroupCleanupPFH) = [
	{ 
		{
			if ((count units _x) == 0) then {
				if (local _x) then {
					[
						LEVEL_INFO,
						QUOTE(COMPONENT),
						"DELETING EMPTY GROUP",
						[
							["groupId", groupId _x],
							["netId", netId _x]
						]
					] call EFUNC(common,log);
					deleteGroup _x;
				} else {
					if (isServer) then {
						[
							LEVEL_INFO,
							QUOTE(COMPONENT),
							"NON LOCAL EMPTY GROUP",
 							[
								["groupId", groupId _x],
								["groupOwner", groupOwner _x]
							]
						] call EFUNC(common,log);
					} else {
						[
							LEVEL_INFO,
							QUOTE(COMPONENT),
							"EMPTY REMOTE GROUP",
							[
								["groupId", groupId _x]
							]
						] call EFUNC(common,log);
					};
				};
			};
		} forEach allGroups;
	},
	300,
	[],
	{ // on creation
		[
			LEVEL_INFO,
			QUOTE(COMPONENT),
			"Empty group deletion PFH loaded",
			[]
		] call EFUNC(common,log);
	},
	{ // on deletion
		[
			LEVEL_INFO,
			QUOTE(COMPONENT),
			"Empty group deletion PFH unloaded",
			[]
		] call EFUNC(common,log);
	},
	{ (missionNamespace getVariable [QGVAR(emptyGroupCleanup_enable), false]) },
	{ not (missionNamespace getVariable [QGVAR(emptyGroupCleanup_enable), false]) },
	[]
] call CBA_fnc_createPerFrameHandlerObject;