Merge pull request 'change logPlayerInventory to return lines, which handlers send to CBA ev' (#12) from #11-inventory-processed-on-every-machine into #7-inventory-compliance-message

Reviewed-on: https://17th-gs.iceberg-gaming.com:5443/hizumi/MissionTemplate/pulls/12

CHANGELOG.md

@@ -4,6 +4,35 @@ All notable changes to this project will be documented in this file.
 
 The format is based on [Keep a Changelog](https://keepachangelog.com/en/1.0.0/), and this project badly attempts [Semantic Versioning](https://semver.org/spec/v2.0.0.html).
 
+## [3.1.3] - 2024-01-10
+
+
+### Changed
+- Merge triage-status-draw3d to fix draw overlay for medics
+
+## [3.1.2] - 2024-01-04
+
+### Added
+- Add forgotten code file file for medical overlay
+
+### Changed
+- Merge update-flag-exclusions branch to fix issues with vehicles not applying flag
+
+## [3.1.1] - 2024-01-04
+
+### Changed
+- Spelling Fixes
+- Update class binding for vehicle flag interaction
+
+## [3.1.0] - 2023-12-17
+
+### Added
+
+- Vehicles now have an ace interaction to allow the mounting of flags onto them for identification. Contributed by IndigoFox
+- Added inventory validation checks
+- Added empty group removal code due to ownership issues on entity transfers
+- Added medical card visibility to medics for triage purposes
+
 ## [3.0.2] - 2023-10-14
 
 ### Changed

functions/CfgFunctions.hpp

@@ -32,12 +32,16 @@ class milsim
 		class bindEventHandlers { postInit = 1; };
 		class bindVehicleActions { postInit = 1; };
 		class addClientStatsPFH {};
+		class addMedicalOverlayPFH { postInit = 1; };
 		class calculateClientStats {};
+		class initVehicleFlags { postInit = 1; };
+		class bindEmptyGroupGarbageCleanup { postInit = 1; };
 	};
 
 	class server {
 		class addServerStatsPFH {};
 		class calculateServerStats {};
+		class logPlayerInventory {};
 	};
 
 	class resupply {

functions/client/fn_addClientStatsPFH.sqf

@@ -8,7 +8,7 @@ _cpsPFH = [
 	},
 	"milsim_client_cps_interval" call CBA_settings_fnc_get,
 	[],
-	{ diag_log text format ["[MILSIM] (client) PFH loaded with interval %1 seconds", "milsim_client_cps_interval" call CBA_settings_fnc_get ], },
+	{ diag_log text format ["[MILSIM] (client) PFH loaded with interval %1 seconds", "milsim_client_cps_interval" call CBA_settings_fnc_get ] },
 	{ diag_log text format ["[MILSIM] (client) PFH unloaded"] },
 	{ "milsim_client_cps_enable" call CBA_settings_fnc_get },
 	{ false },

functions/client/fn_addMedicalOverlayPFH.sqf

@@ -0,0 +1,99 @@
+/*
+
+milsim_fnc_addMedicalOverlayPFH
+
+Author: IndigoFox
+
+Description:
+    Affects players with medical permissions. Will see a 3D colored dot over nearby (5-10m)
+	unconscious players who are not in a vehicle
+	which indicates their current ACE Triage Card status.
+	Designed to increase efficiency of CCPs.
+
+*/
+
+// Force setting if CBA doesn't work?
+if (isNil "milsim_client_medState3D_enabled") then {
+	milsim_client_medState3D_enabled = true;
+};
+if (isNil "milsim_client_medState3D_drawRange") then {
+	milsim_client_medState3D_drawRange = 10;
+};
+
+// List of units to draw icons for
+milsim_client_medState3D_drawTargets = []; 
+
+// ACE Triage colors, for consistency across UIs and functions
+// #define TRIAGE_COLOR_NONE      0.5, 0.5, 0.5, 0.1
+// #define TRIAGE_COLOR_MINIMAL   0, 0.5, 0, 0.9
+// #define TRIAGE_COLOR_DELAYED   1, 0.84, 0, 0.9
+// #define TRIAGE_COLOR_IMMEDIATE 1, 0, 0, 0.9
+// #define TRIAGE_COLOR_DECEASED  0, 0, 0, 0.9
+
+// ACE Triage colors, for consistency across UIs and functions
+milsim_client_medState3D_colors = [
+	[0, 0.5, 0, 0.9], // TRIAGE_COLOR_MINIMAL
+	[1, 0.84, 0, 0.9], // TRIAGE_COLOR_DELAYED
+	[1, 0, 0, 0.9], // TRIAGE_COLOR_IMMEDIATE
+	[0.15, 0.15, 0.15, 0.9], // TRIAGE_COLOR_DECEASED
+	[0.5, 0.5, 0.5, 0] // TRIAGE_COLOR_NONE
+];
+
+// Per-frame handler to draw icons
+// cleanup
+if (!isNil "milsim_client_medState3D_pfh") then {
+	[milsim_client_medState3D_pfh] call CBA_fnc_removePerFrameHandler;
+};
+// add pfh
+milsim_client_medState3D_pfh =	[{
+	// if disabled, skip processing
+	if (!milsim_client_medState3D_enabled) exitWith {false};
+	// if no targets, skip processing
+	if (count milsim_client_medState3D_drawTargets == 0) exitWith {false};
+	if !([player] call ace_medical_treatment_fnc_isMedic) exitWith {false};
+	{
+		// distance within 10 meters
+		if (player distance _x > milsim_client_medState3D_drawRange) then {continue};
+		// check unit not null, not conscious, and not in a vehicle
+		if (
+			!(_x getVariable ["ACE_isUnconscious", false]) ||
+			!isNull (objectParent _x)
+		) then {continue};
+
+		// color based on triage level
+		private _triageLevel = _x getVariable ["ace_medical_triageLevel", -1];
+		if (_triageLevel == -1) then {continue};
+		private _color = milsim_client_medState3D_colors select (
+			(_x getVariable ["ace_medical_triageLevel", -1]) -1
+		);
+		// draw position, slightly above the prone unit
+		private _drawPos = (visiblePosition _x) vectorAdd [0, 0, 0.5];
+		// draw icon
+		drawIcon3D [
+			"\A3\ui_f\data\map\markers\military\dot_CA.paa", // icon texture
+			_color, // color
+			_drawPos, // position AGL
+			1, // width
+			1, // height
+			0 // angle
+			// further params optional, omitted
+		];
+	} forEach milsim_client_medState3D_drawTargets;
+}, 0, []] call CBA_fnc_addPerFrameHandler;
+
+// subroutine to gather nearest 50 units every 5 seconds and store in milsim_client_medState3D_drawTargets
+// cleanup
+if (!isNil "milsim_client_medState3D_drawTargetsPfh") then {
+	[milsim_client_medState3D_drawTargetsPfh] call CBA_fnc_removePerFrameHandler;
+};
+// add pfh
+milsim_client_medState3D_drawTargetsPfh = [{
+	milsim_client_medState3D_drawTargets = (
+		(allUnits + allDeadMen) select {
+			_x isKindOf "CAManBase" && 
+			player distance _x < 50 &&
+			!isNull _x &&
+			player isNotEqualTo _x
+		}
+	);
+}, 5, false] call CBA_fnc_addPerFrameHandler;

functions/client/fn_bindEmptyGroupGarbageCleanup.sqf

@@ -0,0 +1,23 @@
+diag_log text format ["[MILSIM] (client) initializing empty group deletion PFH"];
+
+_emptyGroupPFH = [
+	{ 
+		{
+			if (local _x) then {
+				if ((count units _x) == 0) then {
+					deleteGroup _x;
+				};
+			};
+		} forEach allGroups;
+	},
+	300,
+	[],
+	{ diag_log text format ["[MILSIM] (client) Empty Group Deletion PFH loaded"] },
+	{ diag_log text format ["[MILSIM] (client) Empty Group Deletion"] },
+	{ true },
+	{ false },
+	[]
+] call CBA_fnc_createPerFrameHandlerObject;
+
+
+

functions/client/fn_bindEventHandlers.sqf

@@ -38,6 +38,16 @@ addMissionEventHandler ["HandleChatMessage",
 ];
 
 
+["ace_arsenal_displayClosed", {
+	private _lines = [player] call milsim_fnc_logPlayerInventory;
+	["milsim_logText", [_lines]] call CBA_fnc_globalEvent;
+}] call CBA_fnc_addEventHandler;
+
+[missionNamespace, "arsenalClosed", {
+	private _lines = [player] call milsim_fnc_logPlayerInventory;
+	["milsim_logText", [_lines]] call CBA_fnc_globalEvent;
+}] call BIS_fnc_addScriptedEventHandler;
+
 diag_log text "[MILSIM] (client) event handlers bound";
 
 nil;

functions/client/fn_initVehicleFlags.sqf

@@ -0,0 +1,225 @@
+milsim_vehicleflag_options = [
+	["Chevron IDs", [
+		["flag_chevron_id1", createHashMapFromArray [
+			["Title", "Flag 1"],
+			["Texture", "textures\flag_number\flag_id_1_co.paa"]
+		]],
+		["flag_chevron_id2", createHashMapFromArray [
+			["Title", "Flag 2"],
+			["Texture", "textures\flag_number\flag_id_2_co.paa"]
+		]],
+		["flag_chevron_id3", createHashMapFromArray [
+			["Title", "Flag 3"],
+			["Texture", "textures\flag_number\flag_id_3_co.paa"]
+		]],
+		["flag_chevron_id4", createHashMapFromArray [
+			["Title", "Flag 4"],
+			["Texture", "textures\flag_number\flag_id_4_co.paa"]
+		]],
+		["flag_chevron_id5", createHashMapFromArray [
+			["Title", "Flag 5"],
+			["Texture", "textures\flag_number\flag_id_5_co.paa"]
+		]],
+		["flag_chevron_id6", createHashMapFromArray [
+			["Title", "Flag 6"],
+			["Texture", "textures\flag_number\flag_id_6_co.paa"]
+		]],
+		["flag_chevron_id7", createHashMapFromArray [
+			["Title", "Flag 7"],
+			["Texture", "textures\flag_number\flag_id_7_co.paa"]
+		]],
+		["flag_chevron_id8", createHashMapFromArray [
+			["Title", "Flag 8"],
+			["Texture",  "textures\flag_number\flag_id_8_co.paa"]
+		]],
+		["flag_chevron_id9", createHashMapFromArray [
+			["Title", "Flag 9"],
+			["Texture", "textures\flag_number\flag_id_9_co.paa"]
+		]],
+		["flag_chevron_id10", createHashMapFromArray [
+			["Title", "Flag 10"],
+			["Texture", "textures\flag_number\flag_id_10_co.paa"]
+		]],
+		["flag_chevron_hq", createHashMapFromArray [
+			["Title", "Flag HQ"],
+			["Texture", "textures\flag_number\flag_id_hq_co.paa"]
+		]]
+	]],
+	["Simple Shapes", [
+		["flag_simpleshape_greenoctagon", createHashMapFromArray [
+			["Title", "Green Octagon"],
+			["Texture", "textures\simple_shape\flag_simpleshape_greenoctagon_co.paa"]
+		]],
+		["flag_simpleshape_bluecircle", createHashMapFromArray [
+			["Title", "Blue Circle"],
+			["Texture", "textures\simple_shape\flag_simpleshape_bluecircle_co.paa"]
+		]],
+		["flag_simpleshape_orangesquare", createHashMapFromArray [
+			["Title", "Orange Square"],
+			["Texture", "textures\simple_shape\flag_simpleshape_orangesquare_co.paa"]
+		]],
+		["flag_simpleshape_pinktriangle", createHashMapFromArray[
+			["Title", "Pink Triangle"],
+			["Texture", "textures\simple_shape\flag_simpleshape_pinktriangle_co.paa"]
+		]],
+		["flag_simpleshape_redpentagon", createHashMapFromArray [
+			["Title", "Red Pentagon"],
+			["Texture", "textures\simple_shape\flag_simpleshape_redpentagon_co.paa"]
+		]]
+	]],
+	["Miscellaneous", [
+		["flag_17th_emblem", createHashMapFromArray [
+			["Title", "17th Emblem"],
+			["Texture", "textures\flags_misc\flag_17th_emblem_co.paa"]
+		]],
+		["flag_redcross", createHashMapFromArray [
+			["Title", "Red Cross"],
+			["Texture", "textures\flags_misc\flag_redcross_co.paa"]
+		]]
+	]]
+];
+
+
+private _appliedParentClasses = [
+	"LandVehicle",
+	"Helicopter"
+];
+
+private _modelsWithoutFlagProxies = [
+	"TF373_SOAR_MH47G_Base", // MH-47G Chinook
+	"RHS_MELB_base", // MELB AH-6M/MH-6M/H-6M Little Bird
+	"USAF_C17", // C17 Globemaster III
+	"USAF_C130J", // C130J Super Hercules
+	"USAF_AC130U", // AC130 Spooky II
+	"ej_UH60M_base", // UH-60M Black Hawk + DAP variants
+	"rhsusf_fmtv_base" // M1083A1P2 variants + SOV SOCOM variants
+];
+
+{
+	private _parentClass = _x;
+	[_parentClass, "InitPost", {
+		private _flagActionID = "SetVehicleFlag";
+		private _flagMasterAction = [
+			_flagActionID, // id
+			"Set Vehicle Flag", // displayed title
+			"\A3\ui_f\data\map\markers\flags\nato_ca.paa", // flag icon
+			{true}, // statement
+			{
+				params ["_target", "_player", "_params"];
+				private _modelsWithoutFlagProxies = _params select 1;
+				
+				// check if hierarchy includes any of the models without flag proxies
+				private _excluded = false;
+				{
+					if (_excluded) exitWith {false};
+					_excluded = _target isKindOf _x;
+				} forEach _modelsWithoutFlagProxies;
+				if (_excluded) exitWith {false};
+				
+
+				// check if vehicle is alive
+				alive _target;
+			}, // condition
+			{
+				params ["_target", "_player", "_params"];
+				private _flagActionID = _params#0;
+				private _actions = [];
+				{
+					_x params ["_flagCategory", "_flagOptions"];
+					// diag_log format ["NewFlagCategory: %1 %2", _flagCategory, _flagOptions];
+
+					private _flagCategoryOption = [
+						_flagActionID + "_" + _flagCategory, // id
+						_flagCategory, // displayed title
+						(_flagOptions#0#1) get "Texture", // flag icon
+						{true}, // statement
+						{
+							params ["_target", "_player", "_params"];
+							alive _target;
+							// true;
+						}, // condition
+						{
+							params ["_target", "_player", "_params"];
+							_params params ["_flagActionID", "_flagCategoryID", "_flagOptions"];
+							private _categoryOptions = [];
+							{
+								_x params ["_flagOptionID", "_flagOptionData"];
+								// diag_log format ["NewFlagOption: %1 %2", _flagOptionID, _flagOptionData];
+								private _newFlagOption = [
+									_flagActionID + "_" + _flagCategory + "_" + _flagOptionID, // id
+									_flagOptionData get "Title", // displayed title
+									_flagOptionData get "Texture", // flag icon
+									{
+										params ["_target", "_player", "_params"];
+										_target forceFlagTexture (_params select 2);
+									}, // statement
+									{
+										params ["_target", "_player", "_params"];
+										alive _target;
+										// true;
+									}, // condition
+									nil, // child code
+									[_flagActionID, _flagCategoryID, getMissionPath (_flagOptionData get "Texture")], // params
+									nil, // position
+									4, // distance
+									[false, false, false, false, false] // other params
+								] call ace_interact_menu_fnc_createAction;
+								_categoryOptions pushBack [_newFlagOption, [], _target];
+							} forEach _flagOptions;
+							_categoryOptions;
+						}, // child code
+						[_flagActionID, _flagCategoryID, _flagOptions], // params
+						nil, // position
+						4, // distance
+						[false, false, false, false, false], // other params
+						nil // modifier function code
+					] call ace_interact_menu_fnc_createAction;
+
+					_actions pushBack [_flagCategoryOption, [], _target];
+				} forEach milsim_vehicleflag_options;
+
+				_actions;
+			}, // child code
+			[_flagActionID, _modelsWithoutFlagProxies], // params
+			nil, // position
+			4, // distance
+			[false, false, false, false, false], // other params
+			nil // modifier function code
+		] call ace_interact_menu_fnc_createAction;
+
+		// add action to add flag
+		[
+			(_this select 0), // object
+			0, // action 0 or self-action 1
+			["ACE_MainActions"], // parent
+			_flagMasterAction // action
+		] call ace_interact_menu_fnc_addActionToObject;
+		
+		
+		// add action to remove flag
+		private _removeFlagAction = [
+			_flagActionID + "_removeflag", // id
+			"Remove Flag", // displayed title
+			"\A3\ui_f\data\map\markers\flags\nato_ca.paa", // flag icon
+			{
+				params ["_target", "_player", "_params"];
+				_target forceFlagTexture "";
+			}, // statement
+			{
+				params ["_target", "_player", "_params"];
+				alive _target && getForcedFlagTexture _target != "";
+			}, // condition
+			nil // child code
+		] call ace_interact_menu_fnc_createAction;
+
+		[
+			(_this select 0), // object
+			0, // action 0 or self-action 1
+			["ACE_MainActions", _flagActionID], // parent
+			_removeFlagAction // action
+		] call ace_interact_menu_fnc_addActionToObject;
+			
+	}, true, [], true] call CBA_fnc_addClassEventHandler;
+} forEach _appliedParentClasses;
+
+nil;

functions/init/fn_initPlayerLocal.sqf

@@ -1,5 +1,14 @@
 if ( !hasInterface ) exitWith {};
 
+if (!isServer) then {
+	["milsim_logText", {
+		params [["_strArray", [""], [[]]]];
+		{
+			diag_log text _x;
+		} forEach _strArray;
+	}] call CBA_fnc_addEventHandler;
+};
+
 ["InitializePlayer", [player, true]] call BIS_fnc_dynamicGroups;
 
 nil;

functions/init/fn_initServer.sqf

@@ -53,7 +53,12 @@ publicVariable "milsim_var_rotaryAssets";
 // Initializes the Dynamic Groups framework and groups
 ["Initialize", [true]] call BIS_fnc_dynamicGroups;
 
-
+["milsim_logText", {
+	params [["_strArray", [""], [[]]]];
+	{
+		diag_log text _x;
+	} forEach _strArray;
+}] call CBA_fnc_addEventHandler;
 
 missionNamespace setVariable ["milsim_complete", true];
 diag_log text "[MILSIM] (initServer) milsim_complete: version 2.3";

functions/server/fn_logPlayerInventory.sqf

@@ -0,0 +1,366 @@
+/*
+	Function: milsim_fnc_logPlayerInventory
+
+	Description:
+		Checks a player's inventory for non-compliant items and logs results to all machines.
+
+	Author: Hizumi, EagleTrooper, IndigoFox
+
+	Parameters:
+		0: _player - <OBJECT> - Player to check inventory of.
+
+	Returns:
+		<ARRAY> - Array of strings to be logged.
+
+*/
+params [
+	["_player", objNull, [objNull]]
+];
+
+if (!isPlayer _player) exitWith {
+	["[MILSIM] (logPlayerInventory): ERROR :: _player is not a player"]
+};
+
+// DEFINITIONS
+_blackListItems = [ // Items that NO member is allowed to use.
+	"17BN_ANPVS14", // NVG AN/PVS-14
+	"USP_PVS_14", // NVG AN/PVS-14
+	"USP_PVS_15", // NVG AN/PVS-15
+	"rhsusf_ANPVS_14", // NVG AN/PVS-14
+	"ej_VPS15", // NVG AN/PVS-15
+	"rhsusf_ANPVS_15", // NVG AN/PVS-15
+	"ej_PVS15D", // NVG AN/PVS-15
+	"UK3CB_M16_Carbine", // M16 Series
+	"UK3CB_M16A1", // M16 Series
+	"UK3CB_M16A1_LSW", // M16 Series
+	"UK3CB_M16A2", // M16 Series
+	"UK3CB_M16A2_UGL", // M16 Series
+	"UK3CB_M16A3", // M16 Series
+	"rhs_weap_m16a4", // M16 Series
+	"rhs_weap_m16a4_carryhandle", // M16 Series
+	"rhs_weap_m16a4_carryhandle_M203", // M16 Series
+	"rhs_weap_m16a4_imod", // M16 Series
+	"rhs_weap_m16a4_imod_M203", // M16 Series
+	"rhs_weap_m27iar", // M27 Series
+	"rhs_weap_m27iar_grip", // M27 Series
+	"UK3CB_G36_MLIC", // G36 Series
+	"UK3CB_G36_MLIC_K", // G36 Series
+	"UK3CB_G36_MLIC_C", // G36 Series
+	"UK3CB_G36_KSK_K", // G36 Series
+	"UK3CB_G36_KSK", // G36 Series
+	"UK3CB_G36A1", // G36 Series
+	"UK3CB_AG36A1", // G36 Series
+	"UK3CB_G36A1_K", // G36 Series
+	"UK3CB_G36A1_C", // G36 Series
+	"UK3CB_G36E1", // G36 Series
+	"UK3CB_AG36E1", // G36 Series
+	"UK3CB_G36E1_K", // G36 Series
+	"UK3CB_G36E1_C", // G36 Series
+	"UK3CB_AG36_MLIC", // G36 Series
+	"UK3CB_G36V", // G36 Series
+	"UK3CB_AG36V", // G36 Series
+	"UK3CB_G36_TAC", // G36 Series
+	"UK3CB_G36V_K", // G36 Series
+	"UK3CB_AG36_TAC_K", // G36 Series
+	"UK3CB_G36V_C", // G36 Series
+	"UK3CB_G36_TAC_C", // G36 Series
+	"UK3CB_G36_LSW", // G36 Series
+	"rhs_weap_g36kv", // G36 Series
+	"rhs_weap_g36kv_ag36", // G36 Series
+	"rhs_weap_g36c", // G36 Series
+	"Tier1_SIG_CMX_115_Virtus_300BLK", // MCX 300 Blackout
+	"Tier1_SIG_CMX_115_Virtus_300BLK_Black", // MCX 300 Blackout
+	"Tier1_SIG_CMX_115_Virtus_300BLK_Desert", // MCX 300 Blackout
+	"Tier1_SIG_CMX_115_Virtus_300BLK_FDE", // MCX 300 Blackout
+	"UK3CB_M14", // M14 Series
+	"UK3CB_M14_Railed", // M14 Series
+	"UK3CB_M14DMR", // M14 Series
+	"UK3CB_M14DMR_BLK", // M14 Series
+	"UK3CB_M14DMR_Railed", // M14 Series
+	"UK3CB_M14DMR_Railed_BLK", // M14 Series
+	"srifle_DMR_06_hunter_F", // M14 Series
+	"srifle_DMR_06_camo_F", // M14 Series
+	"srifle_DMR_06_olive_F", // M14 Series
+	"rhs_weap_m14", // M14 Series
+	"rhs_weap_m14_d", // M14 Series
+	"rhs_weap_m14_fiberglass", // M14 Series
+	"rhs_weap_m14_rail", // M14 Series
+	"rhs_weap_m14_rail_d", // M14 Series
+	"rhs_weap_m14_rail_fiberglass", // M14 Series
+	"rhs_weap_m14_rail_wd", // M14 Series
+	"rhs_weap_m14_ris", // M14 Series
+	"rhs_weap_m14_ris_d", // M14 Series
+	"rhs_weap_m14_ris_fiberglass", // M14 Series
+	"rhs_weap_m14_ris_wd", // M14 Series
+	"rhs_weap_m14_wd", // M14 Series
+	"rhs_weap_m14_weap_m14ebrri", // M14 Series
+	"rhs_weap_m14_socom", // M14 Series
+	"rhs_weap_m14_socom_rail", // M14 Series
+	"srifle_EBR_F", // Mk14 Series
+	"UK3CB_FNFAL_OSW", // FN_FAL Series
+	"UK3CB_FNFAL_OSW_GL", // FN_FAL Series
+	"UK3CB_FNFAL_FULL", // FN_FAL Series
+	"UK3CB_FNFAL_FULL_RAILS", // FN_FAL Series
+	"UK3CB_FNFAL_FOREGRIP", // FN_FAL Series
+	"UK3CB_FNFAL_PARA", // FN_FAL Series
+	"UK3CB_FNFAL_PARA_RAILS", // FN_FAL Series
+	"UK3CB_FNFAL_STG58", // FN_FAL Series
+	"SMA_ACRREM", //Remington ACR 556+6.5
+	"SMA_ACRREMAFGCQB",  //Remington ACR 556+6.5
+	"SMA_ACRREMAFG", //Remington ACR 556+6.5
+	"SMA_ACRREMMOECQB", //Remington ACR 556+6.5
+	"SMA_ACRREMMOE", //Remington ACR 556+6.5
+	"SMA_ACRREMblk", //Remington ACR 556+6.5
+	"SMA_ACRREMAFGCQBblk", //Remington ACR 556+6.5
+	"SMA_ACRREMAFGblk", //Remington ACR 556+6.5
+	"SMA_ACRREMMOECQBblk", //Remington ACR 556+6.5
+	"SMA_ACRREMMOEblk", //Remington ACR 556+6.5
+	"SMA_ACRREMGL_B", //Remington ACR 556+6.5
+	"SMA_ACRREMCQBGL", //Remington ACR 556+6.5
+	"SMA_ACRREMGL", //Remington ACR 556+6.5
+	"LMG_Mk200_F", //Mk200 Series
+	"LMG_Mk200_black_F" //Mk200 Series
+];
+
+_restrictedItems = [ // Items that are allowed for Specific USE Case (RRC / Marksman / etc.)
+	"A3_GPNVG18b_REC_TI", // Thermal Quad
+	"A3_GPNVG18_REC_TI", // Thermal Quad
+	"A3_GPNVG18b_TI", // Thermal Quad
+	"A3_GPNVG18_TI", // Thermal Quad
+	"A3_GPNVG18b_REC_BLK_TI", // Thermal Quad
+	"A3_GPNVG18_REC_BLK_TI", // Thermal Quad
+	"A3_GPNVG18b_BLK_TI", // Thermal Quad
+	"A3_GPNVG18_BLK_TI", // Thermal Quad
+	"NVGogglesB_gry_F", // ENVG
+	"NVGogglesB_grn_F", // ENVG
+	"NVGogglesB_blk_F", // ENVG
+	"optic_Nightstalker", // Thermal Optic
+	"rhsusf_acc_anpas13gv1", // Thermal Optic
+	"Tier1_ANPVS10_Tan", // Thermal Optic
+	"rhsusf_acc_anpvs27", // Thermal Optic
+	"optic_tws_mg", // Thermal Optic
+	"optic_tws", // Thermal Optic
+	"Tier1_ATACR18_ADM_Black", //Nightforce Series Optic
+	"Tier1_ATACR18_ADM_Desert", //Nightforce Series Optic
+	"Tier1_ATACR18_ADM_Desert_Vanilla", //Nightforce Series Optic
+	"Tier1_ATACR18_ADM_Black_Vanilla", //Nightforce Series Optic
+	"Tier1_ATACR18_ADM_T1_Black", //Nightforce Series Optic
+	"Tier1_ATACR18_ADM_T1_Desert", //Nightforce Series Optic
+	"Tier1_ATACR18_ADM_T1_Black_Vanilla", //Nightforce Series Optic
+	"Tier1_ATACR18_ADM_T1_Desert_Vanilla", //Nightforce Series Optic
+	"Tier1_ATACR18_Geissele_Black", //Nightforce Series Optic
+	"Tier1_ATACR18_Geissele_Desert", //Nightforce Series Optic
+	"Tier1_ATACR18_Geissele_Black_Vanilla", //Nightforce Series Optic
+	"Tier1_ATACR18_Geissele_Desert_Vanilla", //Nightforce Series Optic
+	"Tier1_ATACR18_Geissele_Docter_Black", //Nightforce Series Optic
+	"Tier1_ATACR18_Geissele_Docter_Desert", //Nightforce Series Optic
+	"Tier1_ATACR18_Geissele_Docter_Black_Vanilla", //Nightforce Series Optic
+	"Tier1_ATACR18_Geissele_Docter_Desert_Vanilla", //Nightforce Series Optic
+	"optic_lrps", //Nightforce Series Optic
+	"optic_lrps_ghex_F", //Nightforce Series Optic
+	"optic_lrps_tna_F", //Nightforce Series Optic
+	"ACE_optic_LRPS_2D", //Nightforce Series Optic
+	"ACE_optic_LRPS_PIP" //Nightforce Series Optic
+];
+
+_tabbedItems = [ // Items that are allowed for individuals with Ranger Tab
+	"arifle_SPAR_03_snd_F", // HK417 Series
+	"arifle_SPAR_03_blk_F", // HK417 Series
+	"arifle_SPAR_03_khk_F", // HK417 Series
+	"SMA_HK417", // HK417 Series
+	"SMA_HK417vfg", // HK417 Series
+	"SMA_HK417_16in", // HK417 Series
+	"rhs_weap_SCARH_CQC", // Scar H Series
+	"rhs_weap_SCARH_FDE_CQC", // Scar H Series
+	"rhs_weap_SCARH_FDE_LB", // Scar H Series
+	"rhs_weap_SCARH_LB", // Scar H Series
+	"rhs_weap_SCARH_FDE_STD", // Scar H Series
+	"rhs_weap_SCARH_STD", // Scar H Series
+	"rhs_weap_SCARH_USA_CQC", // Scar H Series
+	"rhs_weap_SCARH_USA_LB", // Scar H Series
+	"rhs_weap_SCARH_USA_STD", // Scar H Series
+	"SMA_Mk17", // Scar H Series
+	"SMA_Mk17_black", // Scar H Series
+	"SMA_Mk17_green", // Scar H Series
+	"SMA_Mk17_EGML", // Scar H Series
+	"SMA_Mk17_EGML_black", // Scar H Series
+	"SMA_Mk17_EGML_green", // Scar H Series
+	"SMA_Mk17_16", // Scar H Series
+	"SMA_Mk17_16_black", // Scar H Series
+	"SMA_Mk17_16_green", // Scar H Series
+	"Tier1_SR25", // SR-25 Series
+	"Tier1_SR25_tan", // SR-25 Series
+	"Tier1_SR25_ec", // SR-25 Series
+	"Tier1_SR25_ec_tan", // SR-25 Series
+	"arifle_MXC_F", // MXC Series
+	"arifle_MXC_black_F", // MXC Series
+	"arifle_MXC_khk_F", // MXC Series
+	"arifle_MXM_F", // MXM Series
+	"arifle_MXM_black_F", // MXM Series
+	"arifle_MXM_khk_F", // MXM Series
+	"arifle_MX_F", // MX Series
+	"arifle_MX_black_F", // MX Series
+	"arifle_MX_khk_F", // MX Series
+	"arifle_MX_GL_F", // MX 3GL Series
+	"arifle_MX_GL_black_F", // MX 3GL Series
+	"arifle_MX_GL_khk_F", // MX 3GL Series
+	"arifle_MX_SW_F", // MX LSW Series
+	"arifle_MX_SW_black_F", // MX LSW Series
+	"arifle_MX_SW_khk_F", // MX LSW Series
+	"Tier1_MK48_Mod0", // Mk48 Series
+	"Tier1_MK48_Mod0_Desert", // Mk48 Series
+	"Tier1_MK48_Mod0_Para", // Mk48 Series
+	"Tier1_MK48_Mod0_Para_Desert", // Mk48 Series
+	"Tier1_MK48_Mod1", // Mk48 Series
+	"Tier1_MK48_Mod1_Desert" // Mk48 Series
+];
+
+_memeItems = [ // Items that serve no purpose other than to MEME
+	"UK3CB_Cocaine_Brick",
+	"ACE_Banana"
+];
+
+
+// INSTANTIATE VARS
+private _returnLines = [];
+
+_unlisted = [];
+
+_restricted = [];
+_blacklist = [];
+_tabbed = [];
+_meme = [];
+
+private _nonCompliantItemsCount = 0;
+
+// PRIVATE FUNCTIONS
+private _logItem = {
+	params ["_playerObj", "_categoryText", "_itemClassName"];
+	private _cfg = _itemClassName call CBA_fnc_getItemConfig;
+	_returnLines pushBack (format[
+		"[MILSIM] (logPlayerInventory): %1 :: className=""%2"" displayName=""%3"" %4",
+		_categoryText,
+		_itemClassName,
+		[_cfg] call BIS_fnc_displayName,
+		[_playerObj] call _playerInfoString
+	]);
+};
+
+private _playerInfoString = {
+	params ["_playerObj"];
+	format["playerName=""%1"" playerUID=""%2"" playerGroup=""%3""", name _playerObj, getPlayerUID _playerObj, groupId (group _playerObj)];
+};
+
+
+// GATHER INVENTORY
+// _items = [];
+// _items pushback headgear _player;
+// _items pushback uniform _player;
+// _items append uniformItems _player;
+// _items pushback vest _player;
+// _items append vestItems _player;
+// _items pushback backpack _player;
+// _items append backpackItems _player;
+// _items pushback hmd _player;
+// _items pushback binocular _player;
+// _items pushback primaryWeapon _player;
+// _items append primaryWeaponItems _player;
+// _items pushback secondaryWeapon _player;
+// _items append secondaryWeaponItems _player;
+
+_items = [
+	_player, // Unit
+	true, // Include weapons, attachments, loaded magazines
+	true, // Include items in backpack
+	true, // Include items in vest
+	true, // Include items in uniform
+	true, // Include assigned items
+	true // Include not loaded magazines
+] call CBA_fnc_uniqueUnitItems;
+
+_items pushBack (headgear _player);
+_items pushBack (uniform _player);
+
+// CHECK INVENTORY
+_returnLines pushBack (format[
+	"[MILSIM] (logPlayerInventory): CHECKING :: %1",
+	[_player] call _playerInfoString
+]);
+
+{
+	_item = _x;
+	_modes = getArray(configfile >> "CfgWeapons" >> _item >> "visionMode");
+
+	_subModes = [configfile >> "CfgWeapons" >> _item >> "ItemInfo" >> "OpticsModes", 1] call BIS_fnc_returnChildren;
+
+	{
+		_modes append getArray( _x >> "visionMode" );
+	} forEach _subModes;
+
+
+	if ( _item in _blackListItems ) then {
+		_blacklist pushBackUnique _item;
+	};
+
+	if ( _item in _restrictedItems ) then {
+		_restricted pushBackUnique _item;
+	};
+
+	if ( _item in _tabbedItems ) then {
+		_tabbed pushBackUnique _item;
+	};
+
+	if ( _item in _memeItems ) then {
+		_meme pushBackUnique _item;
+	};
+
+	if ((count _modes) isNotEqualTo 0) then {
+		_modes = _modes apply { toLower _x };
+		if ( "ti" in _modes ) then {
+			_unlisted pushBackUnique _item;
+		};
+	};
+
+} forEach _items;
+
+
+
+
+{
+	_nonCompliantItemsCount = _nonCompliantItemsCount + 1;
+	[_player, "BLACKLISTED", _x] call _logItem;
+} forEach _blacklist;
+
+{
+	_nonCompliantItemsCount = _nonCompliantItemsCount + 1;
+	[_player, "RESTRICTED", _x] call _logItem;
+} forEach _restricted;
+
+{
+	_nonCompliantItemsCount = _nonCompliantItemsCount + 1;
+	[_player, "TABBED", _x] call _logItem;
+} forEach _tabbed;
+
+{
+	_nonCompliantItemsCount = _nonCompliantItemsCount + 1;
+	[_player, "MEME", _x] call _logItem;
+} forEach _meme;
+
+{
+	if (
+		_x in _blackListItems ||
+		_x in _restrictedItems
+	) then {continue}; // Skip items that are already checked
+	_nonCompliantItemsCount = _nonCompliantItemsCount + 1;
+	[_player, "UNLISTED THERMAL", _x] call _logItem;
+} forEach _unlisted;
+
+if (_nonCompliantItemsCount isEqualTo 0) then {
+	_returnLines pushBack (format[
+		"[MILSIM] (logPlayerInventory): COMPLIANT :: %1",
+		[_player] call _playerInfoString
+	]);
+};
+
+// returns array of strings
+_returnLines;

functions/settings/fn_addCBASettings.sqf

@@ -6,7 +6,7 @@
 	"milsim_sideChat",
 	"CHECKBOX",
 	"Side Chat Text Enabled",
-	["17th Batallion", "Side Chat"],
+	["17th Battalion", "Side Chat"],
 	false,
 	true,
 	{
@@ -25,7 +25,7 @@
 	"milsim_server_cps_enable",
 	"CHECKBOX",
 	"CPS Metrics Enabled",
-	["17th Batallion", "Server Metrics"],
+	["17th Battalion", "Server Metrics"],
 	true,
 	true,
 	{
@@ -40,7 +40,7 @@
 	"milsim_server_cps_interval",
 	"TIME",
 	"Metrics Interval",
-	["17th Batallion", "Server Metrics"],
+	["17th Battalion", "Server Metrics"],
 	[60,300,120],
 	true,
 	{
@@ -71,7 +71,7 @@
 	"milsim_client_cps_enable",
 	"CHECKBOX",
 	"CPS Metrics Enabled",
-	["17th Batallion", "Client Metrics"],
+	["17th Battalion", "Client Metrics"],
 	true,
 	true,
 	{
@@ -86,7 +86,7 @@
 	"milsim_client_cps_interval",
 	"TIME",
 	"CPS Metrics Interval",
-	["17th Batallion", "Client Metrics"],
+	["17th Battalion", "Client Metrics"],
 	[60,300,120],
 	true,
 	{
@@ -104,6 +104,26 @@
 	}
 ] call CBA_fnc_addSetting;
 
+//---------------------
+//	Medical Overlay
+//---------------------
+
+[
+	"milsim_client_medState3D_enabled", // variable
+	"CHECKBOX", // type
+	["Enable 3D Triage Card State", "Draws a colored dot over units within 10m indicating current ACE Triage State"], // title
+	["17th Battalion", "Medical"], // category
+	true // default value
+] call CBA_fnc_addSetting;
+
+[
+	"milsim_client_medState3D_drawRange", // variable
+	"LIST", // type
+	["Range To Draw Icons", "Determines range at which dots are visible"], // title
+	["17th Battalion", "Medical"], // category
+	[[2, 4, 6, 8, 10], ["2", "4", "6", "8", "10"], 4] // option values, option labels, default index
+] call CBA_fnc_addSetting;
+
 
 diag_log text "[MILSIM] (settings) Custom CBA settings initialized";
 

mission_settings.hpp

@@ -6,6 +6,8 @@ onLoadMission = "THIS APPEARS BELOW THE LOADING SCREEN IMAGE";
 briefingName = "THIS IS THE NAME ON THE #MISSIONS LIST";
 overviewText = "THIS IS WHERE YOU DESCRIBE THE MISSION IN THE #MISSION LIST";
 
+missionSeries = "";
+
 // activate via #ace-fortify west base 2000
 
 class ACEX_Fortify_Presets {