if (!isServer) exitWith {};

milsim_baseObjects = allMissionObjects "ModuleRespawnPosition_F";
publicVariable "milsim_baseObjects";

// init asset stores at bases
[true] call milsim_fbcb2_assets_fnc_updateAssetsByBase;
// starting 5 minutes after postInit, update asset stores every 5 minutes
[{
	[
		{[false] call milsim_fbcb2_assets_fnc_updateAssetsByBase;},
		60*5
	] call CBA_fnc_addPerFrameHandler;
}, 60*5] call CBA_fnc_waitAndExecute;

// add end mission EH
addMissionEventHandler ["MPEnded", {
	// log the "current" asset counts to RPT
	[false, true] call milsim_fbcb2_assets_fnc_updateAssetsByBase;
}];

// Initializes the Dynamic Groups framework and groups
["Initialize", [true]] call BIS_fnc_dynamicGroups;

["milsim_logText", {
	params [["_strArray", [""], [[]]]];
	{
		diag_log text _x;
	} forEach _strArray;
}] call CBA_fnc_addEventHandler;

missionNamespace setVariable ["milsim_complete", true];
diag_log text "[MILSIM] (initServer) milsim_complete: version 2.3";

publicVariable "milsim_complete";