skip large blue spark on objects

description.ext

@@ -95,7 +95,13 @@ class Params
 
 
 // CfgFunctions
+class CfgFunctions {
 	#include "framework\CfgFunctions.hpp"
+};
+
+class CfgSounds {
+	#include "framework\emp\CfgSounds.hpp"
+};
 
 
 

framework/CfgFunctions.hpp

@@ -1,7 +1,5 @@
 #include "script_mod.hpp"
 
-class CfgFunctions {
-
 class DOUBLES(PREFIX,init) {
 	class functions {
 		file = "framework\init\functions";
@@ -50,6 +48,29 @@ class CfgFunctions {
 	};
 };
 
+class DOUBLES(PREFIX,emp) {
+	class functions {
+		file = "framework\emp\functions";
+		// class addCBASettings {preInit=1;};
+		class init {};
+		class addACEActions {};
+
+		class applyLocalObjectEffects {};
+		class applyLocalGroupEffects {};
+		class applyGlobalObjectEffects {};
+		class applyServerObjectEffects {};
+
+		class deploy {};
+		class getObjectsAndGroupsToAffect {};
+		class playLocalEffects {};
+		class playLocalEffectsForObject {};
+
+		class isItemElectronic {};
+		class removeUnitElectricInventoryItems {};
+		class removeVehicleElectricInventoryItems {};
+	};
+};
+
 class DOUBLES(PREFIX,fbcb2_assets) {
 	class functions {
 		file = "framework\fbcb2_assets\functions";
@@ -177,4 +198,3 @@ class CfgFunctions {
 		class addZenModules {};
 	};
 };
-};

framework/common/functions/fn_log.sqf

@@ -27,7 +27,16 @@ private _hash = createHashMapFromArray _data;
 _message regexReplace ['(\[)', "("];
 _message regexReplace ['(\])', ")"];
 
+private _levelText = switch (_logLevel) do {
+	case (_logLevel isEqualTo -1) : {"TRACE"};
+	case (_logLevel isEqualTo 0) : {"DEBUG"};
+	case (_logLevel isEqualTo 1) : {"INFO"};
+	case (_logLevel isEqualTo 2) : {"WARN"};
+	case (_logLevel isEqualTo 3) : {"ERROR"};
+	default {"INFO"};
+};
+
 private _json = [_hash] call CBA_fnc_encodeJSON;
-_log = format ["[%1] [%2] [%3] [%4] :: %5", QUOTE(PREFIX), _component, _fnc_scriptNameParent, _message, _json];
+_log = format ["[%1] [%2] [%3] [%4] [%5] :: %6", QUOTE(PREFIX), _component, _fnc_scriptNameParent, _levelText, _message, _json];
 
 diag_log text _log;

framework/emp/CfgSounds.hpp

@@ -0,0 +1,37 @@
+#include "script_component.hpp"
+
+class GVAR(sound_zap1) {
+	name = QGVAR(sound_zap1);
+	sound[] = {"framework\emp\sounds\zap1.wss", db+10, 1};
+	titles[] = {};
+};
+class GVAR(sound_zap2) {
+	name = QGVAR(sound_zap2);
+	sound[] = {"framework\emp\sounds\zap2.wss", db+10, 1};
+	titles[] = {};
+};	
+class GVAR(sound_zap3) {
+	name = QGVAR(sound_zap3);
+	sound[] = {"framework\emp\sounds\zap3.wss", db+10, 1};
+	titles[] = {};
+};
+class GVAR(sound_zap4) {
+	name = QGVAR(sound_zap4);
+	sound[] = {"framework\emp\sounds\zap4.wss", db+10, 1};
+	titles[] = {};
+};
+class GVAR(sound_electric_explsion_impact_large) {
+	name = QGVAR(sound_electric_explsion_impact_large); 
+	sound[] = {"framework\emp\sounds\electric_explsion_impact_large.wss", db+750, 1};
+	titles[] = {};
+};
+class GVAR(sound_echo3) {
+	name = QGVAR(sound_echo3);
+	sound[] = {"framework\emp\sounds\echo3.wss", db+500, 1};
+	titles[] = {1,""};
+};
+class GVAR(sound_ecou) {
+	name = QGVAR(sound_ecou); 
+	sound[] = {"framework\emp\sounds\ecou.wss", db+100, 1};
+	titles[] = {1,""};
+};

framework/emp/functions/fn_addACEActions.sqf

@@ -0,0 +1,38 @@
+#include "..\script_component.hpp"
+
+if (!hasInterface) exitWith {};
+
+private _rootAction = [
+	QGVAR(action_deploy),
+	"Deploy EMP Device",
+	"",
+	{
+		params ["_target", "_player", "_params"];
+		true;
+	},
+	{true},
+	{
+		params ["_target", "_player", "_params"];
+		private _childActions = [];
+		{
+			private _radius = _x;
+			private _action = [
+				format["%1_%2", QGVAR(action_deploy), _radius],
+				format["Deploy EMP Device (%1m)", _radius],
+				"",
+				{
+					params ["_target", "_player", "_params"];
+					_params params ["_radius"];
+					[GVAR(empDevice1), _radius] call FUNC(deploy);
+				},
+				{!isNull (missionNamespace getVariable [QGVAR(empDevice1), objNull]);},
+				nil,
+				[_radius]
+			] call ace_interact_menu_fnc_createAction;
+			_childActions pushBack [_action, [], _target];
+			false
+		} count [100,500,3000];
+		_childActions;
+	}
+] call ace_interact_menu_fnc_createAction;
+["CAManBase", 1, ["ACE_SelfActions"], _rootAction, true] call ace_interact_menu_fnc_addActionToClass;

framework/emp/functions/fn_applyGlobalObjectEffects.sqf

@@ -0,0 +1,35 @@
+#include "..\script_component.hpp"
+
+// Executed on all machines - global argument, local effect
+// The effects must be applied on all machines
+
+params [["_object", objNull, [objNull]]];
+if (isNull _object) exitWith {};
+
+_object setHitPointDamage ["hitturret",1]; 
+_object setHitPointDamage ["hitcomturret",1]; 
+_object setHitPointDamage ["hitcomgun",1]; 
+_object setHitPointDamage ["#light_hitpoint",1];
+_object setHitPointDamage ["HitBatteries",1]; 
+_object setHitPointDamage ["HitLight",1]; 
+_object setHitPointDamage ["#light_l",1];
+_object setHitPointDamage ["#light_r",1];
+_object setHitPointDamage ["#light_l_flare",1];
+_object setHitPointDamage ["#light_r_flare",1];
+_object setHitPointDamage ["light_l",1]; 
+_object setHitPointDamage ["light_r",1]; 
+_object setHitPointDamage ["light_l2",1]; 
+_object setHitPointDamage ["light_r2",1]; 
+_object setHitPointDamage ["hitEngine",1];  
+_object setHitPointDamage ["hitengine",1]; 
+_object setHitPointDamage ["hitengine1",1];
+_object setHitPointDamage ["hitengine2",1];
+_object setHitPointDamage ["hitengine3",1];
+_object setHitPointDamage ["HitEngine2",1];
+_object setHitPointDamage ["HitAvionics",1];
+_object setHitPointDamage ["HitHRotor",1];
+_object setHitPointDamage ["HitVRotor",1];
+_object setHitPointDamage ["HitHydraulics",1];
+_object setHitPointDamage ["HitHStabilizerL1",1];
+_object setHitPointDamage ["HitHStabilizerR1",1];
+_object setHitPointDamage ["HitVStabilizer1",1];

framework/emp/functions/fn_applyLocalGroupEffects.sqf

@@ -0,0 +1,9 @@
+#include "..\script_component.hpp"
+
+params [["_group", grpNull, [grpNull]]];
+if (isNull _group) exitWith {};
+if !(local _group) exitWith {};
+
+//set gunlight status
+_group enableGunLights "forceOff";
+_group enableIRLasers true;

framework/emp/functions/fn_applyLocalObjectEffects.sqf

@@ -0,0 +1,28 @@
+#include "..\script_component.hpp"
+
+// Executed on all clients, only continue if object is local.
+// Local argument, global effect (the object owner broadcasts new state)
+
+params [["_object", objNull, [objNull]]];
+if (isNull _object) exitWith {};
+if !(local _object) exitWith {};
+
+_object disableAI "LIGHTS"; 
+_object setPilotLight false;  
+_object setCollisionLight false;
+
+if (_object isKindOf "CAManBase") then {
+	[_object] call FUNC(removeUnitElectricInventoryItems);
+} else {
+	[_object] call FUNC(removeVehicleElectricInventoryItems);
+};
+
+[{ // once flicker effects are done, permanently disable lights
+	private _flickerHandle = _object getVariable QGVAR(flickerHandle);
+	!isNil "_flickerHandle" && {scriptDone _flickerHandle}
+}, {
+	_object setHit ["light_1_hitpoint", 0.97]; //all possible light hitpoints
+	_object setHit ["light_2_hitpoint", 0.97]; //no lights escape this
+	_object setHit ["light_3_hitpoint", 0.97];
+	_object setHit ["light_4_hitpoint", 0.97];
+}] call CBA_fnc_waitUntilAndExecute;

framework/emp/functions/fn_applyServerObjectEffects.sqf

@@ -0,0 +1,13 @@
+#include "..\script_component.hpp"
+
+// Executed on server only, global argument and global effect
+// The server makes the change and broadcasts new state to all clients
+
+if (!isServer) exitWith {};
+
+params [["_object", objNull, [objNull]]];
+if (isNull _object) exitWith {};
+
+_object disableTIEquipment true; 
+_object disableNVGEquipment true;
+_object setVariable ["A3TI_Disable", true, true];

framework/emp/functions/fn_deploy.sqf

@@ -0,0 +1,31 @@
+#include "..\script_component.hpp"
+
+// This function is used to deploy an EMP device and trigger the EMP effects on all machines
+// The EMP effect is triggered by the global event "QGVAR(event_empDeployed)"
+// This function should be called on the server
+
+if (!isServer) exitWith {};
+
+//get center and radius
+params [["_origin", objNull, [[], objNull]],["_radius",1500, [300]]];
+
+if (_origin isEqualType []) then {
+  if (count _origin != 3) exitWith {
+    ["Invalid origin position provided (%1)", _origin] call BIS_fnc_error;
+  };
+};
+
+if (_origin isEqualType objNull) then {
+  if (isNull _origin) exitWith {
+    ["No origin object or position provided (%1)", _origin] call BIS_fnc_error;
+  };
+  _origin = getPosASL _origin;
+};
+
+[QGVAR(event_empDeployedPreCheck), [
+  random 100000,
+  _origin,
+  _radius
+]] call CBA_fnc_globalEvent;
+
+true;

framework/emp/functions/fn_getObjectsAndGroupsToAffect.sqf

@@ -0,0 +1,68 @@
+#include "..\script_component.hpp"
+
+// This function will gather objects to be affected by the EMP blast
+// It will return an array of objects within the radius of the EMP blast
+
+params [["_origin", objNull, [[], objNull]],["_radius",1500]];
+
+if (_origin isEqualType []) then {
+  if (count _origin != 3) exitWith {
+    ["Invalid origin position provided (%1)", _origin] call BIS_fnc_error;
+  };
+};
+
+if (_origin isEqualType objNull) then {
+  if (isNull _origin) exitWith {
+    ["No origin object or position provided (%1)", _origin] call BIS_fnc_error;
+  };
+  _origin = getPosASL _origin;
+};
+
+//search for and return objects
+private _objectsToAffect = nearestObjects [
+	_origin,
+	[
+		"Car",
+		"Motorcycle",
+		"UAV",
+		"Tank",
+		"Air",
+		"Ship",
+		"StreetLamp",
+		"Lamps_base_F", //These are all the lights' base classes
+		"PowerLines_base_F",
+		"PowerLines_Small_base_F",
+		"Land_TTowerBig_1_F",
+		"Land_TTowerBig_2_F",
+		"Land_fs_roof_F",
+		"Land_NavigLight",
+		"PowerLines_Wires_base_F",
+		"Land_PowerPoleWooden_L_F",
+		"Land_Runway_PAPI",
+		"Land_fs_sign_F",
+		"Land_FuelStation_01_roof_malevil_F",
+		"Land_FuelStation_01_roof_F",
+		"Lamps",
+		"Helicopter",
+		"Plane",
+		"Autonomous",
+		"Armored",
+		"Land_MobileRadar_01_radar_F",
+		"Land_Camping_Light_F",
+		"Land_PowLines_WoodL",
+		"Land_A_GeneralStore_01",
+		"Land_A_GeneralStore_01a",
+		"Land_Mil_Guardhouse",
+		"Land_NAV_Lighthouse",
+		"Land_Mil_House",
+		"Land_LightHouse_F",
+		"Land_Hospital_side2_F"
+	],
+	_radius
+];
+
+private	_affectedLocalGroups = _objectsToAffect apply {group _x};
+_affectedLocalGroups = _affectedLocalGroups arrayIntersect _affectedLocalGroups;
+_affectedLocalGroups = _affectedLocalGroups select {local _x} select {!isPlayer (leader _x)};
+
+[_objectsToAffect, _affectedLocalGroups];

framework/emp/functions/fn_init.sqf

@@ -0,0 +1,280 @@
+#include "..\script_component.hpp"
+
+GVAR(maxBrightDelay) = 3.25;
+
+GVAR(zapSounds) = createHashMap;
+{
+	private _cfg = missionConfigFile >> "CfgSounds" >> _x;
+	private _dataArr = getArray(_cfg >> "sound");
+	GVAR(zapSounds) set [_x, createHashMapFromArray [
+		["filename", _dataArr#0],
+		["volume", _dataArr#1],
+		["pitch", _dataArr#2]
+	]];
+	true;
+} count [QGVAR(sound_zap1),QGVAR(sound_zap2),QGVAR(sound_zap3),QGVAR(sound_zap4)];
+
+GVAR(echoSounds) = createHashMap;
+{
+	private _cfg = missionConfigFile >> "CfgSounds" >> _x;
+	private _dataArr = getArray(_cfg >> "sound");
+	GVAR(echoSounds) set [_x, createHashMapFromArray [
+		["filename", _dataArr#0],
+		["volume", _dataArr#1],
+		["pitch", _dataArr#2]
+	]];
+	true;
+} count [QGVAR(sound_ecou),QGVAR(sound_echo3)];
+
+
+private _lgExplosionCfg = missionConfigFile >> "CfgSounds" >> QGVAR(sound_electric_explsion_impact_large);
+private _lgExplosionDataArray = getArray(_lgExplosionCfg >> "sound");
+GVAR(sound_electric_explsion_impact_large) = createHashMapFromArray [
+	["filename", _lgExplosionDataArray#0],
+	["volume", _lgExplosionDataArray#1],
+	["pitch", _lgExplosionDataArray#2]
+];
+
+if (hasInterface) then {
+	call FUNC(addACEActions);
+};
+GVAR(activeEMPs) = createHashMap;
+
+// this precheck is sent to all clients from FUNC(deploy)
+// machines will precache affected objects and signal they're ready in return
+[QGVAR(event_empDeployedPreCheck), {
+	params ["_id", "_origin", "_radius"];
+
+	([_origin, _radius] call FUNC(getObjectsAndGroupsToAffect)) params ["_affectedObjects", "_affectedLocalGroups"];
+	GVAR(activeEMPs) set [_id, createHashMapFromArray [
+		["origin", _origin],
+		["radius", _radius],
+		["objects", _affectedObjects],
+		["localGroups", _affectedLocalGroups],
+		["machinesReady", []]
+	]];
+
+	[
+		LEVEL_DEBUG,
+		QUOTE(COMPONENT),
+		"EMP deployed precheck",
+		[
+			["id", _id],
+			["origin", _origin],
+			["radius", _radius],
+			["affectedObjects", count _affectedObjects],
+			["affectedLocalGroups", count _affectedLocalGroups]
+		]
+	] call EFUNC(common,log);
+
+	// notify the server we're ready to play effects
+	[QGVAR(event_readyForEmpEffects), [_id, clientOwner]] call CBA_fnc_serverEvent;
+
+	if (isServer) then {
+		// on the server, create a waiter for all machines to be ready
+		[{
+			_this params ["_id"];
+			private _empData = GVAR(activeEMPs) get _id;
+			count (_empData get "machinesReady") isEqualTo (count allUsers);
+		}, {
+			// when all machines are ready, play effects
+			_this params ["_id"];
+			private _empData = GVAR(activeEMPs) get _id;
+
+			[
+				LEVEL_DEBUG,
+				QUOTE(COMPONENT),
+				"Initiating EMP effects",
+				[
+					["id", _id],
+					["readyCount", count (_empData get "machinesReady")],
+					["allUsers", count allUsers]
+				]
+			] call EFUNC(common,log);
+
+			[QGVAR(event_initiateEMPEffects), [_id]] call CBA_fnc_globalEvent;
+		}, [_id]] call CBA_fnc_waitUntilAndExecute;
+	};
+}] call CBA_fnc_addEventHandler;
+
+// when a machine is ready to play effects, they'll trigger this on the server
+if (isServer) then {
+	[QGVAR(event_readyForEmpEffects), {
+		params ["_id", "_machineID"];
+		private _empData = GVAR(activeEMPs) get _id;
+		private _machinesReady = _empData get "machinesReady";
+		if (!(_machineID in _machinesReady)) then {
+			_machinesReady pushBack _machineID;
+			_empData set ["machinesReady", _machinesReady];
+			[
+				LEVEL_DEBUG,
+				QUOTE(COMPONENT),
+				"Machine ready for EMP effects",
+				[
+					["id", _id],
+					["machineID", _machineID],
+					["readyCount", count _machinesReady]
+				]
+			] call EFUNC(common,log);
+		};
+	}] call CBA_fnc_addEventHandler;
+};
+
+// when all machines are ready, the server will trigger this on all machines to start effects
+[QGVAR(event_initiateEMPEffects), {
+	params ["_id"];
+	private _empData = GVAR(activeEMPs) get _id;
+	private _origin = _empData get "origin";
+	private _affectedObjects = _empData get "objects";
+	private _affectedLocalGroups = _empData get "localGroups";
+
+	if (hasInterface) then {
+		[
+			LEVEL_DEBUG,
+			QUOTE(COMPONENT),
+			"Initiating EMP effects",
+			[
+				["id", _id],
+				["origin", _origin],
+				["affectedObjects", count _affectedObjects],
+				["affectedLocalGroups", count _affectedLocalGroups]
+			]
+		] call EFUNC(common,log);
+
+		[_origin] call FUNC(playLocalEffects);
+
+		// when emp effects reach max brightness, execute object effects
+		[{
+			params ["_affectedObjects", "_affectedLocalGroups"];
+			private _countLocalObjectEffectsPlayed = { // play effects on this machine
+				try {
+					[_x] call FUNC(playLocalEffectsForObject);
+				} catch {
+					[
+						LEVEL_WARNING,
+						QUOTE(COMPONENT),
+						"Failed to play local EMP effects for object",
+						[
+							["object", typeOf _x],
+							["error", _exception]
+						]
+					] call EFUNC(common,log);
+				};
+				true;
+			} count _affectedObjects;
+
+			[
+				LEVEL_DEBUG,
+				QUOTE(COMPONENT),
+				"Played EMP effects",
+				[
+					["localObjectEffectsPlayed", _countLocalObjectEffectsPlayed]
+				]
+			] call EFUNC(common,log);
+		}, [_affectedObjects, _affectedLocalGroups], GVAR(maxBrightDelay)] call CBA_fnc_waitAndExecute;
+	};
+
+	// around peak brightness
+	[{
+		params ["_affectedObjects", "_affectedLocalGroups"];
+
+		private _countLocalObjectEffectsApplied = { // apply affects to objects owned by this machine, start propagation to other machines
+			try {
+				[_x] call FUNC(applyLocalObjectEffects);
+			} catch {
+				[
+					LEVEL_WARNING,
+					QUOTE(COMPONENT),
+					"Failed to apply local EMP effects for object",
+					[
+						["object", typeOf _x],
+						["error", _exception]
+					]
+				] call EFUNC(common,log);
+			};
+			true;
+		} count (_affectedObjects select {local _x});
+		private _countLocalGroupEffectsApplied = { // apply affects to groups owned by this machine, start propagation to other machines
+			try {
+				[_x] call FUNC(applyLocalGroupEffects);
+			} catch {
+				[
+					LEVEL_WARNING,
+					QUOTE(COMPONENT),
+					"Failed to apply local EMP effects for group",
+					[
+						["group", _x],
+						["error", _exception]
+					]
+				] call EFUNC(common,log);
+			};
+			true;
+		} count _affectedLocalGroups;
+
+		if (isServer) then {
+			private _countServerObjectEffectsApplied = {
+				try {
+					[_x] call FUNC(applyServerObjectEffects);
+				} catch {
+					[
+						LEVEL_WARNING,
+						QUOTE(COMPONENT),
+						"Failed to apply server EMP effects for object",
+						[
+							["object", typeOf _x],
+							["error", _exception]
+						]
+					] call EFUNC(common,log);
+				};
+				true;
+			} count _affectedObjects;
+		};
+
+		private _countGlobalObjectEffectsApplied = {
+			try {
+				[_x] call FUNC(applyGlobalObjectEffects);
+			} catch {
+				[
+					LEVEL_WARNING,
+					QUOTE(COMPONENT),
+					"Failed to apply global EMP effects for object",
+					[
+						["object", typeOf _x],
+						["error", _exception]
+					]
+				] call EFUNC(common,log);
+			};
+			true;
+		} count _affectedObjects;
+
+		[
+			LEVEL_DEBUG,
+			QUOTE(COMPONENT),
+			"Applied EMP effects",
+			[
+				["localObjectEffects", _countLocalObjectEffectsApplied],
+				["localGroupEffects", _countLocalGroupEffectsApplied],
+				["serverObjectEffects", _countServerObjectEffectsApplied],
+				["globalObjectEffects", _countGlobalObjectEffectsApplied]
+			]
+		] call EFUNC(common,log);
+	}, [_affectedObjects, _affectedLocalGroups], GVAR(maxBrightDelay)] call CBA_fnc_waitAndExecute;
+
+
+	// clear EMP data after 30 seconds
+	[{
+		params ["_id"];
+		private _empData = GVAR(activeEMPs) get _id;
+		[
+			LEVEL_DEBUG,
+			QUOTE(COMPONENT),
+			"EMP effects finished",
+			[
+				["id", _id],
+				["affectedObjects", count (_empData get "objects")],
+				["affectedLocalGroups", count (_empData get "localGroups")]
+			]
+		] call EFUNC(common,log);
+		GVAR(activeEMPs) deleteAt _id;
+	}, [_id], 30] call CBA_fnc_waitAndExecute;
+}] call CBA_fnc_addEventHandler;

framework/emp/functions/fn_isItemElectronic.sqf

@@ -0,0 +1,38 @@
+#include "..\script_component.hpp"
+
+params [
+	["_itemClassname", "", [""]]
+];
+
+if (_itemClassname isEqualTo "") exitWith {
+	["Param _itemClassname is empty", ""] call BIS_fnc_error;
+	false
+};
+
+private _isTFARRadio = if (isClass (configFile >> "CfgPatches" >> "tfar_core")) then {_itemClassname call TFAR_fnc_isRadio} else {false};
+if (_isTFARRadio) exitWith {true};
+
+private _matchedSpecificClassnames = {(toLower _x) in (toLower _className)} count [
+	"ACE_microDAGR",
+	"Vector21",
+	"MineDetector",
+	"GPS"
+];
+
+if (_matchedSpecificClassnames > 0) exitWith {true};
+
+// find items with NVG or TI capabilities
+private _cfg = _className call CBA_fnc_getItemConfig;
+private _modes = getArray(configfile >> "CfgWeapons" >> _className >> "visionMode");
+private _subModes = [configfile >> "CfgWeapons" >> _className >> "ItemInfo" >> "OpticsModes", 1] call BIS_fnc_returnChildren;
+{
+	_modes append getArray( _x >> "visionMode" );
+} forEach _subModes;
+
+private _hasTI = "ti" in (_modes apply { toLower _x });
+private _hasNVG = "nvg" in (_modes apply { toLower _x });
+
+if (_hasTI || _hasNVG) exitWith {true};
+
+
+false;

framework/emp/functions/fn_playLocalEffects.sqf

@@ -0,0 +1,101 @@
+#include "..\script_component.hpp"
+
+// Executed on all machines with an interface
+// This plays the effects of the EMP itself going off
+
+if (!hasInterface) exitWith {};
+
+params [["_origin", [], [[]]]];
+if (count _origin isEqualTo 0) exitWith {};
+
+private _e_static3 = "#particlesource" createVehicleLocal (ASLToAGL _origin); 
+_e_static3 setParticleCircle [0, [0, 0, 0]];
+_e_static3 setParticleRandom [0.2, [0,0,0], [0.175, 0.175, 0.175], 0.25, 0.15, [0, 0, 0, 1], 1, 0]; 
+_e_static3 setParticleParams [["\A3\data_f\blesk1", 1, 0, 1], "", "SpaceObject", 1, 0.75, [0, 0, 1], [0, 0, 0], 0, 10, 7.9,0, [0, 0.2], [[1, 1, 0.1, 1], [1, 1, 1, 1]], [0.01], 1, 0, "", "", objNull,0,false,-1,[[100,100,100,1],[1,1,1,1]]]; 
+_e_static3 setDropInterval 0.15; 
+
+private _ripple2 = "#particlesource" createVehicleLocal (ASLToAGL _origin);
+_ripple2 setParticleCircle [0,[0,0,0]];
+_ripple2 setParticleRandom [0.1,[0,0,0],[0,0,0],25,1,[0,0,0,0.1],0,0];
+_ripple2 setParticleParams [["\A3\data_f\ParticleEffects\Universal\Refract.p3d",1,0,1], "", "Billboard", 1, 1, [0, 0, 1], [0, 0, 0],0,10,7.9,0, [5,0], [[1, 1, 1, 1], [1, 1, 1, 1]], [0.05], 1, 0, "", "", objNull];
+_ripple2 setDropInterval 0.05;
+
+private _light_emp = "#lightpoint" createVehiclelocal (ASLToAGL _origin); 
+// _light_emp lightAttachObject [objNull, [0,0,0.5]];
+_light_emp setLightAmbient [0.1,0.1,1];  
+_light_emp setLightColor [0.1,0.1,1];
+_light_emp setLightBrightness 0;
+_light_emp setLightUseFlare true; 
+_light_emp setLightFlareSize 1; 
+_light_emp setLightFlareMaxDistance 2500;
+_light_emp setLightDayLight true;
+_light_emp setLightAttenuation [5,1,1,1,5,1000];
+_brit = 0;
+
+
+private _explSoundData = GVAR(sound_electric_explsion_impact_large);
+// local only, last param
+playSound3D [_explSoundData get "filename", nil, false, _origin, _explSoundData get "volume", _explSoundData get "pitch", 3500, 0, true];
+
+[_light_emp, _brit, _ripple2] spawn {
+	params ["_light_emp", "_brit", "_ripple2"];
+	while {_brit < 6.5} do {
+		// takes ~1.73 seconds to reach full brightness
+		_light_emp setLightBrightness _brit;
+		_brit = _brit+0.02; //timing for next stage
+		sleep 0.01;
+	};
+	deleteVehicle _ripple2;
+};
+
+[{
+	params ["_origin", "_light_emp"];
+	private _e_static2 = "#particlesource" createVehicleLocal (ASLToAGL _origin); 
+	_e_static2 setParticleCircle [0, [0, 0, 0]];
+	_e_static2 setParticleRandom [0.2, [0,0,0], [0, 0, 0], 0.25, 1.05, [0, 0, 0, 1], 1, 0]; 
+	_e_static2 setParticleParams [["\A3\data_f\blesk1", 1, 0, 1], "", "SpaceObject", 1, 0.75, [0, 0, 0], [0, 0, 1], 0, 10, 7.9,0, [0,0.5], [[1, 1, 0.1, 1], [1, 1, 1, 1]], [0.08], 1, 0, "", "", objNull,0,false,-1,[[100,100,100,1],[0,0,1,0.01]]]; 
+	_e_static2 setDropInterval 0.05; 
+
+	private _wave = "#particlesource" createVehicleLocal (ASLToAGL _origin);
+	_wave setParticleCircle [0,[0,0,0]];
+	_wave setParticleRandom [0,[0,0,0],[0,0,0],10,0.25,[0,0,0,0.1],0,0];
+	_wave setParticleParams [["\A3\data_f\kouleSvetlo",1,0,1], "", "Billboard", 1, 3, [0, 0, 1], [0, 0, 0],0,10,7.9,0, [0,75], [[0,0,1,1],[0,0,0.25,0]], [0.01], 1, 0, "", "", objNull,0,false,-1,[[0,0,3,0.75],[0,0,1,0.01]]];
+	_wave setDropInterval 30;
+
+	private _ripple = "#particlesource" createVehicleLocal (ASLToAGL _origin);
+	_ripple setParticleCircle [0,[0,0,0]];
+	_ripple setParticleRandom [0,[0,0,0],[0,0,0],0,0.25,[0,0,0,0.1],0,0];
+	_ripple setParticleParams [["\A3\data_f\ParticleEffects\Universal\Refract.p3d",1,0,1], "", "Billboard", 1, 1.5, [0, 0, 1], [0, 0, 0],0,10,7.9,0, [0,500], [[1, 1, 1, 1], [1, 1, 1, 1]], [0.05], 1, 0, "", "", objNull];
+	_ripple setDropInterval 10;
+
+	[{deleteVehicle _this}, _ripple, 0.65] call CBA_fnc_waitAndExecute;
+
+	[{
+		params ["_e_static2", "_e_static3", "_brit", "_light_emp", "_wave"];
+		{
+			deleteVehicle _x;
+		} forEach [_e_static2, _e_static3];
+
+		[_light_emp, _brit, _wave] spawn {
+			params ["_light_emp", "_brit", "_wave"];
+			while {_brit > 0} do {
+				_light_emp setLightBrightness _brit;
+				_brit = _brit-2;
+				sleep 0.01;
+			};
+			deleteVehicle _light_emp;
+			deleteVehicle _wave;
+		};
+	}, [[_e_static2, _e_static3, 6.5, _light_emp, _wave]], 0.85] call CBA_fnc_waitAndExecute;
+}, [_origin, _light_emp], GVAR(maxBrightDelay)] call CBA_fnc_waitAndExecute;
+
+
+
+
+[{
+	params ["_origin"];
+	private _echosound = selectRandom (keys GVAR(echoSounds));
+	private _echoSoundData = GVAR(echoSounds) get _echosound;
+	// local only, last param
+	playSound3D [_echoSoundData get "filename", nil, false, _origin, _echoSoundData get "volume", _echoSoundData get "pitch", 4000, 0, true];
+}, [_origin], GVAR(maxBrightDelay) + 0.65 + 2] call CBA_fnc_waitAndExecute;

framework/emp/functions/fn_playLocalEffectsForObject.sqf

@@ -0,0 +1,79 @@
+#include "..\script_component.hpp"
+
+// executed on all clients with an interface
+// flickers lights for light props/streetlamps and plays a spark sound
+
+if (!hasInterface) exitWith {};
+
+params [["_object", objNull, [objNull]]];
+if (isNull _object) exitWith {};
+
+// flicker the lights
+private _flickerHandle = [_object] spawn {
+	params ["_object"];
+	for "_i" from 1 to 3 do {
+		_object switchLight "OFF";
+		sleep (random 0.3);
+		_object switchLight "ON";
+		sleep (random 0.3);
+	};
+	// always finish by shutting off
+	_object switchLight "OFF";
+};
+
+_object setVariable [QGVAR(flickerHandle), _flickerHandle];
+
+[{scriptDone (_this getVariable QGVAR(flickerHandle));}, {
+	private _object = _this;
+
+	// sound
+	// private _spark_sound = selectRandom (keys GVAR(zapSounds));
+	// private _sparkSoundData = GVAR(zapSounds) get _spark_sound;
+	// playSound3D [_sparkSoundData get "filename", _object, false, getPosASL _object, _sparkSoundData get "volume", _sparkSoundData get "pitch", 75, 0, true];
+
+	// // particle effect, large blue spark
+	// private _e_static = "#particlesource" createVehicleLocal (getPosATL _object);
+	// _e_static setParticleCircle [1, [0, 0, 0]];
+	// _e_static setParticleRandom [0.2, [1.5,1.5,0], [0.175, 0.175, 0], 0.15, 0.2, [0, 0, 0, 1], 1, 0];
+	// _e_static setParticleParams [["\A3\data_f\blesk1", 1, 0, 1], "", "SpaceObject", 1, 0.05, [0, 0, 0], [0, 0, 0], 0, 10, 7.9,0, [0.01, 0.02, 0.01], [[1, 1, 0.1, 1], [1, 1, 1, 1]], [0.025], 1, 0, "", "", _object,0,false,-1,[[100,100,100,1],[0,0,1,0.01]]];
+	// _e_static setDropInterval 0.025;
+
+	// [{deleteVehicle _this;}, _e_static, 1] call CBA_fnc_waitAndExecute;
+
+
+	// play additional spark
+	_bbr = boundingBoxReal vehicle _object;
+	_p1 = _bbr select 0;
+	_p2 = _bbr select 1;
+	_maxHeight = abs ((_p2 select 2) - (_p1 select 2));
+
+	//_spark_poz_rel = [getPos _lamp select 0,getPos _lamp select 1,_maxHeight-0.5];
+	private _spark_poz_rel = (_maxHeight/2)-0.45;
+
+	private _spark_type = ["white","orange"] call BIS_fnc_selectRandom;
+	private _drop = 0.001+(random 0.05);
+	private _scantei_spark = "#particlesource" createVehicleLocal (getPosATL _object);
+
+	if (_spark_type=="orange") then 
+	{
+		_scantei_spark setParticleCircle [0, [0, 0, 0]];
+		_scantei_spark setParticleRandom [1, [0.1, 0.1, 0.1], [0, 0, 0], 0, 0.25, [0, 0, 0, 0], 0, 0];
+		_scantei_spark setParticleParams [["\A3\data_f\proxies\muzzle_flash\muzzle_flash_silencer.p3d", 1, 0, 1], "", "SpaceObject", 1, 1, [0, 0,_spark_poz_rel], [0, 0, 0], 0, 15, 7.9, 0, [0.5,0.5,0.05], [[1, 1, 1, 1], [1, 1, 1, 1], [1, 1, 1, 0]], [0.08], 1, 0, "", "", _object,0,true,0.3,[[1,1,1,1]]];
+		_scantei_spark setDropInterval _drop;
+	} else
+	{
+		//hint "alb";
+		_scantei_spark setParticleCircle [0, [0, 0, 0]];
+		_scantei_spark setParticleRandom [1, [0.05, 0.05, 0.1], [5, 5, 3], 0, 0.0025, [0, 0, 0, 0], 0, 0];
+		_scantei_spark setParticleParams [["\A3\data_f\proxies\muzzle_flash\muzzle_flash_silencer.p3d", 1, 0, 1], "", "SpaceObject", 1, 1, [0, 0,_spark_poz_rel], [0, 0, 0], 0, 20, 7.9, 0, [0.5,0.5,0.05], [[1, 1, 1, 1], [1, 1, 1, 1], [1, 1, 1, 0]], [0.08], 1, 0, "", "", _object,0,true,0.3,[[5,5,3,1]]];
+		_scantei_spark setDropInterval 0.001;
+	};
+
+	private _spark_sound = selectRandom (keys GVAR(zapSounds));
+	private _sparkSoundData = GVAR(zapSounds) get _spark_sound;
+	playSound3D [_sparkSoundData get "filename", _object, false, getPosASL _object, _sparkSoundData get "volume", _sparkSoundData get "pitch", 75, 0, true];
+
+	[{deleteVehicle _this;}, _scantei_spark, 0.4 + (random 0.7)] call CBA_fnc_waitAndExecute;
+}, _object] call CBA_fnc_waitUntilAndExecute;
+
+

framework/emp/functions/fn_removeUnitElectricInventoryItems.sqf

@@ -0,0 +1,53 @@
+#include "..\script_component.hpp"
+
+// Executed where object is local and removes electronics from inventory
+
+params [["_object", objNull, [objNull]]];
+if (isNull _object) exitWith {};
+if (not (_object isKindOf "CAManBase")) exitWith {["Param _object is not a unit", _object] call BIS_fnc_error};
+
+// process unit inventory
+{
+	_object unassignItem _x;
+	_object removeItem _x;
+} forEach ((items _object) + (assignedItems _object)) select {[_x] call FUNC(isItemElectronic)};
+
+// replace backpack radio with base and restore items
+if (isClass (configFile >> "CfgPatches" >> "tfar_core")) then {
+	private _backpackRadio = _object call TFAR_fnc_backpackLR;
+	if (!isNil "_backpackRadio") then {
+		_backpackRadio params ["_actualBackpack", "settings"];
+		private _baseBackpack = _actualBackpack call BIS_fnc_basicBackpack;
+		private _backpackItems = backpackItems _object;
+
+		removeBackpack _object;
+		_object addBackpack _baseBackpack;
+
+		{
+			_object addItemToBackpack _x;
+		} forEach _backpackItems;
+	};
+};
+
+//for player units
+if (isPlayer _object) then {
+	_object action ["IRLaserOff", _object];
+	_object action ["nvGogglesOff", _object];
+};
+
+// remove flashlights/pointers on weapons
+private _primaryFlashlightOrPointer = (primaryWeaponItems _object)#1;
+if (_primaryFlashlightOrPointer != "") then {
+	_object removePrimaryWeaponItem _primaryFlashlightOrPointer;
+	_object removeItem _primaryFlashlightOrPointer;
+};
+private _secondaryFlashlightOrPointer = (secondaryWeaponItems _object)#1;
+if (_secondaryFlashlightOrPointer != "") then {
+	_object removeSecondaryWeaponItem _secondaryFlashlightOrPointer;
+	_object removeItem _secondaryFlashlightOrPointer;
+};
+private _handgunFlashlightOrPointer = (handgunItems _object)#1;
+if (_handgunFlashlightOrPointer != "") then {
+	_object removeHandgunItem _handgunFlashlightOrPointer;
+	_object removeItem _handgunFlashlightOrPointer;
+};

framework/emp/functions/fn_removeVehicleElectricInventoryItems.sqf

@@ -0,0 +1,34 @@
+#include "..\script_component.hpp"
+
+// Executed where object is local and removes electronics from inventory
+
+params [["_object", objNull, [objNull]]];
+if (isNull _object) exitWith {};
+if (_object isKindOf "CAManBase") exitWith {["Param _object is not a vehicle: %1", _object] call BIS_fnc_error};
+
+
+// get all items in vehicle that are electronic
+private _vehicleItems = itemCargo _object;
+// filter array to identify electronic items
+_vehicleItems = _vehicleItems select {[_x] call FUNC(isItemElectronic)};
+{
+	// remove item from vehicle
+	_object addItemCargoGlobal [_x, -1];
+	true;
+} count _vehicleItems;
+
+{ // forEach everyContainer _object - process vests, uniforms, backpacks in a vehicle
+	_x params ["_containerClass", "_containerObject"];
+	private _subItemsOfContainer = itemCargo _containerObject;
+	// filter array to identify electronic items
+	_subItemsOfContainer = _subItemsOfContainer select {[_x] call FUNC(isItemElectronic)};
+	{
+		// remove item from container
+		_subContainer addItemCargoGlobal [_x, -1];
+		true;
+	} count _subItemsOfContainer;
+} forEach (everyContainer _object);
+
+
+// vehicle is now empty of electronics
+// built-in vehicle radios cannot be removed and are left in place

framework/emp/readme.md

@@ -0,0 +1,6 @@
+# EMP Module
+
+Adapted from:
+
+- KE_EB EMP Mission Script (unknown author, found by Sherman)
+- EMP Systems (Murphy, Wenza) on [Steam Workshop](https://steamcommunity.com/sharedfiles/filedetails/?id=2225040619)

framework/emp/script_component.hpp

@@ -0,0 +1,3 @@
+#define COMPONENT emp
+#define COMPONENT_BEAUTIFIED EMP
+#include "../script_mod.hpp"

framework/init/functions/fn_initClient.sqf

@@ -2,13 +2,6 @@
 
 if ( !hasInterface ) exitWith {};
 
-["milsim_logText", {
-	params [["_strArray", [""], [[]]]];
-	{
-		diag_log text _x;
-	} forEach _strArray;
-}] call CBA_fnc_addEventHandler;
-
 // make sure the server has finished init
 waitUntil {!isNil QGVARMAIN(complete)};
 
@@ -23,6 +16,7 @@ EGVAR(common,diaryRecords) = createHashMap;
 
 
 // initialize other modules
+call EFUNC(emp,init);
 call EFUNC(mapcopy,initClient);
 call EFUNC(reinsert,initClient);
 call EFUNC(resupply,initClient);

framework/init/functions/fn_initServer.sqf

@@ -9,20 +9,11 @@ publicVariable QGVARMAIN(baseObjects);
 // Initializes the Dynamic Groups framework and groups
 ["Initialize", [true]] call BIS_fnc_dynamicGroups;
 
-if (isDedicated) then {
-	["milsim_logText", {
-		params [["_strArray", [""], [[]]]];
-		{
-			diag_log text _x;
-		} forEach _strArray;
-	}] call CBA_fnc_addEventHandler;
-};
-
-
 // initialize other modules
 call EFUNC(common,logMissionInfo);
 call EFUNC(fbcb2_assets,initServer);
 call EFUNC(reinsert,initServer);
+call EFUNC(emp,init);
 
 // declare init complete to other modules
 missionNamespace setVariable [QGVARMAIN(complete), true, true];

framework/script_mod.hpp

@@ -6,9 +6,9 @@
 #define VERSION_STR MAJOR.MINOR.PATCHLVL
 #define VERSION_AR  MAJOR,MINOR,PATCHLVL
 
-// #define DEBUG_MODE -1 // TRACE
+#define DEBUG_MODE -1 // TRACE
 // #define DEBUG_MODE 0 // DEBUG
-#define DEBUG_MODE 1 // INFO
+// #define DEBUG_MODE 1 // INFO
 // #define DEBUG_MODE 2 // WARNING
 // #define DEBUG_MODE 3 // ERROR