Merge branch 'main' into inv_expan

Reviewed-on: https://17th-gs.iceberg-gaming.com:5443/hizumi/MissionTemplate/pulls/14

CHANGELOG.md

@@ -4,6 +4,35 @@ All notable changes to this project will be documented in this file.
 
 The format is based on [Keep a Changelog](https://keepachangelog.com/en/1.0.0/), and this project badly attempts [Semantic Versioning](https://semver.org/spec/v2.0.0.html).
 
+## [3.1.3] - 2024-01-10
+
+
+### Changed
+- Merge triage-status-draw3d to fix draw overlay for medics
+
+## [3.1.2] - 2024-01-04
+
+### Added
+- Add forgotten code file file for medical overlay
+
+### Changed
+- Merge update-flag-exclusions branch to fix issues with vehicles not applying flag
+
+## [3.1.1] - 2024-01-04
+
+### Changed
+- Spelling Fixes
+- Update class binding for vehicle flag interaction
+
+## [3.1.0] - 2023-12-17
+
+### Added
+
+- Vehicles now have an ace interaction to allow the mounting of flags onto them for identification. Contributed by IndigoFox
+- Added inventory validation checks
+- Added empty group removal code due to ownership issues on entity transfers
+- Added medical card visibility to medics for triage purposes
+
 ## [3.0.2] - 2023-10-14
 
 ### Changed

description.ext

@@ -17,6 +17,7 @@
 /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
 
 #include "mission_settings.hpp"
+#include "functions\definitions\DisallowedEquipment.hpp"
 
 //-------------------------------------------MISSION INFO--------------------------------------------------------------------
 /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

functions/CfgFunctions.hpp

@@ -32,18 +32,27 @@ class milsim
 		class bindEventHandlers { postInit = 1; };
 		class bindVehicleActions { postInit = 1; };
 		class addClientStatsPFH {};
+		class addMedicalOverlayPFH { postInit = 1; };
 		class calculateClientStats {};
+		class initVehicleFlags { postInit = 1; };
+		class bindEmptyGroupGarbageCleanup { postInit = 1; };
 	};
 
 	class server {
 		class addServerStatsPFH {};
 		class calculateServerStats {};
+		class logPlayerInventory {};
 	};
 
 	class resupply {
+		class crateDefinitions {};
 		class createAmmoBox {};
-		class createWeaponsBox {};
+		class createBox {};
+		class createCSWBox {};
+		class createLaunchersBox {};
 		class createMedicalBox {};
+		class createMortarBox {};
+		class createWeaponsBox {};
 	}
 
 	class ambience {
@@ -60,4 +69,35 @@ class milsim
 		class mapMarkerToString {}; //needs refactor
 		class stringToMapMarker {}; //needs refactor
 	};
+
+	class util
+	{
+		class logMissionInfo { postInit = 1; };
+		class addPlayerInfoToArray {};
+		class log {};
+	};
+};
+
+class milsim_reinsert {
+	class functions {
+		file = "functions\reinsert";
+		class getBaseName {};
+		class getNearestBase {};
+	};
+	class server {
+		file = "functions\reinsert\server";
+		class initServer { postInit = 1; };
+		class addToQueue {};
+		class globalShowQueue {};
+		class removeFromQueue {};
+		class returnReinsertQueueNotification {};
+		class validateQueue {};
+	};
+	class client {
+		file = "functions\reinsert\client";
+		class initClient { postInit = 1; };
+		class addAceSelfActions {};
+		class addCheckQueueSelfAction {};
+		class requestShowQueue {};
+	};
 };

functions/client/fn_addClientStatsPFH.sqf

@@ -8,7 +8,7 @@ _cpsPFH = [
 	},
 	"milsim_client_cps_interval" call CBA_settings_fnc_get,
 	[],
-	{ diag_log text format ["[MILSIM] (client) PFH loaded with interval %1 seconds", "milsim_client_cps_interval" call CBA_settings_fnc_get ], },
+	{ diag_log text format ["[MILSIM] (client) PFH loaded with interval %1 seconds", "milsim_client_cps_interval" call CBA_settings_fnc_get ] },
 	{ diag_log text format ["[MILSIM] (client) PFH unloaded"] },
 	{ "milsim_client_cps_enable" call CBA_settings_fnc_get },
 	{ false },

functions/client/fn_addMedicalOverlayPFH.sqf

@@ -0,0 +1,99 @@
+/*
+
+milsim_fnc_addMedicalOverlayPFH
+
+Author: IndigoFox
+
+Description:
+    Affects players with medical permissions. Will see a 3D colored dot over nearby (5-10m)
+	unconscious players who are not in a vehicle
+	which indicates their current ACE Triage Card status.
+	Designed to increase efficiency of CCPs.
+
+*/
+
+// Force setting if CBA doesn't work?
+if (isNil "milsim_client_medState3D_enabled") then {
+	milsim_client_medState3D_enabled = true;
+};
+if (isNil "milsim_client_medState3D_drawRange") then {
+	milsim_client_medState3D_drawRange = 10;
+};
+
+// List of units to draw icons for
+milsim_client_medState3D_drawTargets = []; 
+
+// ACE Triage colors, for consistency across UIs and functions
+// #define TRIAGE_COLOR_NONE      0.5, 0.5, 0.5, 0.1
+// #define TRIAGE_COLOR_MINIMAL   0, 0.5, 0, 0.9
+// #define TRIAGE_COLOR_DELAYED   1, 0.84, 0, 0.9
+// #define TRIAGE_COLOR_IMMEDIATE 1, 0, 0, 0.9
+// #define TRIAGE_COLOR_DECEASED  0, 0, 0, 0.9
+
+// ACE Triage colors, for consistency across UIs and functions
+milsim_client_medState3D_colors = [
+	[0, 0.5, 0, 0.9], // TRIAGE_COLOR_MINIMAL
+	[1, 0.84, 0, 0.9], // TRIAGE_COLOR_DELAYED
+	[1, 0, 0, 0.9], // TRIAGE_COLOR_IMMEDIATE
+	[0.15, 0.15, 0.15, 0.9], // TRIAGE_COLOR_DECEASED
+	[0.5, 0.5, 0.5, 0] // TRIAGE_COLOR_NONE
+];
+
+// Per-frame handler to draw icons
+// cleanup
+if (!isNil "milsim_client_medState3D_pfh") then {
+	[milsim_client_medState3D_pfh] call CBA_fnc_removePerFrameHandler;
+};
+// add pfh
+milsim_client_medState3D_pfh =	[{
+	// if disabled, skip processing
+	if (!milsim_client_medState3D_enabled) exitWith {false};
+	// if no targets, skip processing
+	if (count milsim_client_medState3D_drawTargets == 0) exitWith {false};
+	if !([player] call ace_medical_treatment_fnc_isMedic) exitWith {false};
+	{
+		// distance within 10 meters
+		if (player distance _x > milsim_client_medState3D_drawRange) then {continue};
+		// check unit not null, not conscious, and not in a vehicle
+		if (
+			!(_x getVariable ["ACE_isUnconscious", false]) ||
+			!isNull (objectParent _x)
+		) then {continue};
+
+		// color based on triage level
+		private _triageLevel = _x getVariable ["ace_medical_triageLevel", -1];
+		if (_triageLevel == -1) then {continue};
+		private _color = milsim_client_medState3D_colors select (
+			(_x getVariable ["ace_medical_triageLevel", -1]) -1
+		);
+		// draw position, slightly above the prone unit
+		private _drawPos = (visiblePosition _x) vectorAdd [0, 0, 0.5];
+		// draw icon
+		drawIcon3D [
+			"\A3\ui_f\data\map\markers\military\dot_CA.paa", // icon texture
+			_color, // color
+			_drawPos, // position AGL
+			1, // width
+			1, // height
+			0 // angle
+			// further params optional, omitted
+		];
+	} forEach milsim_client_medState3D_drawTargets;
+}, 0, []] call CBA_fnc_addPerFrameHandler;
+
+// subroutine to gather nearest 50 units every 5 seconds and store in milsim_client_medState3D_drawTargets
+// cleanup
+if (!isNil "milsim_client_medState3D_drawTargetsPfh") then {
+	[milsim_client_medState3D_drawTargetsPfh] call CBA_fnc_removePerFrameHandler;
+};
+// add pfh
+milsim_client_medState3D_drawTargetsPfh = [{
+	milsim_client_medState3D_drawTargets = (
+		(allUnits + allDeadMen) select {
+			_x isKindOf "CAManBase" && 
+			player distance _x < 50 &&
+			!isNull _x &&
+			player isNotEqualTo _x
+		}
+	);
+}, 5, false] call CBA_fnc_addPerFrameHandler;

functions/client/fn_addZenModules.sqf

@@ -5,35 +5,42 @@ if ( !hasInterface ) exitWith {};
 	"Create Resupply Box", 
 	{
 		params [["_pos", [0,0,0], [[]], 3], ["_target", objNull, [objNull]]];
-		
+		_keysSorted = keys milsim_resupply_crateDefinitions;
+		_keysSorted sort true;
+		_comboOptions = [];
+		_comboOptions resize (count _keysSorted);
+		for "_i" from 0 to (count _keysSorted) - 1 do {
+			private _definition = milsim_resupply_crateDefinitions get (_keysSorted select _i);
+			_comboOptions set [_i, [
+				_definition getOrDefault ["displayName", "ERROR"], // display name
+				_definition getOrDefault ["description", "No description"], // tooltip
+				_definition getOrDefault ["icon", "No icon"] // icon
+			]];
+		};
+
 		[
 			"Resupply Box Options",
 			[
-				[ "COMBO", "Box Type", [[1,2,3], [["Ammo"],["Weapons"],["Medical"]],0] ]
+				// [ "COMBO", "Box Type", [[1,2,3], [["Ammo"],["Weapons"],["Medical"]],0] ]
+				["COMBO", "Box Type", [_keysSorted, _comboOptions, 0]]
 			],
 			{
 				
 				params ["_dialog", "_args"];
 				
-				_dialog params ["_type"];
-				_args params ["_pos", "_target"];
-						
-				switch (_type) do {
-					case 1: {
-						[_target, _pos] call milsim_fnc_createAmmoBox;
-					};
-					case 2: {
-						[_target, _pos] call milsim_fnc_createWeaponsBox;
-					};
-					case 3: {
-						[_target, _pos] call milsim_fnc_createMedicalBox;
-					};
+				_dialog params ["_typeOptionSelected"];
+				_args params ["_pos", "_target", "_keysSorted"];
+
+
+				private _box = [_target, _typeOptionSelected, _pos] call milsim_fnc_createBox;
+				if (isNull _box) exitWith {
+					["Resupply Box", "WARNING: Failed to locate or create box!"] call BIS_fnc_curatorHint;
 				};
+				["Resupply Box", format["Created a %1 box", _typeOptionSelected]] call BIS_fnc_curatorHint;
 			},
 			{},
-			[_pos, _target]
+			[_pos, _target, _options]
 		] call zen_dialog_fnc_create;
-
 	}
 ] call zen_custom_modules_fnc_register;
 

functions/client/fn_bindEmptyGroupGarbageCleanup.sqf

@@ -0,0 +1,23 @@
+diag_log text format ["[MILSIM] (client) initializing empty group deletion PFH"];
+
+_emptyGroupPFH = [
+	{ 
+		{
+			if (local _x) then {
+				if ((count units _x) == 0) then {
+					deleteGroup _x;
+				};
+			};
+		} forEach allGroups;
+	},
+	300,
+	[],
+	{ diag_log text format ["[MILSIM] (client) Empty Group Deletion PFH loaded"] },
+	{ diag_log text format ["[MILSIM] (client) Empty Group Deletion"] },
+	{ true },
+	{ false },
+	[]
+] call CBA_fnc_createPerFrameHandlerObject;
+
+
+

functions/client/fn_bindEventHandlers.sqf

