#include "..\script_component.hpp"

private _recordTitle = "MDS - INTEL - ENVIRONMENT";

private _text = [
	format[
		"<font size='%1' color='%2' face='%3'>%4</font><br/><br/>",
		GVAR(recordTitleSize),
		GVAR(recordTitleColor),
		GVAR(recordTitleFont),
		_recordTitle
	]
];

private _sunriseColor = "#4A86E8";
private _sunsetColor = "#6AA84F";
private _whiteColor = "#FFFFFF";

private _sunTimes = date call BIS_fnc_sunriseSunsetTime;

_text pushBack format[
	"<font size='%1' color='%2'>Local Sunrise</font><br/>
	<font size='%3' color='%4'>%5</font><br/><br/>",
	GVAR(recordTextHeaderSize),
	_sunriseColor,
	GVAR(recordTextBodySize),
	_whiteColor,
	([_sunTimes select 0, "HH:MM"] call BIS_fnc_timeToString)
];

_text pushBack format[
	"<font size='%1' color='%2'>Local Sunset</font><br/>
	<font size='%3' color='%4'>%5</font><br/><br/>",
	GVAR(recordTextHeaderSize),
	_sunsetColor,
	GVAR(recordTextBodySize),
	_whiteColor,
	([_sunTimes select 1, "HH:MM"] call BIS_fnc_timeToString)
];

_text = _text joinString "";

[
	GVAR(subjectIntelID),
	_recordTitle,
	_text
] call FUNC(createOrUpdateDiaryRecord);