@@ -3,9 +3,13 @@ if ( !hasInterface ) exitWith {};
 player addEventHandler["Respawn", 
 	{
 		params ["_unit", "_corpse"];
-		_killer = _corpse getVariable ["ace_medical_causeOfDeath", "#scripted"];
+		private _killer = _corpse getVariable ["ace_medical_causeOfDeath", "#scripted"];
 		if (_killer == "respawn_button") then {
-			format["[MILSIM] (client) %1 was unconscious then clicked the respawn button", name _unit] remoteExec["diag_log", 0];
+			[
+				"client",
+				"RESPAWNED WHILE UNCONSCIOUS",
+				[_unit] call milsim_fnc_addPlayerInfoToArray
+			] remoteExec ["milsim_fnc_log", 2];
 		//	format["%1 was unconscious then clicked the respawn button", name _unit] remoteExec["systemChat", 0];
 		};
 	}
@@ -38,6 +42,14 @@ addMissionEventHandler ["HandleChatMessage",
 ];
 
 
+["ace_arsenal_displayClosed", {
+	[player] remoteExec ["milsim_fnc_logPlayerInventory", 2];
+}] call CBA_fnc_addEventHandler;
+
+[missionNamespace, "arsenalClosed", {
+	[player] remoteExec ["milsim_fnc_logPlayerInventory", 2];
+}] call BIS_fnc_addScriptedEventHandler;
+
 diag_log text "[MILSIM] (client) event handlers bound";
 
 nil;

functions/client/fn_initVehicleFlags.sqf

@@ -0,0 +1,225 @@
+milsim_vehicleflag_options = [
+	["Chevron IDs", [
+		["flag_chevron_id1", createHashMapFromArray [
+			["Title", "Flag 1"],
+			["Texture", "textures\flag_number\flag_id_1_co.paa"]
+		]],
+		["flag_chevron_id2", createHashMapFromArray [
+			["Title", "Flag 2"],
+			["Texture", "textures\flag_number\flag_id_2_co.paa"]
+		]],
+		["flag_chevron_id3", createHashMapFromArray [
+			["Title", "Flag 3"],
+			["Texture", "textures\flag_number\flag_id_3_co.paa"]
+		]],
+		["flag_chevron_id4", createHashMapFromArray [
+			["Title", "Flag 4"],
+			["Texture", "textures\flag_number\flag_id_4_co.paa"]
+		]],
+		["flag_chevron_id5", createHashMapFromArray [
+			["Title", "Flag 5"],
+			["Texture", "textures\flag_number\flag_id_5_co.paa"]
+		]],
+		["flag_chevron_id6", createHashMapFromArray [
+			["Title", "Flag 6"],
+			["Texture", "textures\flag_number\flag_id_6_co.paa"]
+		]],
+		["flag_chevron_id7", createHashMapFromArray [
+			["Title", "Flag 7"],
+			["Texture", "textures\flag_number\flag_id_7_co.paa"]
+		]],
+		["flag_chevron_id8", createHashMapFromArray [
+			["Title", "Flag 8"],
+			["Texture",  "textures\flag_number\flag_id_8_co.paa"]
+		]],
+		["flag_chevron_id9", createHashMapFromArray [
+			["Title", "Flag 9"],
+			["Texture", "textures\flag_number\flag_id_9_co.paa"]
+		]],
+		["flag_chevron_id10", createHashMapFromArray [
+			["Title", "Flag 10"],
+			["Texture", "textures\flag_number\flag_id_10_co.paa"]
+		]],
+		["flag_chevron_hq", createHashMapFromArray [
+			["Title", "Flag HQ"],
+			["Texture", "textures\flag_number\flag_id_hq_co.paa"]
+		]]
+	]],
+	["Simple Shapes", [
+		["flag_simpleshape_greenoctagon", createHashMapFromArray [
+			["Title", "Green Octagon"],
+			["Texture", "textures\simple_shape\flag_simpleshape_greenoctagon_co.paa"]
+		]],
+		["flag_simpleshape_bluecircle", createHashMapFromArray [
+			["Title", "Blue Circle"],
+			["Texture", "textures\simple_shape\flag_simpleshape_bluecircle_co.paa"]
+		]],
+		["flag_simpleshape_orangesquare", createHashMapFromArray [
+			["Title", "Orange Square"],
+			["Texture", "textures\simple_shape\flag_simpleshape_orangesquare_co.paa"]
+		]],
+		["flag_simpleshape_pinktriangle", createHashMapFromArray[
+			["Title", "Pink Triangle"],
+			["Texture", "textures\simple_shape\flag_simpleshape_pinktriangle_co.paa"]
+		]],
+		["flag_simpleshape_redpentagon", createHashMapFromArray [
+			["Title", "Red Pentagon"],
+			["Texture", "textures\simple_shape\flag_simpleshape_redpentagon_co.paa"]
+		]]
+	]],
+	["Miscellaneous", [
+		["flag_17th_emblem", createHashMapFromArray [
+			["Title", "17th Emblem"],
+			["Texture", "textures\flags_misc\flag_17th_emblem_co.paa"]
+		]],
+		["flag_redcross", createHashMapFromArray [
+			["Title", "Red Cross"],
+			["Texture", "textures\flags_misc\flag_redcross_co.paa"]
+		]]
+	]]
+];
+
+
+private _appliedParentClasses = [
+	"LandVehicle",
+	"Helicopter"
+];
+
+private _modelsWithoutFlagProxies = [
+	"TF373_SOAR_MH47G_Base", // MH-47G Chinook
+	"RHS_MELB_base", // MELB AH-6M/MH-6M/H-6M Little Bird
+	"USAF_C17", // C17 Globemaster III
+	"USAF_C130J", // C130J Super Hercules
+	"USAF_AC130U", // AC130 Spooky II
+	"ej_UH60M_base", // UH-60M Black Hawk + DAP variants
+	"rhsusf_fmtv_base" // M1083A1P2 variants + SOV SOCOM variants
+];
+
+{
+	private _parentClass = _x;
+	[_parentClass, "InitPost", {
+		private _flagActionID = "SetVehicleFlag";
+		private _flagMasterAction = [
+			_flagActionID, // id
+			"Set Vehicle Flag", // displayed title
+			"\A3\ui_f\data\map\markers\flags\nato_ca.paa", // flag icon
+			{true}, // statement
+			{
+				params ["_target", "_player", "_params"];
+				private _modelsWithoutFlagProxies = _params select 1;
+				
+				// check if hierarchy includes any of the models without flag proxies
+				private _excluded = false;
+				{
+					if (_excluded) exitWith {false};
+					_excluded = _target isKindOf _x;
+				} forEach _modelsWithoutFlagProxies;
+				if (_excluded) exitWith {false};
+				
+
+				// check if vehicle is alive
+				alive _target;
+			}, // condition
+			{
+				params ["_target", "_player", "_params"];
+				private _flagActionID = _params#0;
+				private _actions = [];
+				{
+					_x params ["_flagCategory", "_flagOptions"];
+					// diag_log format ["NewFlagCategory: %1 %2", _flagCategory, _flagOptions];
+
+					private _flagCategoryOption = [
+						_flagActionID + "_" + _flagCategory, // id
+						_flagCategory, // displayed title
+						(_flagOptions#0#1) get "Texture", // flag icon
+						{true}, // statement
+						{
+							params ["_target", "_player", "_params"];
+							alive _target;
+							// true;
+						}, // condition
+						{
+							params ["_target", "_player", "_params"];
+							_params params ["_flagActionID", "_flagCategoryID", "_flagOptions"];
+							private _categoryOptions = [];
+							{
+								_x params ["_flagOptionID", "_flagOptionData"];
+								// diag_log format ["NewFlagOption: %1 %2", _flagOptionID, _flagOptionData];
+								private _newFlagOption = [
+									_flagActionID + "_" + _flagCategory + "_" + _flagOptionID, // id
+									_flagOptionData get "Title", // displayed title
+									_flagOptionData get "Texture", // flag icon
+									{
+										params ["_target", "_player", "_params"];
+										_target forceFlagTexture (_params select 2);
+									}, // statement
+									{
+										params ["_target", "_player", "_params"];
+										alive _target;
+										// true;
+									}, // condition
+									nil, // child code
+									[_flagActionID, _flagCategoryID, getMissionPath (_flagOptionData get "Texture")], // params
+									nil, // position
+									4, // distance
+									[false, false, false, false, false] // other params
+								] call ace_interact_menu_fnc_createAction;
+								_categoryOptions pushBack [_newFlagOption, [], _target];
+							} forEach _flagOptions;
+							_categoryOptions;
+						}, // child code
+						[_flagActionID, _flagCategoryID, _flagOptions], // params
+						nil, // position
+						4, // distance
+						[false, false, false, false, false], // other params
+						nil // modifier function code
+					] call ace_interact_menu_fnc_createAction;
+
+					_actions pushBack [_flagCategoryOption, [], _target];
+				} forEach milsim_vehicleflag_options;
+
+				_actions;
+			}, // child code
+			[_flagActionID, _modelsWithoutFlagProxies], // params
+			nil, // position
+			4, // distance
+			[false, false, false, false, false], // other params
+			nil // modifier function code
+		] call ace_interact_menu_fnc_createAction;
+
+		// add action to add flag
+		[
+			(_this select 0), // object
+			0, // action 0 or self-action 1
+			["ACE_MainActions"], // parent
+			_flagMasterAction // action
+		] call ace_interact_menu_fnc_addActionToObject;
+		
+		
+		// add action to remove flag
+		private _removeFlagAction = [
+			_flagActionID + "_removeflag", // id
+			"Remove Flag", // displayed title
+			"\A3\ui_f\data\map\markers\flags\nato_ca.paa", // flag icon
+			{
+				params ["_target", "_player", "_params"];
+				_target forceFlagTexture "";
+			}, // statement
+			{
+				params ["_target", "_player", "_params"];
+				alive _target && getForcedFlagTexture _target != "";
+			}, // condition
+			nil // child code
+		] call ace_interact_menu_fnc_createAction;
+
+		[
+			(_this select 0), // object
+			0, // action 0 or self-action 1
+			["ACE_MainActions", _flagActionID], // parent
+			_removeFlagAction // action
+		] call ace_interact_menu_fnc_addActionToObject;
+			
+	}, true, [], true] call CBA_fnc_addClassEventHandler;
+} forEach _appliedParentClasses;
+
+nil;

functions/definitions/DisallowedEquipment.hpp

@@ -0,0 +1,223 @@
+// To access these from SQF:
+// to get an array of STRING with each subclass name:
+// (missionConfigFile >> "DisallowedEquipment") call BIS_fnc_getCfgSubClasses
+// To access a specific class' properties:
+// (missionConfigFile >> "DisallowedEquipment" >> "blacklisted" >> "label") call BIS_fnc_getCfgData;
+// (missionConfigFile >> "DisallowedEquipment" >> "blacklisted" >> "description") call BIS_fnc_getCfgData;
+// (missionConfigFile >> "DisallowedEquipment" >> "blacklisted" >> "items") call BIS_fnc_getCfgDataArray;
+
+class DisallowedEquipment {
+	class blacklisted {
+		label = "BLACKLISTED WEAPON OR ITEM";
+		description = "Items that NO member is allowed to use.";
+		items[] = {
+			"17BN_ANPVS14", // NVG AN/PVS-14
+			"ej_PVS15D", // NVG AN/PVS-15
+			"ej_VPS15", // NVG AN/PVS-15
+			"LMG_Mk200_black_F", //Mk200 Series
+			"LMG_Mk200_F", //Mk200 Series
+			"rhs_weap_g36c", // G36 Series
+			"rhs_weap_g36kv_ag36", // G36 Series
+			"rhs_weap_g36kv", // G36 Series
+			"rhs_weap_m14_d", // M14 Series
+			"rhs_weap_m14_fiberglass", // M14 Series
+			"rhs_weap_m14_rail_d", // M14 Series
+			"rhs_weap_m14_rail_fiberglass", // M14 Series
+			"rhs_weap_m14_rail_wd", // M14 Series
+			"rhs_weap_m14_rail", // M14 Series
+			"rhs_weap_m14_ris_d", // M14 Series
+			"rhs_weap_m14_ris_fiberglass", // M14 Series
+			"rhs_weap_m14_ris_wd", // M14 Series
+			"rhs_weap_m14_ris", // M14 Series
+			"rhs_weap_m14_socom_rail", // M14 Series
+			"rhs_weap_m14_socom", // M14 Series
+			"rhs_weap_m14_wd", // M14 Series
+			"rhs_weap_m14_weap_m14ebrri", // M14 Series
+			"rhs_weap_m14", // M14 Series
+			"rhs_weap_m16a4_carryhandle_M203", // M16 Series
+			"rhs_weap_m16a4_carryhandle", // M16 Series
+			"rhs_weap_m16a4_imod_M203", // M16 Series
+			"rhs_weap_m16a4_imod", // M16 Series
+			"rhs_weap_m16a4", // M16 Series
+			"rhs_weap_m27iar_grip", // M27 Series
+			"rhs_weap_m27iar", // M27 Series
+			"rhsusf_ANPVS_14", // NVG AN/PVS-14
+			"rhsusf_ANPVS_15", // NVG AN/PVS-15
+			"SMA_ACRREM", //Remington ACR 556+6.5
+			"SMA_ACRREMAFG", //Remington ACR 556+6.5
+			"SMA_ACRREMAFGblk", //Remington ACR 556+6.5
+			"SMA_ACRREMAFGCQB",  //Remington ACR 556+6.5
+			"SMA_ACRREMAFGCQBblk", //Remington ACR 556+6.5
+			"SMA_ACRREMblk", //Remington ACR 556+6.5
+			"SMA_ACRREMCQBGL", //Remington ACR 556+6.5
+			"SMA_ACRREMGL_B", //Remington ACR 556+6.5
+			"SMA_ACRREMGL", //Remington ACR 556+6.5
+			"SMA_ACRREMMOE", //Remington ACR 556+6.5
+			"SMA_ACRREMMOEblk", //Remington ACR 556+6.5
+			"SMA_ACRREMMOECQB", //Remington ACR 556+6.5
+			"SMA_ACRREMMOECQBblk", //Remington ACR 556+6.5
+			"srifle_DMR_06_camo_F", // M14 Series
+			"srifle_DMR_06_hunter_F", // M14 Series
+			"srifle_DMR_06_olive_F", // M14 Series
+			"srifle_EBR_F", // Mk14 Series
+			"Tier1_SIG_CMX_115_Virtus_300BLK_Black", // MCX 300 Blackout
+			"Tier1_SIG_CMX_115_Virtus_300BLK_Desert", // MCX 300 Blackout
+			"Tier1_SIG_CMX_115_Virtus_300BLK_FDE", // MCX 300 Blackout
+			"Tier1_SIG_CMX_115_Virtus_300BLK", // MCX 300 Blackout
+			"UK3CB_AG36_MLIC", // G36 Series
+			"UK3CB_AG36_TAC_K", // G36 Series
+			"UK3CB_AG36A1", // G36 Series
+			"UK3CB_AG36E1", // G36 Series
+			"UK3CB_AG36V", // G36 Series
+			"UK3CB_FNFAL_FOREGRIP", // FN_FAL Series
+			"UK3CB_FNFAL_FULL_RAILS", // FN_FAL Series
+			"UK3CB_FNFAL_FULL", // FN_FAL Series
+			"UK3CB_FNFAL_OSW_GL", // FN_FAL Series
+			"UK3CB_FNFAL_OSW", // FN_FAL Series
+			"UK3CB_FNFAL_PARA_RAILS", // FN_FAL Series
+			"UK3CB_FNFAL_PARA", // FN_FAL Series
+			"UK3CB_FNFAL_STG58", // FN_FAL Series
+			"UK3CB_G36_KSK_K", // G36 Series
+			"UK3CB_G36_KSK", // G36 Series
+			"UK3CB_G36_LSW", // G36 Series
+			"UK3CB_G36_MLIC_C", // G36 Series
+			"UK3CB_G36_MLIC_K", // G36 Series
+			"UK3CB_G36_MLIC", // G36 Series
+			"UK3CB_G36_TAC_C", // G36 Series
+			"UK3CB_G36_TAC", // G36 Series
+			"UK3CB_G36A1_C", // G36 Series
+			"UK3CB_G36A1_K", // G36 Series
+			"UK3CB_G36A1", // G36 Series
+			"UK3CB_G36E1_C", // G36 Series
+			"UK3CB_G36E1_K", // G36 Series
+			"UK3CB_G36E1", // G36 Series
+			"UK3CB_G36V_C", // G36 Series
+			"UK3CB_G36V_K", // G36 Series
+			"UK3CB_G36V", // G36 Series
+			"UK3CB_M14_Railed", // M14 Series
+			"UK3CB_M14", // M14 Series
+			"UK3CB_M14DMR_BLK", // M14 Series
+			"UK3CB_M14DMR_Railed_BLK", // M14 Series
+			"UK3CB_M14DMR_Railed", // M14 Series
+			"UK3CB_M14DMR", // M14 Series
+			"UK3CB_M16_Carbine", // M16 Series
+			"UK3CB_M16A1_LSW", // M16 Series
+			"UK3CB_M16A1", // M16 Series
+			"UK3CB_M16A2_UGL", // M16 Series
+			"UK3CB_M16A2", // M16 Series
+			"UK3CB_M16A3", // M16 Series
+			"USP_PVS_14", // NVG AN/PVS-14
+			"USP_PVS_15" // NVG AN/PVS-15
+		};
+	};
+
+	class restrictedItems {
+		label = "RESTRICTED ITEM";
+		description = "Items that are allowed for specific USE Case (RRC / Marksman / etc.)";
+		items[] = {
+			"A3_GPNVG18_BLK_TI", // Thermal Quad
+			"A3_GPNVG18_REC_BLK_TI", // Thermal Quad
+			"A3_GPNVG18_REC_TI", // Thermal Quad
+			"A3_GPNVG18_TI", // Thermal Quad
+			"A3_GPNVG18b_BLK_TI", // Thermal Quad
+			"A3_GPNVG18b_REC_BLK_TI", // Thermal Quad
+			"A3_GPNVG18b_REC_TI", // Thermal Quad
+			"A3_GPNVG18b_TI", // Thermal Quad
+			"ACE_optic_LRPS_2D", //Nightforce Series Optic
+			"ACE_optic_LRPS_PIP", //Nightforce Series Optic
+			"NVGogglesB_blk_F", // ENVG
+			"NVGogglesB_grn_F", // ENVG
+			"NVGogglesB_gry_F", // ENVG
+			"optic_lrps_ghex_F", //Nightforce Series Optic
+			"optic_lrps_tna_F", //Nightforce Series Optic
+			"optic_lrps", //Nightforce Series Optic
+			"optic_Nightstalker", // Thermal Optic
+			"optic_tws_mg", // Thermal Optic
+			"optic_tws", // Thermal Optic
+			"rhsusf_acc_anpas13gv1", // Thermal Optic
+			"rhsusf_acc_anpvs27", // Thermal Optic
+			"Tier1_ANPVS10_Tan", // Thermal Optic
+			"Tier1_ATACR18_ADM_Black_Vanilla", //Nightforce Series Optic
+			"Tier1_ATACR18_ADM_Black", //Nightforce Series Optic
+			"Tier1_ATACR18_ADM_Desert_Vanilla", //Nightforce Series Optic
+			"Tier1_ATACR18_ADM_Desert", //Nightforce Series Optic
+			"Tier1_ATACR18_ADM_T1_Black_Vanilla", //Nightforce Series Optic
+			"Tier1_ATACR18_ADM_T1_Black", //Nightforce Series Optic
+			"Tier1_ATACR18_ADM_T1_Desert_Vanilla", //Nightforce Series Optic
+			"Tier1_ATACR18_ADM_T1_Desert", //Nightforce Series Optic
+			"Tier1_ATACR18_Geissele_Black_Vanilla", //Nightforce Series Optic
+			"Tier1_ATACR18_Geissele_Black", //Nightforce Series Optic
+			"Tier1_ATACR18_Geissele_Desert_Vanilla", //Nightforce Series Optic
+			"Tier1_ATACR18_Geissele_Desert", //Nightforce Series Optic
+			"Tier1_ATACR18_Geissele_Docter_Black_Vanilla", //Nightforce Series Optic
+			"Tier1_ATACR18_Geissele_Docter_Black", //Nightforce Series Optic
+			"Tier1_ATACR18_Geissele_Docter_Desert_Vanilla", //Nightforce Series Optic
+			"Tier1_ATACR18_Geissele_Docter_Desert" //Nightforce Series Optic
+		};
+	};
+
+	class tabbedItems { // Items that are allowed for individuals with Ranger Tab
+		label = "TABBED WEAPON";
+		description = "Items that are allowed for individuals with Ranger Tab.";
+		items[] = {
+			"arifle_MX_black_F", // MX Series
+			"arifle_MX_F", // MX Series
+			"arifle_MX_GL_black_F", // MX 3GL Series
+			"arifle_MX_GL_F", // MX 3GL Series
+			"arifle_MX_GL_khk_F", // MX 3GL Series
+			"arifle_MX_khk_F", // MX Series
+			"arifle_MX_SW_black_F", // MX LSW Series
+			"arifle_MX_SW_F", // MX LSW Series
+			"arifle_MX_SW_khk_F", // MX LSW Series
+			"arifle_MXC_black_F", // MXC Series
+			"arifle_MXC_F", // MXC Series
+			"arifle_MXC_khk_F", // MXC Series
+			"arifle_MXM_black_F", // MXM Series
+			"arifle_MXM_F", // MXM Series
+			"arifle_MXM_khk_F", // MXM Series
+			"arifle_SPAR_03_blk_F", // HK417 Series
+			"arifle_SPAR_03_khk_F", // HK417 Series
+			"arifle_SPAR_03_snd_F", // HK417 Series
+			"rhs_weap_SCARH_CQC", // Scar H Series
+			"rhs_weap_SCARH_FDE_CQC", // Scar H Series
+			"rhs_weap_SCARH_FDE_LB", // Scar H Series
+			"rhs_weap_SCARH_FDE_STD", // Scar H Series
+			"rhs_weap_SCARH_LB", // Scar H Series
+			"rhs_weap_SCARH_STD", // Scar H Series
+			"rhs_weap_SCARH_USA_CQC", // Scar H Series
+			"rhs_weap_SCARH_USA_LB", // Scar H Series
+			"rhs_weap_SCARH_USA_STD", // Scar H Series
+			"SMA_HK417_16in", // HK417 Series
+			"SMA_HK417", // HK417 Series
+			"SMA_HK417vfg", // HK417 Series
+			"SMA_Mk17_16_black", // Scar H Series
+			"SMA_Mk17_16_green", // Scar H Series
+			"SMA_Mk17_16", // Scar H Series
+			"SMA_Mk17_black", // Scar H Series
+			"SMA_Mk17_EGML_black", // Scar H Series
+			"SMA_Mk17_EGML_green", // Scar H Series
+			"SMA_Mk17_EGML", // Scar H Series
+			"SMA_Mk17_green", // Scar H Series
+			"SMA_Mk17", // Scar H Series
+			"Tier1_MK48_Mod0_Desert", // Mk48 Series
+			"Tier1_MK48_Mod0_Para_Desert", // Mk48 Series
+			"Tier1_MK48_Mod0_Para", // Mk48 Series
+			"Tier1_MK48_Mod0", // Mk48 Series
+			"Tier1_MK48_Mod1_Desert", // Mk48 Series
+			"Tier1_MK48_Mod1", // Mk48 Series
+			"Tier1_SR25_ec_tan", // SR-25 Series
+			"Tier1_SR25_ec", // SR-25 Series
+			"Tier1_SR25_tan", // SR-25 Series
+			"Tier1_SR25" // SR-25 Series
+		};
+	};
+
+	class memeItems {
+		label = "MEME ITEM";
+		description = "Items that serve no purpose other than to MEME.";
+		items[] = {
+			"ACE_Banana",
+			"UK3CB_Cocaine_Brick"
+		};
+	};
+};

functions/fbcb2/fn_messageFBCB2AssetStatus.sqf

@@ -11,7 +11,7 @@ _text = composeText [_text, parseText "<t align='left' size='2'>Asset</t><t alig
 	_assigned = _x select 2;
 	_available =  0; //count (getMarkerPos "respawn_west"  nearEntities [ _asset, 2000] );  
 	
-	 _homes = allMissionObjects "ModuleRespawnPosition_F";
+	_homes = allMissionObjects "ModuleRespawnPosition_F";
 
 	{
 		_home = _x;

functions/fbcb2/fn_processFBCB2Callsigns.sqf

@@ -2,19 +2,19 @@
 _text = "
 <font size='24' color='#ff0000'>=======------   Mission Data Set   ------=======</font>
 <br/><br/>
-<font color='#00FF00' size='16'>RIPTIDE</font><br/>
+<font color='#00FF00' size='16'>SPARTAN</font><br/>
 Command
 <br/><br/>
-<font color='#00FF00' size='16'>ONI</font><br/>
+<font color='#00FF00' size='16'>BLACKJACK</font><br/>
 Alpha Platoon
 <br/><br/>
-<font color='#00FF00' size='16'>GOLIATH</font><br/>
+<font color='#00FF00' size='16'>ZOOMER</font><br/>
 Echo
 <br/><br/>
 <font color='#00FF00' size='16'>TIGER</font><br/>
 RRC
 <br/><br/>
-<font color='#00FF00' size='16'>BLACKFOOT/font><br/>
+<font color='#00FF00' size='16'>BLACKFOOT</font><br/>
 Weapons Squad
 <br/><br/>
 ";

functions/init/fn_initPlayerLocal.sqf

@@ -1,5 +1,17 @@
 if ( !hasInterface ) exitWith {};
 
+if (!isServer) then {
+	["milsim_logText", {
+		params [["_strArray", [""], [[]]]];
+		{
+			diag_log text _x;
+		} forEach _strArray;
+	}] call CBA_fnc_addEventHandler;
+};
+
+// define milsim_resupply_crateDefinitions
+call milsim_fnc_crateDefinitions;
+
 ["InitializePlayer", [player, true]] call BIS_fnc_dynamicGroups;
 
 nil;

functions/init/fn_initServer.sqf

@@ -1,5 +1,8 @@
 if (!isServer) exitWith {};
 
+// define milsim_resupply_crateDefinitions
+call milsim_fnc_crateDefinitions;
+
 _fixedAssets = [ 
 	["Ares",  "USAF_A10",   0], 
 	["Odyssey",  "RHSGREF_A29B_HIDF",   0], 
@@ -50,10 +53,17 @@ missionNamespace setVariable ["milsim_var_rotaryAssets", _rotaryAssets];
 publicVariable "milsim_var_fixedAssets";
 publicVariable "milsim_var_rotaryAssets";
 
+
+
 // Initializes the Dynamic Groups framework and groups
 ["Initialize", [true]] call BIS_fnc_dynamicGroups;
 
-
+["milsim_logText", {
+	params [["_strArray", [""], [[]]]];
+	{
+		diag_log text _x;
+	} forEach _strArray;
+}] call CBA_fnc_addEventHandler;
 
 missionNamespace setVariable ["milsim_complete", true];
 diag_log text "[MILSIM] (initServer) milsim_complete: version 2.3";

functions/reinsert/client/fn_addAceSelfActions.sqf

@@ -0,0 +1,67 @@
+params ["_type"]; // string of the object's classname
+if (!(_type isKindOf "CAManBase")) exitWith {};
+
+if (
+	(localNamespace getVariable ["milsim_reinsert_fileForReinsertClassesAdded", []])
+	find _type != -1
+) exitWith {};
+
+private _fileForReinsertAction = [
+	"milsim_reinsert_fileReinsertRequest",
+	"File Re-insert Request",
+	"\A3\ui_f\data\igui\cfg\simpleTasks\types\takeoff_ca.paa",
+	{ // statement
+		params ["_target", "_player", "_params"];
+		// find nearest base or location
+		private _base = [_player] call milsim_reinsert_fnc_getNearestBase;
+		private _baseName = [_base] call milsim_reinsert_fnc_getBaseName;
+		// send event to server
+		["milsim_reinsert_fileReinsertRequest", [_player, _base]] call CBA_fnc_serverEvent;
+		// notify player their request was filed
+		[["Re-insert Request Filed"], [format["Location: %1", _baseName]]] call CBA_fnc_notify;
+	},
+	{ // condition
+		params ["_target", "_player", "_params"];
+		// find nearest base or location
+		private _base = [_player] call milsim_reinsert_fnc_getNearestBase;
+		private _baseDistance = _player distance _base;
+
+		private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
+		private _existingQueue = missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []];
+
+		// check if module is enabled, player is near a base, and player is not already in the queue
+		// (serverTime - milsim_reinsert_missionStartServerTime) > 60*5 && // only allow after 15 minutes
+		missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_enabled", true] &&
+		(_baseDistance < _maxRangeToReady) &&
+		not (_player in (_existingQueue apply {_x#0}))
+	}
+] call ace_interact_menu_fnc_createAction;
+[_type, 1, ["ACE_SelfActions"], _fileForReinsertAction, true] call ace_interact_menu_fnc_addActionToClass;
+
+private _removeFileForReinsertAction = [
+	"milsim_reinsert_removeReinsertRequest",
+	"Remove Re-insert Request",
+	"\A3\ui_f\data\igui\cfg\simpleTasks\types\land_ca.paa",
+	{ // statement
+		params ["_target", "_player", "_params"];
+		// send event to server
+		["milsim_reinsert_removeReinsertRequest", [_player]] call CBA_fnc_serverEvent;
+		// notify player their request was rescinded
+		"Re-insert Request Rescinded" call CBA_fnc_notify;
+	},
+	{ // condition
+		params ["_target", "_player", "_params"];
+		private _existingQueue = missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []];
+
+		// check if module is enabled, player is in the queue
+		// (serverTime - milsim_reinsert_missionStartServerTime) > 60*5 && // only allow after 15 minutes
+		missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_enabled", true] &&
+		(_player in (_existingQueue apply {_x#0}))
+	}
+] call ace_interact_menu_fnc_createAction;
+[_type, 1, ["ACE_SelfActions"], _removeFileForReinsertAction, true] call ace_interact_menu_fnc_addActionToClass;
+
+private _classesActionsAddedTo = (localNamespace getVariable ["milsim_reinsert_fileForReinsertClassesAdded", []]);
+_classesActionsAddedTo pushBackUnique _type;
+localNamespace setVariable ["milsim_reinsert_fileForReinsertClassesAdded", _classesActionsAddedTo];
+

functions/reinsert/client/fn_addCheckQueueSelfAction.sqf

@@ -0,0 +1,28 @@
+params ["_type"]; // string of the object's classname
+if (!(_type isKindOf "CAManBase")) exitWith {};
+
+if (
+	(localNamespace getVariable ["milsim_reinsert_checkReinsertQueueClassesAdded", []])
+	find _type != -1
+) exitWith {};
+
+private _checkReinsertQueueAction = [
+	"milsim_reinsert_checkReinsertQueue",
+	"[PILOT] Check Re-insert Queue",
+	"\A3\ui_f\data\igui\cfg\simpleTasks\types\land_ca.paa",
+	{
+		params ["_target", "_player", "_params"];
+		// request notification from the server
+		call milsim_reinsert_fnc_requestShowQueue;
+		// reset last check time
+		localNamespace setVariable ["milsim_reinsert_lastReinsertQueueCheck", diag_tickTime];
+	},
+	{
+		missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_enabled", true]
+	} // always allow
+] call ace_interact_menu_fnc_createAction;
+[_type, 1, ["ACE_SelfActions"], _checkReinsertQueueAction, true] call ace_interact_menu_fnc_addActionToClass;
+
+private _classesActionsAddedTo = (localNamespace getVariable ["milsim_reinsert_checkReinsertQueueClassesAdded", []]);
+_classesActionsAddedTo pushBackUnique _type;
+localNamespace setVariable ["milsim_reinsert_checkReinsertQueueClassesAdded", _classesActionsAddedTo];

functions/reinsert/client/fn_initClient.sqf

@@ -0,0 +1,53 @@
+if (!hasInterface) exitWith {};
+
+// ACE SELF-INTERACTIONS FOR FILING AND RESCINDING REINSERT REQUESTS NEAR BASE - ALL PLAYERS
+localNamespace setVariable ["milsim_reinsert_fileForReinsertClassesAdded", []];
+// add actions to current class
+[typeOf player] call milsim_reinsert_fnc_addAceSelfActions;
+// add actions to future classes
+["ace_interact_menu_newControllableObject", {
+	_this call milsim_reinsert_fnc_addAceSelfActions;
+}] call CBA_fnc_addEventHandler;
+
+/////////////////////////////////////////////////////
+// PILOTS ONLY
+// ACE SELF-INTERACTIONS FOR CHECKING REINSERT QUEUE - ONLY FOR PILOTS
+if ((typeOf player) in ["B_Helipilot_F", "B_helicrew_F"]) then {
+	localNamespace setVariable ["milsim_reinsert_checkReinsertQueueClassesAdded", []];
+	localNamespace setVariable ["milsim_reinsert_lastReinsertQueueCheck", diag_tickTime];
+
+	// add actions to current class
+	[typeOf player] call milsim_reinsert_fnc_addCheckQueueSelfAction;
+	// add actions to future classes
+	["ace_interact_menu_newControllableObject", {
+		_this call milsim_reinsert_fnc_addCheckQueueSelfAction;
+	}] call CBA_fnc_addEventHandler;
+};
+/////////////////////////////////////////////////////
+
+
+// ADD TIMER FOR PILOTS - IF REINSERT LIST NOT CHECKED FOR 20 MINUTES, SHOW NOTIFICATION AUTOMATICALLY
+if ((typeOf player) in ["B_Helipilot_F", "B_helicrew_F"]) then {
+	[{
+		// if module not enabled and pilot forced check not enabled, exit
+		if (not (
+			missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_enabled", true] &&
+			missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_pilotForcedCheckEnabled", true]
+		)) exitWith {};
+
+		// if last check was less than X minutes ago, skip
+		private _lastCheck = localNamespace getVariable ["milsim_reinsert_lastReinsertQueueCheck", diag_tickTime];
+		private _requiredCheckInterval = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_pilotForcedCheckInterval", 60*20];
+		if (
+			diag_tickTime - _lastCheck <
+			_requiredCheckInterval
+		) exitWith {}; // if last check was less than X minutes ago, skip
+
+		// last check was greater than X minutes ago
+		// reset last check time
+		localNamespace setVariable ["milsim_reinsert_lastReinsertQueueCheck", diag_tickTime];
+		// request notification from the server
+		call milsim_reinsert_fnc_requestShowQueue;
+	}, 30] call CBA_fnc_addPerFrameHandler;
+};
+/////////////////////////////////////////////////////

functions/reinsert/client/fn_requestShowQueue.sqf

@@ -0,0 +1,3 @@
+if (!hasInterface) exitWith {};
+
+[] remoteExec ["milsim_reinsert_fnc_returnReinsertQueueNotification", 2];

functions/reinsert/fn_getBaseName.sqf

@@ -0,0 +1,8 @@
+params [["_base", objNull, [objNull]]];
+if (_base == objNull) exitWith {""};
+
+// get base name
+private _baseName = _base getVariable ["name", ""];
+if (_baseName == "") then {_baseName = format["near %1", text (nearestLocation [_base, ["NameCity", "NameLocal"]])]};
+
+_baseName;

functions/reinsert/fn_getNearestBase.sqf

@@ -0,0 +1,10 @@
+params [["_player", objNull, [objNull]]];
+if (isNull _player) exitWith {objNull};
+
+private _bases = missionNamespace getVariable ["milsim_reinsert_bases", []];
+if (count _bases == 0) exitWith {objNull};
+
+// get nearest base (Module_Respawn_F)
+private _closestBase = [_bases, _player] call BIS_fnc_nearestPosition;
+if (isNull _closestBase) exitWith {objNull};
+_closestBase;

functions/reinsert/server/fn_addToQueue.sqf

@@ -0,0 +1,56 @@
+params [
+	["_player", objNull, [objNull]],
+	["_base", objNull, [objNull]],
+	["_timeFiled", diag_tickTime, [25]]
+];
+
+if (!isServer) exitWith {
+	[
+		"respawn_reinsertion",
+		"ATTEMPTED RUN ON CLIENT",
+		[
+			["player", _player],
+			["base", _base]
+		]
+	] call milsim_fnc_log;
+};
+if (
+	isNull _player ||
+	isNull _base
+) exitWith {
+	[
+		"respawn_reinsertion",
+		"NULL PARAMETERS",
+		[
+			["player", _player],
+			["base", _base]
+		]
+	] call milsim_fnc_log;
+};
+
+
+private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
+// nearest base here is the same as the base sent
+private _nearestBase = _base;
+
+milsim_reinsert_reinsertionQueue pushBackUnique [
+	_player, _base, _timeFiled
+];
+// broadcast new list to all machines
+publicVariable "milsim_reinsert_reinsertionQueue";
+
+// log to rpt
+private _logParams = [
+	["filedAtBase", [_base] call milsim_reinsert_fnc_getBaseName],
+	["filedAtBaseDistance", _player distance _base],
+	["closestBase", [_nearestBase] call milsim_reinsert_fnc_getBaseName],
+	["closestBaseDistance", _player distance _nearestBase],
+	["maxDistanceSetting", _maxRangeToReady],
+	["inQueueDuration", diag_tickTime - _timeFiled]
+];
+_logParams = [_player, _logParams] call milsim_fnc_addPlayerInfoToArray;
+[
+	"respawn_reinsertion",
+	"PLAYER FILED REQUEST",
+	_logParams
+] call milsim_fnc_log;

functions/reinsert/server/fn_globalShowQueue.sqf

@@ -0,0 +1,70 @@
+if (!isServer) exitWith {};
+
+// if at least 1 player in the queue has been waiting longer than the configured timeout, notify all players
+private _timeout = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_max_wait", 60*20]; // default 20 minutes
+private _timeoutPlayers = milsim_reinsert_reinsertionQueue select {
+	_x params ["_player", "_base", "_timeFiled"];
+	alive (_player) &&
+	(diag_tickTime - (_timeFiled)) > _timeout
+};
+if (count _timeoutPlayers > 0) then {
+	// GLOBAL CBA NOTIFY
+	private _playerLines = [["Players are still waiting for Re-insert!", 1.2, [1, 0.64, 0, 1]]];
+	private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
+
+	// get base objects from queue
+	private _basesWithPeople = (missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []]) apply {_x#1};
+	// get unique base objects
+	private _basesWithPeople = _basesWithPeople arrayIntersect _basesWithPeople;
+
+	{
+		private _thisBase = _x;
+
+		// Add line for base name
+		_playerLines pushBack ([[_thisBase] call milsim_reinsert_fnc_getBaseName, 1, [0,1,0,1]]);
+
+		// Get players under this base
+		private _thisBasePlayers = _timeoutPlayers select {_x#1 isEqualTo _thisBase};
+		// sort _timeoutPlayers by time in queue, descending
+		_thisBasePlayers = [_thisBasePlayers, [], {
+			_x params ["_player", "_base", "_timeFiled"];
+			_timeFiled;
+		}, "DESCEND"] call BIS_fnc_sortBy;
+
+
+		{ // for each player under this base, add a line
+			_x params ["_player", "_base", "_timeFiled"];
+			// get the closest base to the player
+			private _nearestBase = [_player] call milsim_reinsert_fnc_getNearestBase;
+
+			// add player to array of players under bases
+			_playerLines pushBack ([format [
+				"%1: %2 [%3]",
+				groupID (group (_player)),
+				name (_player),
+				[diag_tickTime - (_timeFiled), "MM:SS"] call BIS_fnc_secondsToString
+			], 0.8, [0.8, 0.8, 0.8, 1]]);
+
+			// log to rpt
+			private _logParams = [
+				["filedAtBase", [_base] call milsim_reinsert_fnc_getBaseName],
+				["filedAtBaseDistance", _player distance _base],
+				["closestBase", [_nearestBase] call milsim_reinsert_fnc_getBaseName],
+				["closestBaseDistance", _player distance _nearestBase],
+				["maxDistanceSetting", _maxRangeToReady],
+				["inQueueDuration", diag_tickTime - _timeFiled]
+			];
+			_logParams = [_player, _logParams] call milsim_fnc_addPlayerInfoToArray;
+			[
+				"respawn_reinsertion",
+				"PLAYER WAITING OVER TIMEOUT",
+				_logParams
+			] call milsim_fnc_log;
+		} forEach _thisBasePlayers;
+	} forEach _basesWithPeople;
+
+	// SEND NOTIFY
+	_playerLines remoteExec ["CBA_fnc_notify", [0, -2] select isDedicated];
+	// RESET NOTIFICATION TIMER
+	milsim_reinsert_reinsertionOverTimeoutLastNotificationTime = diag_tickTime;
+};

functions/reinsert/server/fn_initServer.sqf

@@ -0,0 +1,50 @@
+// if a player files for reinsert using self-interaction
+// they're added to the queue along with their nearest base location and the time they filed
+// if a player's time in the queue exceeds the configured timeout, a message will be posted every 5 minutes on a cycle based around
+// the player's time in the queue stating how long they have been waiting, their name, and their group's name
+
+if (!isServer) exitWith {};
+
+// array of all respawn modules in the mission, used as 'base' locations for reinsertion
+milsim_reinsert_bases = allMissionObjects "ModuleRespawnPosition_F";
+publicVariable "milsim_reinsert_bases";
+
+// register queue
+milsim_reinsert_reinsertionQueue = [];
+publicVariable "milsim_reinsert_reinsertionQueue";
+
+
+// server mission start time
+milsim_reinsert_missionStartServerTime = serverTime;
+
+// FILE REQUEST CBA HANDLER
+["milsim_reinsert_fileReinsertRequest", {
+	params ["_player", "_base"];
+	[_player, _base] call milsim_reinsert_fnc_addToQueue;
+}] call CBA_fnc_addEventHandler;
+
+// REMOVE REQUEST CBA HANDLER
+["milsim_reinsert_removeReinsertRequest", {
+	params ["_player"];
+	[_player] call milsim_reinsert_fnc_removeFromQueue;
+}] call CBA_fnc_addEventHandler;
+
+
+// automated wait threshold timer
+milsim_reinsert_reinsertionOverTimeoutLastNotificationTime = 0;
+
+[{ // every 60 seconds
+
+	// validate queue
+	call milsim_reinsert_fnc_validateQueue;
+
+	// check if last overTimeout notification was sent more than X minutes ago
+	if (
+		diag_tickTime - milsim_reinsert_reinsertionOverTimeoutLastNotificationTime > 60*5
+	) then {
+		// show global queue notification with any players that are over timeout
+		call milsim_reinsert_fnc_globalShowQueue;
+	};
+
+}, 60] call CBA_fnc_addPerFrameHandler;
+

functions/reinsert/server/fn_removeFromQueue.sqf

@@ -0,0 +1,57 @@
+params [["_player", objNull, [objNull]]];
+
+if (!isServer) exitWith {
+	[
+		"respawn_reinsertion",
+		"ATTEMPTED RUN ON CLIENT",
+		[
+			["player", _player]
+		]
+	] call milsim_fnc_log;
+};
+if (isNull _player) exitWith {
+	[
+		"respawn_reinsertion",
+		"NULL PARAMETERS",
+		[
+			["player", _player]
+		]
+	] call milsim_fnc_log;
+};
+
+// get entries for this player from queue
+private _unitArrs = milsim_reinsert_reinsertionQueue select {_x#0 isEqualTo _player};
+// if player not in queue, skip
+if (count _unitArrs isEqualTo 0) exitWith {};
+
+private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
+
+// remove player from queue
+milsim_reinsert_reinsertionQueue = milsim_reinsert_reinsertionQueue - _unitArrs;
+// broadcast new list to all machines
+publicVariable "milsim_reinsert_reinsertionQueue";
+
+// sort _unitArrs by time in queue, descending, to get longest wait (if for some reason there's a duplicate)
+[_unitArrs, [], {
+	_x#2
+}, "DESCEND"] call BIS_fnc_sortBy;
+
+// get first entry (longest wait)
+(_unitArrs#0) params ["_player", "_base", "_timeFiled"]; // _unitArr = [unit, base, timeInQueue]
+// get the closest base to the player
+private _nearestBase = [_player] call milsim_reinsert_fnc_getNearestBase;
+// log to rpt
+private _logParams = [
+	["filedAtBase", [_base] call milsim_reinsert_fnc_getBaseName],
+	["filedAtBaseDistance", _player distance _base],
+	["closestBase", [_nearestBase] call milsim_reinsert_fnc_getBaseName],
+	["closestBaseDistance", _player distance _nearestBase],
+	["maxDistanceSetting", _maxRangeToReady],
+	["inQueueDuration", diag_tickTime - _timeFiled]
+];
+_logParams = [_player, _logParams] call milsim_fnc_addPlayerInfoToArray;
+[
+	"respawn_reinsertion",
+	"PLAYER RESCINDED REQUEST",
+	_logParams
+] call milsim_fnc_log;

functions/reinsert/server/fn_returnReinsertQueueNotification.sqf

@@ -0,0 +1,109 @@
+/*
+	Function: milsim_reinsert_fnc_showReinsertQueueNotification
+
+	Description:
+		Designed to be remoteExecuted on the server. Will show a CBA notification on the remoteExecutedOwner's screen with the current reinsertion queue and log this occurrence in the server RPT.
+
+	Author: IndigoFox
+*/
+
+if (not isRemoteExecuted) exitWith {
+	diag_log text format ["[milsim] (respawn_reinsertion) SHOW QUEUE NOT REMOTE EXECUTED"];
+};
+if (not isServer) exitWith {
+	diag_log text format ["[milsim] (respawn_reinsertion) SHOW QUEUE NOT RUN ON SERVER"];
+};
+
+private _users = allUsers apply {getUserInfo _x} select {count _x > 0};
+private _userIndex = _users findIf {_x#1 isEqualTo remoteExecutedOwner};
+if (_userIndex isEqualTo -1) exitWith {
+	diag_log text format ["[milsim] (respawn_reinsertion) SHOW QUEUE USER NOT FOUND"];
+};
+private _userObject = _users select _userIndex select 10;
+if (isNull _userObject) exitWith {
+	diag_log text format ["[milsim] (respawn_reinsertion) SHOW QUEUE USER OBJECT NOT FOUND"];
+};
+
+// log to rpt
+private _logParams = [_userObject, []] call milsim_fnc_addPlayerInfoToArray;
+[
+	"respawn_reinsertion",
+	"SHOW QUEUE REQUESTED",
+	_logParams
+] call milsim_fnc_log;
+
+private _queue = missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []];
+// get base objects from queue
+private _basesWithPeople = (missionNamespace getVariable ["milsim_reinsert_reinsertionQueue", []]) apply {_x#1};
+// get unique base objects
+private _basesWithPeople = _basesWithPeople arrayIntersect _basesWithPeople;
+
+// text array to use in notification
+private _par = [["Players Awaiting Reinsert", 1.2, [1,0.64,0,1]]];
+
+if (count _basesWithPeople isEqualTo 0) then {
+	_par pushBack ["[QUEUE EMPTY]", 1, [1,1,1,1]];
+};
+
+// forEach _basesWithPeople
+{
+	private _thisBase = _x;
+	private _baseName = [_thisBase] call milsim_reinsert_fnc_getBaseName;
+	
+	// generate player lines for this base
+	private _playerLines = _queue select {
+		_x#1 isEqualTo _thisBase
+	} apply {
+		_x params ["_player", "_base", "_timeFiled"];
+		[
+			format [
+				"%1: %2 [%3]",
+				groupId (group _player),
+				name _player,
+				[diag_tickTime - _timeFiled, "MM:SS"] call BIS_fnc_secondsToString
+			],
+			0.8,
+			[1,1,1,1]
+		];
+	};
+
+	// determine suffix for player count based on count
+	private _playerCountText = "";
+	switch (count _playerLines) do {
+		case 0: {
+			_playerCountText = "No players";
+		};
+		case 1: {
+			_playerCountText = "1 player";
+		};
+		default {
+			_playerCountText = format ["%1 players", count _playerLines];
+		};
+	};
+	
+	// add base name and player count to notification lines
+	_par pushBack [
+		format ["Location: %1 (%2)", 
+			_baseName, 
+			_playerCountText
+		],
+		1,
+		[0,1,0,1]
+	];
+
+	// sort by text (first piece of text is group name)
+	_playerLines = [
+		_playerLines,
+		[],
+		{_x#0}
+	] call BIS_fnc_sortBy;
+
+	// add to notification lines	
+	{
+		_par pushBack _x;
+	} forEach _playerLines;
+} forEach _basesWithPeople;
+
+_par remoteExec ["CBA_fnc_notify", remoteExecutedOwner];
+
+true;

functions/reinsert/server/fn_validateQueue.sqf

@@ -0,0 +1,57 @@
+// revalidate any players in the queue
+// compare their distance to the nearest base, and remove them if they're too far away (or dead)
+private _stillValid = [];
+private _maxRangeToReady = missionNamespace getVariable ["milsim_reinsert_setting_reinsertion_maxRangeToReady", 400];
+{
+	_x params ["_player", "_base", "_timeFiled"]; // _unitArr = [unit, baseName, timeInQueue]
+
+	private _distanceToOriginalBase = _player distance _base;
+	// get the closest base to the player
+	private _nearestBase = [_player] call milsim_reinsert_fnc_getNearestBase;
+	private _isCloseEnoughToAnyBase = (_player distance _nearestBase) < _maxRangeToReady;
+
+	if (not _isCloseEnoughToAnyBase || not (alive _player)) then {
+		// don't include player in updated queue
+		// log to rpt
+		private _logParams = [
+			["filedAtBase", [_base] call milsim_reinsert_fnc_getBaseName],
+			["filedAtBaseDistance", _player distance _base],
+			["closestBase", [_nearestBase] call milsim_reinsert_fnc_getBaseName],
+			["closestBaseDistance", _player distance _nearestBase],
+			["maxDistanceSetting", _maxRangeToReady],
+			["inQueueDuration", diag_tickTime - _timeFiled]
+		];
+		_logParams = [_player, _logParams] call milsim_fnc_addPlayerInfoToArray;
+		[
+			"respawn_reinsertion",
+			"PLAYER DEQUEUED AUTOMATICALLY",
+			_logParams
+		] call milsim_fnc_log;
+		// continue loop
+		continue
+	};
+
+	// include player in updated queue, and update their location to nearest base
+	_stillValid pushBackUnique [_player, _nearestBase, _timeFiled];
+	// if player's base has changed, log to rpt
+	if (_base != _nearestBase) then {
+		private _logParams = [
+			["filedAtBase", [_base] call milsim_reinsert_fnc_getBaseName],
+			["filedAtBaseDistance", _player distance _base],
+			["closestBase", [_nearestBase] call milsim_reinsert_fnc_getBaseName],
+			["closestBaseDistance", _player distance _nearestBase],
+			["maxDistanceSetting", _maxRangeToReady],
+			["inQueueDuration", diag_tickTime - _timeFiled]
+		];
+		_logParams = [_player, _logParams] call milsim_fnc_addPlayerInfoToArray;
+		[
+			"respawn_reinsertion",
+			"PLAYER BASE WAS UPDATED",
+			_logParams
+		] call milsim_fnc_log;
+	};
+} forEach milsim_reinsert_reinsertionQueue;
+
+// broadcast new list to all machines
+milsim_reinsert_reinsertionQueue = _stillValid;
+publicVariable "milsim_reinsert_reinsertionQueue";

functions/resupply/fn_crateDefinitions.sqf

@@ -0,0 +1,201 @@
+milsim_resupply_crateDefinitions = createHashMapFromArray [
+	["AMMO LIGHT", createHashMapFromArray [
+		["className", "Box_Syndicate_Ammo_F"],
+		["displayName", "Ammo Crate"],
+		["description", "A crate containing general ammunition and equipment for an infantry squad."],
+		["icon", "\A3\ui_f\data\igui\cfg\simpleTasks\types\rifle_ca.paa"],
+		["items", createHashMapFromArray [
+			["backpacks", []],
+			["weapons", [
+				["rhs_weap_M136",4],
+				["rhs_weap_M136_hp",4],
+				["rhs_weap_m72a7",2]
+			]],
+			["magazines", [
+				["1Rnd_SmokePurple_Grenade_shell",12],
+				["1Rnd_SmokeBlue_Grenade_shell",24],
+				["1Rnd_SmokeOrange_Grenade_shell",12],
+				["rhs_mag_M441_HE",25],
+				["rhs_mag_M433_HEDP",15],
+				["ACE_40mm_Flare_ir",12],
+				["rhsusf_200Rnd_556x45_mixed_soft_pouch_coyote",25],
+				["rhsusf_20Rnd_762x51_m993_Mag",25],
+				["SmokeShell",12],
+				["rhs_mag_m67",12],
+				["1Rnd_Smoke_Grenade_shell",24],
+				["1Rnd_SmokeRed_Grenade_shell",24],
+				["1Rnd_SmokeGreen_Grenade_shell",24],
+				["1Rnd_SmokeYellow_Grenade_shell",12],
+				["Tier1_30Rnd_556x45_M856A1_EMag",25],
+				["Tier1_30Rnd_556x45_Mk318Mod0_EMag",75],
+				["ACE_30Rnd_65_Creedmor_mag",25],
+				["SMA_30Rnd_762x35_BLK_EPR",25],
+				["Tier1_30Rnd_762x35_300BLK_SMK_PMAG",25],
+				["SMA_30Rnd_68x43_SPC_FMJ",25],
+				["SMA_30Rnd_68x43_SPC_FMJ_Tracer",25],
+				["SMA_20Rnd_762x51mm_M80A1_EPR",25],
+				["SMA_20Rnd_762x51mm_M80A1_EPR_Tracer",25],
+				["SMA_20Rnd_762x51mm_Mk316_Mod_0_Special_Long_Range",25],
+				["SMA_20Rnd_762x51mm_Mk316_Mod_0_Special_Long_Range_Tracer",25],
+				["Tier1_250Rnd_762x51_Belt_M993_AP",15],
+				["ACE_20Rnd_762x51_Mag_Tracer",25],
+				["ACE_20Rnd_762x51_M993_AP_Mag",25],
+				["rhsusf_20Rnd_762x51_SR25_m993_Mag",25],
+				["Tier1_20Rnd_762x51_M993_SR25_Mag",25],
+				["Tier1_20Rnd_65x48_Creedmoor_SR25_Mag",25],
+				["rhssaf_30rnd_556x45_EPR_G36", 25],
+				["DemoCharge_Remote_Mag",16]
+			]],
+			["items", []]
+		]
+	]]],
+	["AMMO HEAVY", createHashMapFromArray [
+		["className", "Box_NATO_Wps_F"],
+		["displayName", "Heavy Ammo Crate"],
+		["description", "A crate containing mixed ammo for rifles, ARs, MAT, and HAT."],
+		["icon", "\A3\ui_f\data\igui\cfg\simpleTasks\types\heli_ca.paa"],
+		["items", createHashMapFromArray [
+			["backpacks", []],
+			["weapons", []],
+			["magazines", [
+				["MRAWS_HEAT_F",35],
+				["MRAWS_HE_F",15],
+				["Tier1_250Rnd_762x51_Belt_M993_AP",50],
+				["Tier1_30Rnd_556x45_M856A1_EMag",25],
+				["Tier1_30Rnd_556x45_Mk318Mod0_EMag",50],
+				["Titan_AA",10],
+				["Titan_AT",10],
+				["200Rnd_65x39_cased_Box_Tracer_Red",50]
+			]],
+			["items", []]
+		]
+	]]],
+	["AMMO MORTAR", createHashMapFromArray [
+		["className", "Box_Syndicate_Wps_F"],
+		["displayName", "Mortar Ammo Crate"],
+		["description", "A crate containing mortar ammunition."],
+		["icon", "\A3\ui_f\data\igui\cfg\simpleTasks\types\scout_ca.paa"],
+		["items", createHashMapFromArray [
+			["backpacks", []],
+			["weapons", []],
+			["magazines", [
+				["ACE_1Rnd_82mm_Mo_HE",24],
+				["ACE_1Rnd_82mm_Mo_Smoke",12],
+				["ACE_1Rnd_82mm_Mo_Illum",12]
+			]],
+			["items", []]
+		]
+	]]],
+	["MEDICAL", createHashMapFromArray [
+		["className", "ACE_medicalSupplyCrate_advanced"],
+		["displayName", "Medical Crate"],
+		["description", "A crate containing medical supplies."],
+		["icon", "\A3\ui_f\data\igui\cfg\simpleTasks\types\heal_ca.paa"],
+		["items", createHashMapFromArray [
+			["backpacks", []],
+			["weapons", []],
+			["magazines", []],
+			["items", [
+				["ACE_packingBandage",100],
+				["ACE_elasticBandage",100],
+				["ACE_tourniquet",48],
+				["ACE_splint",48],
+				["ACE_morphine",50],
+				["ACE_epinephrine",50],
+				["ACE_bloodIV",75],
+				["ACE_bloodIV_500",50],
+				["ACE_bloodIV_250",25],
+				["ACE_quikclot",75],
+				["ACE_personalAidKit", 5],
+				["ACE_surgicalKit", 5]
+			]]
+		]
+	]]],
+	["LAUNCHERS", createHashMapFromArray [
+		["className", "Box_NATO_WpsLaunch_F"],
+		["displayName", "Launcher Crate"],
+		["description", "A crate containing missile launchers and ammunition."],
+		["icon", "\A3\ui_f\data\igui\cfg\simpleTasks\types\heli_ca.paa"],
+		["items", createHashMapFromArray [
+			["backpacks", [
+
+			]],
+			["weapons", [
+				["launch_B_Titan_short_F",2],
+				["launch_NLAW_F",2],
+				["rhs_weap_fim92",2]
+			]],
+			["magazines", [
+				["Titan_AA",6],
+				["Titan_AT",6]
+			]],
+			["items", [
+
+			]]
+		]
+	]]],
+	["CSW", createHashMapFromArray [
+		["className", "Box_NATO_Equip_F"],
+		["displayName", "CSW Crate"],
+		["description", "A crate containing backpacks that assemble into static weapons."],
+		["icon", "\A3\ui_f\data\igui\cfg\simpleTasks\types\defend_ca.paa"],
+		["items", createHashMapFromArray [
+			["backpacks", [
+				["RHS_M2_Gun_Bag",2],
+				["RHS_M2_Tripod_Bag",2],
+				["RHS_M2_MiniTripod_Bag",2],
+				["rhs_Tow_Gun_Bag",2],
+				["rhs_TOW_Tripod_Bag",2],
+				["UK3CB_Static_M240_Elcan_Gun_Bag",2],
+				["UK3CB_B_Static_M240_Elcan_Tripod_Low_Bag_US_D",2],
+				["RHS_Mk19_Gun_Bag",2],
+				["RHS_Mk19_Tripod_Bag",2]
+			]],
+			["weapons", []],
+			["magazines", []],
+			["items", []]
+		]
+	]]],
+	["MORTAR MK6", createHashMapFromArray [
+		["className", "Box_NATO_WpsSpecial_F"],
+		["displayName", "Mortar MK6 Supply Crate"],
+		["description", "A crate containing Mk6 mortar resupply (tubes) and tools."],
+		["icon", "\A3\ui_f\data\igui\cfg\simpleTasks\types\scout_ca.paa"],
+		["items", createHashMapFromArray [
+			["backpacks", [
+				["B_Mortar_01_support_F",3],
+				["B_Mortar_01_weapon_F",6],
+				["UK3CB_LSM_B_B_CARRYALL_RADIO_TIG_STRIPE_01",1]
+			]],
+			["weapons", [
+				["ACE_Vector",2]
+			]],
+			["magazines", [
+				["acex_intelitems_notepad",2]
+			]],
+			["items", [
+				["ACE_artilleryTable",2],
+				["ACE_RangeTable_82mm",2],
+				["ACE_microDAGR",2],
+				["ACE_MapTools",2]
+			]]
+		]
+	]]],
+	["MORTAR 60MM COMMANDO", createHashMapFromArray [
+		["className", "Box_NATO_WpsSpecial_F"],
+		["displayName", "Mortar 60mm Commando Supply Crate"],
+		["description", "A crate containing COMMANDO 60mm mortar shells and some STANAGs."],
+		["icon", "\A3\ui_f\data\igui\cfg\simpleTasks\types\scout_ca.paa"],
+		["items", createHashMapFromArray [
+			["backpacks", []],
+			["weapons", []],
+			["magazines", [
+				["twc_2inch_he_1rnd",70],
+				["twc_2inch_smoke_1rnd",15],
+				["twc_2inch_illum_1rnd",15],
+				["Tier1_30Rnd_556x45_Mk318Mod0_EMag",20]
+			]],
+			["items", []]
+		]
+	]]]
+];

functions/resupply/fn_createAmmoBox.sqf

@@ -1,7 +1,7 @@
 /*
  * Author: Hizumi
  *
- * Create Ammo resupply box for the 17th Batallion
+ * Create Ammo resupply box for the 17th Battalion
  *
  * Arguments:
  * 0: Vehicle - <OBJECT>
@@ -12,9 +12,19 @@
  *
  * Example:
  * [box] call milsim_fnc_createAmmoBox; 			// create ammo box via init line of editor object
- * [objNull, pos] call milsim_fnc_createAmmoBox		// create ammo box via zeus module
+ * [objNull, pos] call milsim_fnc_createAmmoBox;		// create ammo box via zeus module
  *
  * Public: Yes
+ *
+ * Note: For gathering:
+	formatText ["%1", [
+		["containerClassname", typeOf cursorObject],
+		["backpack", (backpackCargo cursorObject) call BIS_fnc_consolidateArray],
+		["item", (itemCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazine", (magazineCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazineAmmo", magazinesAmmoCargo cursorObject],
+		["weapon", (weaponCargo cursorObject) call BIS_fnc_consolidateArray]
+	]];
  */
 
 
@@ -23,89 +33,4 @@ params [
 	["_pos", [0,0,0], [[]], 3]
 ];
 
-if (isNull _box) then {
-	_box = "Box_Syndicate_Ammo_F" createVehicle _pos;
-};
-
-clearBackpackCargoGlobal _box;
-clearItemCargoGlobal _box;
-clearMagazineCargoGlobal _box;
-clearWeaponCargoGlobal _box;
-
-_packs = [];
-
-_items = [];
-
-_magazines = [
-	["1Rnd_SmokePurple_Grenade_shell",12],
-	["1Rnd_SmokeBlue_Grenade_shell",24],
-	["1Rnd_SmokeOrange_Grenade_shell",12],
-	["rhs_mag_M441_HE",25],
-	["rhs_mag_M433_HEDP",15],
-	["ACE_40mm_Flare_ir",12],
-	["rhsusf_200Rnd_556x45_mixed_soft_pouch_coyote",25],
-	["rhsusf_20Rnd_762x51_m993_Mag",25],
-	["SmokeShell",12],
-	["rhs_mag_m67",12],
-	["1Rnd_Smoke_Grenade_shell",24],
-	["1Rnd_SmokeRed_Grenade_shell",24],
-	["1Rnd_SmokeGreen_Grenade_shell",24],
-	["1Rnd_SmokeYellow_Grenade_shell",12],
-	["Tier1_30Rnd_556x45_M856A1_EMag",25],
-	["Tier1_30Rnd_556x45_Mk318Mod0_EMag",75],
-	["ACE_30Rnd_65_Creedmor_mag",25],
-	["SMA_30Rnd_762x35_BLK_EPR",25],
-	["Tier1_30Rnd_762x35_300BLK_SMK_PMAG",25],
-	["SMA_30Rnd_68x43_SPC_FMJ",25],
-	["SMA_30Rnd_68x43_SPC_FMJ_Tracer",25],
-	["SMA_20Rnd_762x51mm_M80A1_EPR",25],
-	["SMA_20Rnd_762x51mm_M80A1_EPR_Tracer",25],
-	["SMA_20Rnd_762x51mm_Mk316_Mod_0_Special_Long_Range",25],
-	["SMA_20Rnd_762x51mm_Mk316_Mod_0_Special_Long_Range_Tracer",25],
-	["Tier1_250Rnd_762x51_Belt_M993_AP",15],
-	["ACE_20Rnd_762x51_Mag_Tracer",25],
-	["ACE_20Rnd_762x51_M993_AP_Mag",25],
-	["rhsusf_20Rnd_762x51_SR25_m993_Mag",25],
-	["Tier1_20Rnd_762x51_M993_SR25_Mag",25],
-	["Tier1_20Rnd_65x48_Creedmoor_SR25_Mag",25],
-	["rhssaf_30rnd_556x45_EPR_G36", 25],
-	["DemoCharge_Remote_Mag",16]
-];
-
-_weapons = [
-	["rhs_weap_M136",4],
-	["rhs_weap_M136_hp",4],
-	["rhs_weap_m72a7",2]
-];
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addBackpackCargoGlobal [_class, _qty]
-	
-} foreach _packs;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addItemCargoGlobal [_class, _qty]
-	
-} foreach _items;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addMagazineCargoGlobal [_class, _qty]
-	
-} foreach _magazines;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addWeaponCargoGlobal [_class, _qty]
-	
-} foreach _weapons;
-
-[_box,1] call ace_cargo_fnc_setSize;
-
-true;
+[_box, "AMMO LIGHT", _pos] call milsim_fnc_createBox;

functions/resupply/fn_createBox.sqf

@@ -0,0 +1,101 @@
+/*
+ * Author: Hizumi & IndigoFox
+ *
+ * Create Mortar resupply box for the 17th Battalion
+ *
+ * Arguments:
+ * 0: Vehicle - <OBJECT>
+ * 1: Position - <ARRAY>
+ *
+ * Return Value:
+ * Function executed <BOOL>
+ *
+ * Example:
+ * [box] call milsim_fnc_createBox; 			// create mortar ammo box via init line of editor object
+ * [objNull, pos] call milsim_fnc_createBox;		// create mortar ammo box via zeus module
+ *
+ * Public: Yes
+ *
+ * Note: For gathering:
+	formatText ["%1", [
+		["containerClassname", typeOf cursorObject],
+		["backpack", (backpackCargo cursorObject) call BIS_fnc_consolidateArray],
+		["item", (itemCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazine", (magazineCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazineAmmo", magazinesAmmoCargo cursorObject],
+		["weapon", (weaponCargo cursorObject) call BIS_fnc_consolidateArray]
+	]];
+ */
+
+
+params [
+	["_box", objNull, [objNull]],
+	["_type", "", [""]],
+	["_pos", [0,0,0], [[]], 3]
+];
+
+if (isNil "milsim_resupply_crateDefinitions") exitWith {
+	format["Resupply Boxes: milsim_resupply_crateDefinitions is not defined, possibly a bad edit?"] remoteExec ["systemChat", 0];
+	false;
+};
+
+if (_type isEqualTo "") exitWith {
+	format["Resupply Boxes: [_boxObject, _type, _pos] call milsim_fnc_createBox"] remoteExec ["systemChat", 0];
+	format["Please use one of the following types for _type:"] remoteExec ["systemChat", 0];
+	format["%1", (keys milsim_resupply_crateDefinitions)] remoteExec ["systemChat", 0];
+	false;
+};
+
+private _boxData = milsim_resupply_crateDefinitions getOrDefault [_type, createHashMap];
+if (count _boxData isEqualTo 0) exitWith {
+	format["Resupply Boxes: [_boxObject, _type, _pos] call milsim_fnc_createBox"] remoteExec ["systemChat", 0];
+	format["%1 is not a valid type for _type", _type] remoteExec ["systemChat", 0];
+	format["Please use one of the following types for _type:"] remoteExec ["systemChat", 0];
+	format["%1", (keys milsim_resupply_crateDefinitions)] remoteExec ["systemChat", 0];
+	false;
+};
+
+private _boxItems = _boxData getOrDefault ["items", createHashMap];
+
+if (isNull _box) then {
+	_box = (_boxData get "className") createVehicle _pos;
+};
+
+clearBackpackCargoGlobal _box;
+clearItemCargoGlobal _box;
+clearMagazineCargoGlobal _box;
+clearWeaponCargoGlobal _box;
+
+{
+	_x params ["_class", "_qty"];
+	
+	_box addBackpackCargoGlobal [_class, _qty]
+	
+} foreach (_boxItems getOrDefault ["backpacks", []]);
+
+{
+	_x params ["_class", "_qty"];
+	
+	_box addItemCargoGlobal [_class, _qty]
+	
+} foreach (_boxItems getOrDefault ["items", []]);
+
+{
+	_x params ["_class", "_qty"];
+	
+	_box addMagazineCargoGlobal [_class, _qty]
+	
+} foreach (_boxItems getOrDefault ["magazines", []]);
+
+{
+	_x params ["_class", "_qty"];
+	
+	_box addWeaponCargoGlobal [_class, _qty]
+	
+} foreach (_boxItems getOrDefault ["weapons", []]);
+
+[_box,1] call ace_cargo_fnc_setSize;
+
+// ignore weight restrictions for carry/drag
+_box setVariable ["ace_ignoreWeightCarry", true, true];
+_box;

functions/resupply/fn_createCSWBox.sqf

@@ -0,0 +1,36 @@
+/*
+ * Author: Hizumi & IndigoFox
+ *
+ * Create Ammo resupply box for the 17th Battalion
+ *
+ * Arguments:
+ * 0: Vehicle - <OBJECT>
+ * 1: Position - <ARRAY>
+ *
+ * Return Value:
+ * Function executed <BOOL>
+ *
+ * Example:
+ * [box] call milsim_fnc_createCSWBox; 			// create ammo box via init line of editor object
+ * [objNull, pos] call milsim_fnc_createCSWBox;		// create ammo box via zeus module
+ *
+ * Public: Yes
+ *
+ * Note: For gathering:
+	formatText ["%1", [
+		["containerClassname", typeOf cursorObject],
+		["backpack", (backpackCargo cursorObject) call BIS_fnc_consolidateArray],
+		["item", (itemCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazine", (magazineCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazineAmmo", magazinesAmmoCargo cursorObject],
+		["weapon", (weaponCargo cursorObject) call BIS_fnc_consolidateArray]
+	]];
+ */
+
+
+params [
+	["_box", objNull, [objNull]],
+	["_pos", [0,0,0], [[]], 3]
+];
+
+[_box, "CSW", _pos] call milsim_fnc_createBox;

functions/resupply/fn_createLaunchersBox.sqf

@@ -0,0 +1,36 @@
+/*
+ * Author: Hizumi & IndigoFox
+ *
+ * Create Ammo resupply box for the 17th Battalion
+ *
+ * Arguments:
+ * 0: Vehicle - <OBJECT>
+ * 1: Position - <ARRAY>
+ *
+ * Return Value:
+ * Function executed <BOOL>
+ *
+ * Example:
+ * [box] call milsim_fnc_createLaunchersBox; 			// create ammo box via init line of editor object
+ * [objNull, pos] call milsim_fnc_createLaunchersBox;		// create ammo box via zeus module
+ *
+ * Public: Yes
+ *
+ * Note: For gathering:
+	formatText ["%1", [
+		["containerClassname", typeOf cursorObject],
+		["backpack", (backpackCargo cursorObject) call BIS_fnc_consolidateArray],
+		["item", (itemCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazine", (magazineCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazineAmmo", magazinesAmmoCargo cursorObject],
+		["weapon", (weaponCargo cursorObject) call BIS_fnc_consolidateArray]
+	]];
+ */
+
+
+params [
+	["_box", objNull, [objNull]],
+	["_pos", [0,0,0], [[]], 3]
+];
+
+[_box, "LAUNCHERS", _pos] call milsim_fnc_createBox;

functions/resupply/fn_createMedicalBox.sqf

@@ -23,64 +23,4 @@ params [
 	["_pos", [0,0,0], [[]], 3]
 ];
 
-if (isNull _box) then {
-	_box = "ACE_medicalSupplyCrate_advanced" createVehicle _pos;
-};
-
-clearBackpackCargoGlobal _box;
-clearItemCargoGlobal _box;
-clearMagazineCargoGlobal _box;
-clearWeaponCargoGlobal _box;
-
-_packs = [];
-
-_items = [
-	["ACE_packingBandage",100],
-	["ACE_elasticBandage",100],
-	["ACE_tourniquet",48],
-	["ACE_splint",48],
-	["ACE_morphine",50],
-	["ACE_epinephrine",50],
-	["ACE_bloodIV",75],
-	["ACE_bloodIV_500",50],
-	["ACE_bloodIV_250",25],
-	["ACE_quikclot",75],
-	["ACE_personalAidKit", 5],
-	["ACE_surgicalKit", 5]
-];
-
-_magazines = [];
-
-_weapons = [];
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addBackpackCargoGlobal [_class, _qty]
-	
-} foreach _packs;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addItemCargoGlobal [_class, _qty]
-	
-} foreach _items;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addMagazineCargoGlobal [_class, _qty]
-	
-} foreach _magazines;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addWeaponCargoGlobal [_class, _qty]
-	
-} foreach _weapons;
-
-[_box,1] call ace_cargo_fnc_setSize;
-
-true;
+[_box, "MEDICAL", _pos] call milsim_fnc_createBox;

functions/resupply/fn_createMortarBox.sqf

@@ -0,0 +1,36 @@
+/*
+ * Author: Hizumi & IndigoFox
+ *
+ * Create Mortar resupply box for the 17th Battalion
+ *
+ * Arguments:
+ * 0: Vehicle - <OBJECT>
+ * 1: Position - <ARRAY>
+ *
+ * Return Value:
+ * Function executed <BOOL>
+ *
+ * Example:
+ * [box] call milsim_fnc_createMortarBox; 			// create mortar ammo box via init line of editor object
+ * [objNull, pos] call milsim_fnc_createMortarBox;		// create mortar ammo box via zeus module
+ *
+ * Public: Yes
+ *
+ * Note: For gathering:
+	formatText ["%1", [
+		["containerClassname", typeOf cursorObject],
+		["backpack", (backpackCargo cursorObject) call BIS_fnc_consolidateArray],
+		["item", (itemCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazine", (magazineCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazineAmmo", magazinesAmmoCargo cursorObject],
+		["weapon", (weaponCargo cursorObject) call BIS_fnc_consolidateArray]
+	]];
+ */
+
+
+params [
+	["_box", objNull, [objNull]],
+	["_pos", [0,0,0], [[]], 3]
+];
+
+[_box, "AMMO MORTAR", _pos] call milsim_fnc_createBox;

functions/resupply/fn_createWeaponsBox.sqf

@@ -12,9 +12,19 @@
  *
  * Example:
  * [box] call milsim_fnc_createWeaponsBox; 			// create ammo box via init line of editor object
- * [objNull, pos] call milsim_fnc_createWeaponsBox		// create ammo box via zeus module
+ * [objNull, pos] call milsim_fnc_createWeaponsBox;		// create ammo box via zeus module
  *
  * Public: Yes
+ *
+ * Note: For gathering:
+	formatText ["%1", [
+		["containerClassname", typeOf cursorObject],
+		["backpack", (backpackCargo cursorObject) call BIS_fnc_consolidateArray],
+		["item", (itemCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazine", (magazineCargo cursorObject) call BIS_fnc_consolidateArray],
+		["magazineAmmo", magazinesAmmoCargo cursorObject],
+		["weapon", (weaponCargo cursorObject) call BIS_fnc_consolidateArray]
+	]];
  */
 
 
@@ -23,60 +33,4 @@ params [
 	["_pos", [0,0,0], [[]], 3]
 ];
 
-if (isNull _box) then {
-	_box = "Box_NATO_Wps_F" createVehicle _pos;
-};
-
-clearBackpackCargoGlobal _box;
-clearItemCargoGlobal _box;
-clearMagazineCargoGlobal _box;
-clearWeaponCargoGlobal _box;
-
-_packs = [];
-
-_items = [];
-
-_magazines = [
-	["MRAWS_HEAT_F",35],
-	["MRAWS_HE_F",15],
-	["Tier1_250Rnd_762x51_Belt_M993_AP",50],
-	["Tier1_30Rnd_556x45_M856A1_EMag",25],
-	["Tier1_30Rnd_556x45_Mk318Mod0_EMag",50],
-	["Titan_AA",10],
-	["Titan_AT",10],
-	["200Rnd_65x39_cased_Box_Tracer_Red",50]
-];
-
-_weapons = [];
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addBackpackCargoGlobal [_class, _qty]
-	
-} foreach _packs;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addItemCargoGlobal [_class, _qty]
-	
-} foreach _items;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addMagazineCargoGlobal [_class, _qty]
-	
-} foreach _magazines;
-
-{
-	_x params ["_class", "_qty"];
-	
-	_box addWeaponCargoGlobal [_class, _qty]
-	
-} foreach _weapons;
-
-[_box,1] call ace_cargo_fnc_setSize;
-
-true;
+[_box, "AMMO HEAVY", _pos] call milsim_fnc_createBox;

functions/server/fn_logPlayerInventory.sqf

@@ -0,0 +1,144 @@
+/*
+	Function: milsim_fnc_logPlayerInventory
+
+	Description:
+		Checks a player's inventory for non-compliant items and logs results to all machines.
+
+	Author: Hizumi, EagleTrooper, IndigoFox
+
+	Parameters:
+		0: _player - <OBJECT> - Player to check inventory of.
+
+	Returns:
+		<ARRAY> - Array of strings to be logged.
+
+*/
+params [
+	["_player", objNull, [objNull]]
+];
+
+if (!isPlayer _player) exitWith {
+	[
+		"logPlayerInventory",
+		"PARAM PLAYER IS NOT A PLAYER",
+		[["player", _player]]
+	] call milsim_fnc_log;
+};
+
+// testing
+// test_old = compile preprocessFileLineNumbers "testold.sqf"; 
+// test_new = compile preprocessFileLineNumbers "testnew.sqf";
+// player addItem "A3_GPNVG18_BLK_TI";
+// player addWeapon "SMA_HK417_16in";
+// player addItem "ej_VPS15";
+// player addItem "ACE_Banana";
+
+// INSTANTIATE VARS
+private _foundItemsKeyValue = [];
+private _allFoundItemsSoFar = [];
+
+// GET PLAYER ITEMS
+private _playerItems = [
+	_player, // Unit
+	true, // Include weapons, attachments, loaded magazines
+	true, // Include items in backpack
+	true, // Include items in vest
+	true, // Include items in uniform
+	true, // Include assigned items
+	true // Include not loaded magazines
+] call CBA_fnc_uniqueUnitItems;
+
+_playerItems pushBack (headgear _player);
+_playerItems pushBack (uniform _player);
+
+
+[
+	"logPlayerInventory",
+	"CHECKING PLAYER INVENTORY",
+	[_player] call milsim_fnc_addPlayerInfoToArray
+] call milsim_fnc_log;
+
+////////////////////////////////////////
+// HARDCODED DISALLOWED ITEMS - see functions/definitions/DisallowedEquipment.hpp
+
+// Get parent class
+private _disallowedEquipmentCfg = (missionConfigFile >> "DisallowedEquipment");
+
+// Get all subclasses
+private _definitionCfgs = (_disallowedEquipmentCfg call BIS_fnc_getCfgSubClasses) apply {
+	(_disallowedEquipmentCfg >> _x)
+};
+
+// diag_log text format["DEFINITION CFGS: %1", _definitionCfgs];
+// Check all items
+{ // forEach _subclassesCfgs
+	private _definitionCfg = _x;
+	private _definitionLabel = (_definitionCfg >> "label") call BIS_fnc_getCfgData;
+	private _definitionItems = (_definitionCfg >> "items") call BIS_fnc_getCfgDataArray;
+	// diag_log text format["DEF ITEMS: %1", _definitionItems];
+	{ // forEach _playerItems
+		private _playerItem = _x;
+		// diag_log text format["PLAYER ITEM: %1", _playerItem];
+		if (_playerItem in _definitionItems && not (_playerItem in _allFoundItemsSoFar)) then {
+			// add under def label
+			[_foundItemsKeyValue, _definitionLabel, _playerItem] call BIS_fnc_addToPairs;
+			// add to all found items
+			_allFoundItemsSoFar pushBackUnique _playerItem;
+		};
+	} forEach _playerItems;
+} forEach _definitionCfgs;
+
+////////////////////////////////////////
+// UNLISTED THERMAL - Any item with thermal capabilities that is not already in the list
+
+// Identify thermal items in the player list
+private _thermalItems = _playerItems select {
+	private _playerItem = _x;
+	private _modes = getArray(configfile >> "CfgWeapons" >> _playerItem >> "visionMode");
+	private _subModes = [configfile >> "CfgWeapons" >> _playerItem >> "ItemInfo" >> "OpticsModes", 1] call BIS_fnc_returnChildren;
+	{
+		_modes append getArray( _x >> "visionMode" );
+	} forEach _subModes;
+	if ((count _modes) isNotEqualTo 0) then {
+		// if the item has thermal capabilities and is not in the list anywhere else, include it
+		"ti" in (_modes apply { toLower _x }) && not (_playerItem in _allFoundItemsSoFar);
+	} else {
+		false;
+	};
+};
+
+{
+	[_foundItemsKeyValue, "UNLISTED THERMAL", _x] call BIS_fnc_addToPairs;
+} forEach _thermalItems;
+
+
+// Only log compliance message if no non-compliant items were found
+if (count _allFoundItemsSoFar isEqualTo 0) exitWith {
+	[
+		"logPlayerInventory",
+		"PLAYER INVENTORY IS COMPLIANT",
+		[_player] call milsim_fnc_addPlayerInfoToArray
+	] call milsim_fnc_log;
+};
+
+// Log all non-compliant items
+{
+	_x params ["_categoryLabel", "_items"];
+	if (typeName _items isEqualTo "STRING") then {
+		_items = [_items];
+	};
+	{
+		private _itemClassName = _x;
+		private _itemConfig = _itemClassName call CBA_fnc_getItemConfig;
+		// Log to RPT
+		[
+			"logPlayerInventory",
+			"NON-COMPLIANT ITEM",
+			[_player, [
+				["category", _categoryLabel],
+				["className", _itemClassName],
+				["displayName", [_itemConfig] call BIS_fnc_displayName]
+			]] call milsim_fnc_addPlayerInfoToArray
+		] call milsim_fnc_log;
+	} forEach _items;
+} forEach _foundItemsKeyValue;

functions/settings/fn_addCBASettings.sqf

@@ -6,7 +6,7 @@
 	"milsim_sideChat",
 	"CHECKBOX",
 	"Side Chat Text Enabled",
-	["17th Batallion", "Side Chat"],
+	["17th Battalion", "Side Chat"],
 	false,
 	true,
 	{
@@ -25,7 +25,7 @@
 	"milsim_server_cps_enable",
 	"CHECKBOX",
 	"CPS Metrics Enabled",
-	["17th Batallion", "Server Metrics"],
+	["17th Battalion", "Server Metrics"],
 	true,
 	true,
 	{
@@ -40,7 +40,7 @@
 	"milsim_server_cps_interval",
 	"TIME",
 	"Metrics Interval",
-	["17th Batallion", "Server Metrics"],
+	["17th Battalion", "Server Metrics"],
 	[60,300,120],
 	true,
 	{
@@ -71,7 +71,7 @@
 	"milsim_client_cps_enable",
 	"CHECKBOX",
 	"CPS Metrics Enabled",
-	["17th Batallion", "Client Metrics"],
+	["17th Battalion", "Client Metrics"],
 	true,
 	true,
 	{
@@ -86,7 +86,7 @@
 	"milsim_client_cps_interval",
 	"TIME",
 	"CPS Metrics Interval",
-	["17th Batallion", "Client Metrics"],
+	["17th Battalion", "Client Metrics"],
 	[60,300,120],
 	true,
 	{
@@ -104,6 +104,143 @@
 	}
 ] call CBA_fnc_addSetting;
 
+//---------------------
+//	Medical Overlay
+//---------------------
+
+[
+	"milsim_client_medState3D_enabled", // variable
+	"CHECKBOX", // type
+	["Enable 3D Triage Card State", "Draws a colored dot over units within 10m indicating current ACE Triage State"], // title
+	["17th Battalion", "Medical"], // category
+	true // default value
+] call CBA_fnc_addSetting;
+
+[
+	"milsim_client_medState3D_drawRange", // variable
+	"LIST", // type
+	["Range To Draw Icons", "Determines range at which dots are visible"], // title
+	["17th Battalion", "Medical"], // category
+	[[2, 4, 6, 8, 10], ["2", "4", "6", "8", "10"], 4] // option values, option labels, default index
+] call CBA_fnc_addSetting;
+
+
+//---------------------
+// Respawn Settings
+[
+	"milsim_reinsert_setting_reinsertion_enabled", // variable
+	"CHECKBOX", // type
+	["Enabled", "Whether or not players can file for reinsert and pilots can check the reinsert queue"], // title
+	["17th Battalion", "Re-insert Queue"], // category
+	true, // default value
+	true, // global setting
+	{
+		params ["_value"];
+		[
+			"respawn_reinsertion",
+			"SETTING CHANGED",
+			[
+				[
+					"setting",
+					"milsim_reinsert_setting_reinsertion_enabled"
+				],
+				["newValue", _value]
+			]
+		] call milsim_fnc_log;
+	}
+] call CBA_fnc_addSetting;
+
+[
+	"milsim_reinsert_setting_reinsertion_maxRangeToReady", // variable
+	"SLIDER", // type
+	["Max Request Filing Range", "Maximum distance from a respawn point a player can be to ready up"], // title
+	["17th Battalion", "Re-insert Queue"], // category
+	[0, 1000, 400, 0, false], // [_min, _max, _default, _trailingDecimals, _isPercentage]
+	true, // global setting
+	{
+		params ["_value"];
+		[
+			"respawn_reinsertion",
+			"SETTING CHANGED",
+			[
+				[
+					"setting",
+					"milsim_reinsert_setting_reinsertion_maxRangeToReady"
+				],
+				["newValue", _value]
+			]
+		] call milsim_fnc_log;
+	}
+] call CBA_fnc_addSetting;
+
+[
+	"milsim_reinsert_setting_reinsertion_pilotForcedCheckEnabled", // variable
+	"CHECKBOX", // type
+	["Enabled", "Whether or not pilots are forced to view the contents of the reinsertion queue per interval"], // title
+	["17th Battalion", "Re-insert Queue"], // category
+	true, // default value
+	true, // global setting
+	{
+		params ["_value"];
+		[
+			"respawn_reinsertion",
+			"SETTING CHANGED",
+			[
+				[
+					"setting",
+					"milsim_reinsert_setting_reinsertion_pilotForcedCheckEnabled"
+				],
+				["newValue", _value]
+			]
+		] call milsim_fnc_log;
+	}
+] call CBA_fnc_addSetting;
+
+[
+	"milsim_reinsert_setting_reinsertion_pilotForcedCheckInterval", // variable
+	"TIME", // type
+	["Pilot Forced Check Interval", "Pilots will be force shown the queue if they haven't checked it in X seconds"], // title
+	["17th Battalion", "Re-insert Queue"], // category
+	[60*5, 60*30, 60*10], // [_min, _max, _default]
+	true,
+	{
+		params ["_value"];
+		[
+			"respawn_reinsertion",
+			"SETTING CHANGED",
+			[
+				[
+					"setting",
+					"milsim_reinsert_setting_reinsertion_pilotForcedCheckInterval"
+				],
+				["newValue", _value]
+			]
+		] call milsim_fnc_log;
+	}
+] call CBA_fnc_addSetting;
+
+[
+	"milsim_reinsert_setting_reinsertion_max_wait", // variable
+	"TIME", // type
+	["Max Wait Threshold", "How long should at least one person be waiting before prompting a global notification."], // title
+	["17th Battalion", "Re-insert Queue"], // category
+	[60*5, 60*30, 60*20], // [_min, _max, _default]
+	true,
+	{
+		params ["_value"];
+		[
+			"respawn_reinsertion",
+			"SETTING CHANGED",
+			[
+				[
+					"setting",
+					"milsim_reinsert_setting_reinsertion_max_wait"
+				],
+				["newValue", _value]
+			]
+		] call milsim_fnc_log;
+	}
+] call CBA_fnc_addSetting;
 
 diag_log text "[MILSIM] (settings) Custom CBA settings initialized";
 

functions/settings/fn_addRespawnChatHandler.sqf

@@ -3,7 +3,15 @@
 	{
 		_clientID = _thisArgs select 0;
 		player setDamage 1;
-		format["[MILSIM] (init) %1 claims they were glitched and respawned - %2", name player, netID player] remoteExec["diag_log", 2];
+
+		// log to server RPT
+		[
+			"init",
+			"CHAT COMMAND RESPAWN",
+			[player] call milsim_fnc_addPlayerInfoToArray
+		] remoteExec ["milsim_fnc_log", 2];
+
+		// systemChat to all remote machines
 		format["%1 claims they were glitched and respawned (%2)", name player, netID player] remoteExec["systemChat", -_clientID];
 	},
 	"all",

functions/util/fn_addPlayerInfoToArray.sqf

@@ -0,0 +1,14 @@
+params [["_playerObj", objNull], ["_arrayToModify", [], [[]]]];
+
+if (isNull _playerObj) exitWith {_arrayToModify};
+
+{
+	_arrayToModify = [_arrayToModify, _x#0, _x#1] call BIS_fnc_setToPairs;
+} forEach [
+	["playerName", name _playerObj],
+	["playerUID", getPlayerUID _playerObj],
+	["playerGroup", groupId (group _playerObj)],
+	["playerNetID", [_playerObj] call BIS_fnc_netId]
+];
+
+_arrayToModify;

functions/util/fn_log.sqf

@@ -0,0 +1,24 @@
+/* 
+	Function: milsim_fnc_log
+
+	Description:
+		Used to log messages to the server RPT file.
+
+	Parameters:
+		0: STRING - component name.
+		1: STRING - message to log.
+		2: ARRAY - Key value pairs of data to log.
+*/
+
+params [
+	["_component", "", [""]],
+	["_message", "", [""]],
+	["_data", [], [[]]]
+];
+
+private _hash = createHashMapFromArray _data;
+
+private _json = [_hash] call CBA_fnc_encodeJSON;
+_log = format ["[milsim] (%1) (%2) (%3) :: %4", _component, _fnc_scriptNameParent, _message, _json];
+
+diag_log text _log;

functions/util/fn_logMissionInfo.sqf

@@ -0,0 +1,23 @@
+[
+	"init",
+	"MISSION INFO",
+	[
+		["serverName", serverName],
+		["worldName", worldName],
+		["missionSeries", getMissionConfigValue ["missionSeries", ""]],
+		["missionName", missionName],
+		["briefingName", briefingName],
+		["overviewText", getMissionConfigValue ["overviewText", ""]],
+		["onLoadName", getMissionConfigValue ["onLoadName", ""]],
+		["onLoadMission", getMissionConfigValue ["onLoadMission", ""]],
+		["missionAuthor", getMissionConfigValue ["author", ""]],
+		["unitSlots", createHashMapFromArray [
+			["EAST", playableSlotsNumber EAST], // 0 is EAST side
+			["WEST", playableSlotsNumber WEST], // 1 is WEST side
+			["RESISTANCE", playableSlotsNumber RESISTANCE], // 2 is RESISTANCE side
+			["CIVILIAN", playableSlotsNumber CIVILIAN], // 3 is CIVILIAN side
+			["SIDEUNKNOWN", 0], // 4 is SIDEUNKNOWN side
+			["LOGIC", playableSlotsNumber sideLogic] // 5 is LOGIC side
+		]]
+	]
+] call milsim_fnc_log;

mission_settings.hpp

@@ -6,6 +6,8 @@ onLoadMission = "THIS APPEARS BELOW THE LOADING SCREEN IMAGE";
 briefingName = "THIS IS THE NAME ON THE #MISSIONS LIST";
 overviewText = "THIS IS WHERE YOU DESCRIBE THE MISSION IN THE #MISSION LIST";
 
+missionSeries = "";
+
 // activate via #ace-fortify west base 2000
 
 class ACEX_Fortify_Presets {